/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1462 - (show annotations) (download)
Mon Oct 29 14:18:13 2007 UTC (12 years, 8 months ago) by schoenebeck
File size: 8318 byte(s)
- forgot some autotools updates needed for the Qt4 version

1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.1.5.1, rncbc@rncbc.org, qsampler)
3 AC_CONFIG_SRCDIR(src/qsamplerMainForm.h)
4 AC_CONFIG_HEADERS(config.h)
5 AC_CONFIG_FILES(Makefile qsampler.pro qsampler.spec qsampler.desktop)
6
7 # Set default installation prefix.
8 AC_PREFIX_DEFAULT(/usr/local)
9 ac_prefix=$prefix
10 if test "x$ac_prefix" = "xNONE"; then
11 ac_prefix=$ac_default_prefix
12 fi
13 AC_SUBST(ac_prefix)
14 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
15
16 # Enable debugging argument option.
17 AC_ARG_ENABLE(debug,
18 AC_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
19 [ac_debug="$enableval"])
20
21 if test "x$ac_debug" = "xyes"; then
22 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
23 ac_debug="debug"
24 else
25 ac_debug="release"
26 fi
27 AC_SUBST(ac_debug)
28
29 # Enable libgig availability.
30 AC_ARG_ENABLE(libgig,
31 AC_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
32 [ac_libgig="$enableval"],
33 [ac_libgig="yes"])
34
35 # Standard installation base dirs.
36 ac_with_paths="/usr /usr/local"
37
38 # Some a-la-debian alternatives...
39 for X in /usr/lib /usr/share; do
40 for Y in qt qt4; do
41 if test -d $X/$Y/bin; then
42 ac_with_paths="$ac_with_paths $X/$Y"
43 fi
44 done
45 done
46
47 # Set for alternate liblscp installation dir.
48 AC_ARG_WITH(liblscp,
49 AC_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
50 [ac_with_paths="$ac_with_paths $withval"])
51
52 # Set for alternate libgig installation dir.
53 AC_ARG_WITH(libgig,
54 AC_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
55 [ac_with_paths="$ac_with_paths $withval"])
56
57 # Checks for programs.
58 AC_PROG_CC
59 AC_PROG_CPP
60 AC_PROG_CXX
61 AC_PROG_CXXCPP
62 AC_PROG_GCC_TRADITIONAL
63
64 # Checks for languages.
65 AC_LANG_C
66 AC_LANG_CPLUSPLUS
67
68 # Check for QTDIR environment variable.
69 AC_MSG_CHECKING([whether QTDIR environment variable is set])
70 if test "x$QTDIR" = "x"; then
71 AC_MSG_RESULT([no])
72 else
73 AC_MSG_RESULT([$QTDIR])
74 ac_with_paths="$ac_with_paths $QTDIR"
75 fi
76
77 # Prepend alternate dependencies paths.
78 ac_path=$PATH
79 for X in $ac_with_paths; do
80 if test -d $X/bin; then
81 ac_path="$X/bin:$ac_path"
82 fi
83 if test -d $X/include; then
84 for Y in qt qt4; do
85 if test -d $X/include/$Y; then
86 CFLAGS="-I$X/include/$Y $CFLAGS"
87 CPPFLAGS="-I$X/include/$Y $CPPFLAGS"
88 ac_incpath="$X/include/$Y $ac_incpath"
89 fi
90 done
91 CFLAGS="-I$X/include $CFLAGS"
92 CPPFLAGS="-I$X/include $CPPFLAGS"
93 ac_incpath="$X/include $ac_incpath"
94 fi
95 if test -d $X/lib64; then
96 LIBS="-L$X/lib64 $LIBS"
97 ac_libs="-L$X/lib64 $ac_libs"
98 fi
99 if test -d $X/lib; then
100 LIBS="-L$X/lib $LIBS"
101 ac_libs="-L$X/lib $ac_libs"
102 fi
103 done
104
105 # Checks for Qt library.
106 for X in qt-mt qt; do
107 if test "x$ac_qtlib" = "x"; then
108 AC_CHECK_LIB($X, main, [ac_qtlib=$X])
109 fi
110 done
111 if test "x$ac_qtlib" = "x"; then
112 AC_MSG_ERROR([Qt library not found. Maybe QTDIR isn't properly set.])
113 fi
114 AC_SUBST(ac_qtlib)
115
116 # Check for Qt multi-thread support.
117 if test "x$ac_qtlib" = "xqt-mt"; then
118 ac_thread="thread"
119 fi
120 AC_SUBST(ac_thread)
121
122 AC_CACHE_CHECK([for Qt library version >= 4.0.0],
123 ac_qtlib_version, [
124 AC_TRY_LINK([#include <Qt/qglobal.h>], [
125 #ifndef QT_VERSION
126 #error QT_VERSION macro not defined!
127 #endif
128 #if QT_VERSION < 0x040000
129 #error Qt library 4.0.0 or greater required.
130 #endif
131 ],
132 ac_qtlib_version="yes", [
133 echo "no; Qt 4.0.0 or greater is required"
134 exit
135 ])
136 ])
137
138 # A common error message:
139 ac_qtdir_errmsg="not found in current PATH. Maybe QT development environment isn't available (qt4-devel)."
140
141 # Check for Qt qmake utility.
142 AC_PATH_PROG(ac_qmake, qmake, [no], $ac_path)
143 if test "x$ac_qmake" = "xno"; then
144 AC_MSG_ERROR([qmake $ac_qtdir_errmsg])
145 fi
146 AC_SUBST(ac_qmake)
147
148 # Check for Qt moc utility.
149 AC_PATH_PROG(ac_moc, moc, [no], $ac_path)
150 if test "x$ac_moc" = "xno"; then
151 AC_MSG_ERROR([moc $ac_qtdir_errmsg])
152 fi
153 AC_SUBST(ac_moc)
154
155 # Check for Qt uic utility.
156 AC_PATH_PROG(ac_uic, uic, [no], $ac_path)
157 if test "x$ac_uic" = "xno"; then
158 AC_MSG_ERROR([uic $ac_qtdir_errmsg])
159 fi
160 AC_SUBST(ac_uic)
161
162 # Checks for libraries.
163 AC_CHECK_LIB(m, main)
164 AC_CHECK_LIB(X11, main)
165 AC_CHECK_LIB(Xext, main)
166 AC_CHECK_LIB($ac_qtlib, main)
167
168 # Check for round math function.
169 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
170 if test "x$ac_round" = "xyes"; then
171 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
172 fi
173
174 # Check for mandatory libraries.
175 AC_CHECK_LIB(lscp, main, [ac_liblscp="yes"], [ac_liblscp="no"])
176 if test "x$ac_liblscp" = "xno"; then
177 AC_MSG_ERROR([LSCP library not found.])
178 fi
179 ac_libs="$ac_libs -llscp"
180
181 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
182 ac_instrument_name, [
183 AC_TRY_COMPILE([#include "lscp/client.h"], [
184 lscp_channel_info_t info;
185 info.instrument_name = 0;
186 ], ac_instrument_name="yes", ac_instrument_name="no")
187 ])
188 if test "x$ac_instrument_name" = "xyes"; then
189 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
190 fi
191
192 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
193 ac_mute_solo, [
194 AC_TRY_COMPILE([#include "lscp/client.h"], [
195 lscp_channel_info_t info;
196 info.mute = 0;
197 info.solo = 0;
198 ], ac_mute_solo="yes", ac_mute_solo="no")
199 ])
200 if test "x$ac_mute_solo" = "xyes"; then
201 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
202 fi
203 if test "x$ac_mute_solo" = "xyes"; then
204 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
205 fi
206 if test "x$ac_mute_solo" = "xyes"; then
207 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
208 fi
209
210 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
211 if test "x$ac_midi_instrument" = "xyes"; then
212 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
213 fi
214
215 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
216 if test "x$ac_fxsend" = "xyes"; then
217 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
218 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
219 ac_fxsend_level, [
220 AC_TRY_COMPILE([#include "lscp/client.h"], [
221 lscp_fxsend_info_t info;
222 info.level = 0.0f;
223 ], ac_fxsend_level="yes", ac_fxsend_level="no")
224 ])
225 if test "x$ac_fxsend_level" = "xyes"; then
226 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
227 fi
228 fi
229
230 AC_CACHE_CHECK([for audio_routing array type],
231 ac_audio_routing, [
232 AC_TRY_COMPILE([#include "lscp/client.h"], [
233 lscp_channel_info_t info;
234 char ch = info.audio_routing[0][0];
235 ], ac_audio_routing="no", ac_audio_routing="yes")
236 ])
237 if test "x$ac_audio_routing" = "xyes"; then
238 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
239 fi
240
241 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
242 if test "x$ac_volume" = "xyes"; then
243 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
244 fi
245
246 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
247 if test "x$ac_edit_instrument" = "xyes"; then
248 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
249 fi
250
251 # Check for optional libraries.
252 if test "x$ac_libgig" = "xyes"; then
253 AC_CHECK_LIB(gig, main, [ac_libgig="yes"], [ac_libgig="no"])
254 if test "x$ac_libgig" = "xyes"; then
255 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
256 ac_libs="$ac_libs -lgig"
257 fi
258 fi
259
260 # Check for round math function.
261 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
262 if test "x$ac_round" = "xyes"; then
263 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
264 fi
265
266 AC_SUBST(ac_libs)
267 AC_SUBST(ac_incpath)
268
269 # Checks for header files.
270 AC_HEADER_STDC
271 AC_HEADER_SYS_WAIT
272 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h)
273
274 AC_CHECK_HEADER(lscp/client.h, [ac_lscp_h="yes"], [ac_lscp_h="no"])
275 if test "x$ac_lscp_h" = "xno"; then
276 AC_MSG_ERROR([LSCP headers not found.])
277 fi
278
279 # Checks for typedefs, structures, and compiler characteristics.
280 # AC_C_CONST
281
282 # Checks for library functions.
283 AC_CHECK_FUNCS(system)
284
285 # Finally produce a configure header file and the makefiles.
286 AC_OUTPUT
287
288 # make clean > /dev/null 2>&1
289
290 echo ""
291 echo "Now type 'make', followed by 'make install' as root."
292 echo ""

  ViewVC Help
Powered by ViewVC