/[svn]/gigedit/trunk/configure.ac
ViewVC logotype

Contents of /gigedit/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1645 - (show annotations) (download)
Sat Jan 19 20:07:39 2008 UTC (13 years, 1 month ago) by schoenebeck
File size: 5639 byte(s)
* autoconf fix: LS plugin dirs with digits in their prefix
  (e.g. "/usr/lib64/foo") are now resolved in relative dirs as well
  (show a warning when resolving the relative path failed)

1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(configure.ac)
3 AC_CONFIG_AUX_DIR([.])
4
5 #------------------------------------------------------------------------------------
6 # The following is the current, official release version of gigedit:
7
8 GIGEDIT_VER_MAJOR=0
9 GIGEDIT_VER_MINOR=1
10 GIGEDIT_VER_RELEASE=1
11
12 #------------------------------------------------------------------------------------
13 # The following is the libtool / shared library version. This doesn't have to
14 # do anything with the release version. It MUST conform to the following rules:
15 #
16 # 1. Start with version information of `0:0:0' for each libtool library.
17 # 2. Update the version information only immediately before a public release of
18 # your software. More frequent updates are unnecessary, and only guarantee
19 # that the current interface number gets larger faster.
20 # 3. If the library source code has changed at all since the last update, then
21 # increment revision (`c:r:a' becomes `c:r+1:a').
22 # 4. If any interfaces have been added, removed, or changed since the last update,
23 # increment current, and set revision to 0.
24 # 5. If any interfaces have been added since the last public release, then increment
25 # age.
26 # 6. If any interfaces have been removed since the last public release, then set age
27 # to 0.
28
29 LIBGIGEDIT_LT_CURRENT=1
30 LIBGIGEDIT_LT_REVISION=0
31 LIBGIGEDIT_LT_AGE=0
32
33 SHARED_VERSION_INFO="$LIBGIGEDIT_LT_CURRENT:$LIBGIGEDIT_LT_REVISION:$LIBGIGEDIT_LT_AGE"
34 AC_LANG_CPLUSPLUS
35 AC_PROG_CXX
36 AC_PROG_LIBTOOL
37 AC_SUBST(SHLIB_VERSION_ARG)
38 AC_SUBST(SHARED_VERSION_INFO)
39 AC_SUBST(GIGEDIT_VER_MAJOR)
40 AC_SUBST(GIGEDIT_VER_MINOR)
41 AC_SUBST(GIGEDIT_VER_RELEASE)
42
43 # configure checks for the following file's existence to make sure that
44 # the directory that it is told contains the source code in fact does.
45 # Occasionally people accidentally specify the wrong directory with
46 # `--srcdir'; this is a safety check.
47 AC_CONFIG_SRCDIR(src/gigedit/main.cpp)
48
49 GETTEXT_PACKAGE=gigedit
50 AC_SUBST([GETTEXT_PACKAGE])
51 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
52
53 # the libgig header files need this
54 AC_C_BIGENDIAN
55
56 AC_PROG_CXX
57
58 IT_PROG_INTLTOOL(0.35.0)
59 AM_GLIB_GNU_GETTEXT
60
61 PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 >= 2.4.10 gthread-2.0)
62 PKG_CHECK_MODULES(GIG, gig >= 3.2.0)
63
64 # check for presence of libsndfile
65 PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.2)
66 AC_SUBST(SNDFILE_CFLAGS)
67 AC_SUBST(SNDFILE_LIBS)
68
69 # check for loop functionality in libsndfile
70 gigedit_save_CFLAGS=$CFLAGS
71 CFLAGS="$SNDFILE_CFLAGS $CFLAGS"
72 AC_CHECK_MEMBERS([SF_INSTRUMENT.loops],,
73 [AC_MSG_WARN([Your version of libsndfile does not support
74 reading of loop information. Gigedit will not be able to
75 extract loop information from sample files.])],
76 [#include <sndfile.h>])
77 CFLAGS=$gigedit_save_CFLAGS
78
79 # check for (optional) presence of liblinuxsampler
80 liblinuxsampler_version="0.5.0"
81 PKG_CHECK_MODULES(
82 LINUXSAMPLER, linuxsampler >= $liblinuxsampler_version,
83 have_linuxsampler=1, have_linuxsampler=0
84 )
85 LINUXSAMPLER_PLUGIN_DIR=
86 if test "$have_linuxsampler" = "0"; then
87 echo "Required liblinuxsampler version not found!"
88 echo "You need to have liblinuxsampler version ${liblinuxsampler_version}"
89 echo "installed. Support for on-the-fly editing with LinuxSampler will"
90 echo "be disabled."
91 else
92 echo "Found linuxsampler $liblinuxsampler_version"
93 echo -n "Retrieving LinuxSampler's plugin dir... "
94 LINUXSAMPLER_PLUGIN_DIR=`pkg-config --variable plugindir linuxsampler`
95 if test "$LINUXSAMPLER_PLUGIN_DIR" = ""; then
96 have_linuxsampler=0
97 echo "Error"
98 echo "Could not retrieve LinuxSampler's plugin directory. Support"
99 echo "for on-the-fly editing with LinuxSampler will be disabled."
100 else
101 echo "${LINUXSAMPLER_PLUGIN_DIR} "
102 # convert absolute LS plugin dir into relative dir
103 # (see ch 27.10 of the automake manual,
104 # "Installing to Hard-Coded Locations")
105 # this one is extended to work with digit postfixed lib directories
106 # (e.g. "/usr/lib64/linuxsampler") as well
107 LINUXSAMPLER_PLUGIN_DIR=`echo "${LINUXSAMPLER_PLUGIN_DIR}" | sed 's/^.*\/lib[[0-9]]*\//\${libdir}\//g'`
108 if echo "${LINUXSAMPLER_PLUGIN_DIR}" | grep "\${libdir}" > /dev/null; then
109 echo "Relative plugin dir: ${LINUXSAMPLER_PLUGIN_DIR}"
110 else
111 echo "*********************************************************"
112 echo "* ! WARNING ! : Could not resolve LinuxSampler's plugin"
113 echo "* directory as relative path. This is probably not an"
114 echo "* issue if you're just going to install gigedit by"
115 echo "* 'make install', but it IS a problem if you're"
116 echo "* installing to a certain destination directory and/or"
117 echo "* compile in sandbox (e.g. Debian package or Gentoo emerge)"
118 echo "*********************************************************"
119 fi
120 fi
121 fi
122 AC_SUBST(LINUXSAMPLER_CFLAGS)
123 AC_SUBST(LINUXSAMPLER_LIBS)
124 AC_SUBST(LINUXSAMPLER_PLUGIN_DIR)
125 AM_CONDITIONAL(HAVE_LINUXSAMPLER, test $have_linuxsampler = "1")
126 AC_DEFINE_UNQUOTED(
127 HAVE_LINUXSAMPLER, $have_linuxsampler,
128 [Define to 1 if you have LinuxSampler installed.]
129 )
130
131 AC_CONFIG_HEADERS(config.h)
132 AM_INIT_AUTOMAKE(gigedit, "$GIGEDIT_VER_MAJOR.$GIGEDIT_VER_MINOR.$GIGEDIT_VER_RELEASE")
133
134 AC_CONFIG_FILES([
135 Makefile
136 src/Makefile
137 src/gigedit/Makefile
138 src/plugin/Makefile
139 gfx/Makefile
140 po/Makefile.in
141 debian/Makefile
142 doc/Makefile
143 doc/quickstart/Makefile
144 win32/libgigedit.dev
145 win32/gigedit.dev
146 win32/gigedit.nsi
147 win32/Makefile
148 ])
149 AC_OUTPUT

  ViewVC Help
Powered by ViewVC