/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 2987 - (show annotations) (download)
Fri Sep 23 11:42:50 2016 UTC (7 years, 6 months ago) by capela
File size: 15848 byte(s)
- Almost complete overhaul on the configure script command
  line options, wrt. installation directories specification,
  eg. --prefix, --bindir, --libdir, --datadir and --mandir.
  (EXPERIMENTAL)
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.4.1.1, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri src/qsampler.desktop)
7
8 # Sanitize version string.
9 ac_version=$(echo $PACKAGE_VERSION | sed -r 's/^([0-9|\.]+).*$/\1/')
10 AC_SUBST(ac_version)
11
12 # Set default installation prefix.
13 AC_PREFIX_DEFAULT(/usr/local)
14 if test "x$prefix" = "xNONE"; then
15 prefix=$ac_default_prefix
16 fi
17 if test "x$exec_prefix" = "xNONE"; then
18 exec_prefix=$prefix
19 fi
20 eval ac_prefix=$prefix
21 AC_SUBST(ac_prefix)
22 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
23
24 # Set default installation directories.
25 eval ac_bindir=$bindir
26 AC_SUBST(ac_bindir)
27 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
28
29 eval ac_libdir=$libdir
30 AC_SUBST(ac_libdir)
31 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
32
33 eval datarootdir=$datarootdir
34 eval ac_datadir=$datadir
35 AC_SUBST(ac_datadir)
36 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
37
38 eval ac_mandir=$mandir
39 AC_SUBST(ac_mandir)
40 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
41
42
43 # Enable debugging argument option.
44 AC_ARG_ENABLE(debug,
45 AC_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
46 [ac_debug="$enableval"])
47
48 if test "x$ac_debug" = "xyes"; then
49 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
50 ac_stacktrace="yes"
51 ac_debug="debug"
52 else
53 ac_stacktrace="no"
54 ac_debug="release"
55 fi
56 AC_SUBST(ac_debug)
57
58
59 # Enable Qt4/5 availability.
60 AC_ARG_ENABLE(qt4,
61 AC_HELP_STRING([--enable-qt4], [enable Qt4 build (default=no)]),
62 [ac_qt4="$enableval"],
63 [ac_qt4="no"])
64
65
66 # Enable libgig availability.
67 AC_ARG_ENABLE(libgig,
68 AC_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
69 [ac_libgig="$enableval"],
70 [ac_libgig="yes"])
71
72 # Enable X11 unique/single instance.
73 AC_ARG_ENABLE(xunique,
74 AC_HELP_STRING([--enable-xunique], [enable X11 unique/single instance (default=yes)]),
75 [ac_xunique="$enableval"],
76 [ac_xunique="yes"])
77
78 # Enable debugger stack-trace option (assumes --enable-debug).
79 AC_ARG_ENABLE(stacktrace,
80 AC_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
81 [ac_stacktrace="$enableval"])
82
83
84 # Standard installation base dirs.
85 ac_with_paths=""
86
87 # Set for alternate Qt4/5 installation dir.
88 AC_ARG_WITH(qt4,
89 AC_HELP_STRING([--with-qt4=PATH], [use alternate Qt4 install path]),
90 [ac_qt4_path="$withval"], [ac_qt4_path="no"])
91
92 AC_ARG_WITH(qt5,
93 AC_HELP_STRING([--with-qt5=PATH], [use alternate Qt5 install path]),
94 [ac_qt5_path="$withval"], [ac_qt5_path="no"])
95
96 if test "x$ac_qt4_path" != "xno"; then
97 ac_with_paths="$ac_with_paths $ac_qt4_path"
98 ac_qt4="yes"
99 fi
100
101 if test "x$ac_qt5_path" != "xno"; then
102 ac_with_paths="$ac_with_paths $ac_qt5_path"
103 ac_qt4="no"
104 fi
105
106 # Set for alternate liblscp installation dir.
107 AC_ARG_WITH(liblscp,
108 AC_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
109 [ac_with_paths="$ac_with_paths $withval"])
110
111 # Set for alternate libgig installation dir.
112 AC_ARG_WITH(libgig,
113 AC_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
114 [ac_with_paths="$ac_with_paths $withval"])
115
116
117 # Honor user specified flags.
118 ac_cflags=$CFLAGS
119 ac_ldflags=$LDFLAGS
120
121
122 # Checks for programs.
123 AC_PROG_CPP
124 AC_PROG_CXX
125 AC_PROG_CXXCPP
126
127 # Checks for languages.
128 AC_LANG_CPLUSPLUS
129
130 PKG_PROG_PKG_CONFIG
131
132 # Check for proper flags.
133 ac_arch=`uname -m`
134
135 # Check for install paths and alternatives...
136 ac_libdirs="lib"
137
138 if test "x$ac_arch" = "xx86_64"; then
139 ac_libdirs="$ac_libdirs lib64"
140 fi
141
142 CFLAGS="-fPIC $CFLAGS"
143 CPPFLAGS="-fPIC $CPPFLAGS"
144
145 # Prepend alternate dependencies paths.
146 ac_path=$PATH
147
148 for X in $ac_with_paths; do
149 if test -d $X/bin; then
150 ac_path="$X/bin:$ac_path"
151 fi
152 if test -d $X/include; then
153 CFLAGS="-I$X/include $CFLAGS "
154 CPPFLAGS="-I$X/include $CPPFLAGS"
155 ac_incpath="$X/include $ac_incpath"
156 fi
157 for Y in $ac_libdirs; do
158 if test -d $X/$Y; then
159 LIBS="-L$X/$Y $LIBS"
160 ac_libs="-L$X/$Y $ac_libs"
161 fi
162 done
163 done
164
165 # A common error message:
166 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
167
168 if test "x$ac_qt4" = "xyes"; then
169 AC_PATH_PROG(ac_qmake, qmake-qt4, [no], $ac_path)
170 else
171 AC_PATH_PROG(ac_qmake, qmake-qt5, [no], $ac_path)
172 fi
173 if test "x$ac_qmake" = "xno"; then
174 AC_PATH_PROG(ac_cv_qmake, qmake, [no], $ac_path)
175 ac_qmake=$ac_cv_qmake
176 fi
177 if test "x$ac_qmake" = "xno"; then
178 AC_MSG_ERROR([qmake $ac_errmsg])
179 fi
180
181 # Check for proper Qt4/5 major version.
182 ac_qt_version_major=`$ac_qmake -query QT_VERSION | cut -d. -f1`
183 if test "x$ac_qt4" = "xyes"; then
184 if test "x$ac_qt_version_major" != "x4"; then
185 AC_MSG_ERROR([qmake-qt4 $ac_errmsg (qt4-devel)])
186 fi
187 else
188 if test "x$ac_qt_version_major" != "x5"; then
189 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
190 fi
191 fi
192
193 ac_qt_install_bins=`$ac_qmake -query QT_INSTALL_BINS`
194 if test -d $ac_qt_install_bins; then
195 ac_path="$ac_qt_install_bins:$ac_path"
196 fi
197
198 # Check it again, now with updated PATH, just in case...
199 AC_PATH_PROG(ac_cv_qmake, qmake, [no], $ac_path)
200 ac_qmake=$ac_cv_qmake
201 if test "x$ac_qmake" = "xno"; then
202 AC_MSG_ERROR([qmake $ac_errmsg])
203 fi
204
205 AC_SUBST(ac_qmake)
206
207 ac_qt_install_headers=`$ac_qmake -query QT_INSTALL_HEADERS`
208 if test -d $ac_qt_install_headers; then
209 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
210 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
211 ac_incpath="$ac_qt_install_headers $ac_incpath"
212 fi
213
214 ac_qt_install_libs=`$ac_qmake -query QT_INSTALL_LIBS`
215 if test -d $ac_qt_install_libs; then
216 LIBS="-L$ac_qt_install_libs $LIBS"
217 ac_libs="-L$ac_qt_install_libs $ac_libs"
218 fi
219
220 # Check for proper Qt4/5 version.
221 if test "x$ac_qt4" = "xyes"; then
222 AC_CACHE_CHECK([for Qt library version >= 4.4],
223 ac_cv_qtversion, [
224 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
225 #if QT_VERSION < 0x040400 || QT_VERSION >= 0x050000
226 #error Qt library 4.4 or greater required.
227 #endif
228 ], ac_cv_qtversion="yes", [
229 echo "no; Qt 4.4 or greater is required"
230 exit 1
231 ])
232 ])
233 else
234 AC_CACHE_CHECK([for Qt library version >= 5.1],
235 ac_cv_qtversion, [
236 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
237 #if QT_VERSION < 0x050100 || QT_VERSION >= 0x060000
238 #error Qt library 5.1 or greater required.
239 #endif
240 ], ac_cv_qtversion="yes", [
241 echo "no; Qt 5.1 or greater is required"
242 exit 1
243 ])
244 ])
245 fi
246
247 # Check for Qt moc utility.
248 AC_PATH_PROG(ac_moc, moc, [no], $ac_path)
249 if test "x$ac_moc" = "xno"; then
250 AC_MSG_ERROR([moc $ac_errmsg])
251 fi
252 AC_SUBST(ac_moc)
253
254 # Check for Qt uic utility.
255 AC_PATH_PROG(ac_uic, uic, [no], $ac_path)
256 if test "x$ac_uic" = "xno"; then
257 AC_MSG_ERROR([uic $ac_errmsg])
258 fi
259 AC_SUBST(ac_uic)
260
261 # Check for Qt lupdate utility.
262 AC_PATH_PROG(ac_lupdate, lupdate, [no], $ac_path)
263 if test "x$ac_lupdate" = "xno"; then
264 AC_MSG_ERROR([lupdate $ac_errmsg])
265 fi
266 AC_SUBST(ac_lupdate)
267
268 # Check for Qt lrelease utility.
269 AC_PATH_PROG(ac_lrelease, lrelease, [no], $ac_path)
270 if test "x$ac_release" = "xno"; then
271 AC_MSG_ERROR([lrelease $ac_errmsg])
272 fi
273 AC_SUBST(ac_lrelease)
274
275
276 # Checks for libraries.
277 AC_CHECK_LIB(m, main)
278 AC_CHECK_LIB(X11, main)
279 AC_CHECK_LIB(Xext, main)
280
281 # Check for round math function.
282 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
283 if test "x$ac_round" = "xyes"; then
284 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
285 fi
286
287 # Check for mandatory libraries.
288 AC_CHECK_LIB(lscp, main, [ac_liblscp="yes"], [ac_liblscp="no"])
289 if test "x$ac_liblscp" = "xno"; then
290 AC_MSG_ERROR([LSCP library not found.])
291 fi
292 ac_libs="$ac_libs -llscp"
293 case "{$host}" in
294 *mingw*)
295 ac_libs="$ac_libs -lws2_32"
296 LIBS="$LIBS -lws2_32"
297 ;;
298 esac
299
300 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
301 ac_cv_instrument_name, [
302 AC_TRY_COMPILE([#include "lscp/client.h"], [
303 lscp_channel_info_t info;
304 info.instrument_name = 0;
305 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
306 ])
307 ac_instrument_name=$ac_cv_instrument_name
308 if test "x$ac_instrument_name" = "xyes"; then
309 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
310 fi
311
312 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
313 ac_cv_mute_solo, [
314 AC_TRY_COMPILE([#include "lscp/client.h"], [
315 lscp_channel_info_t info;
316 info.mute = 0;
317 info.solo = 0;
318 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
319 ])
320 ac_mute_solo=$ac_cv_mute_solo
321 if test "x$ac_mute_solo" = "xyes"; then
322 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
323 fi
324 if test "x$ac_mute_solo" = "xyes"; then
325 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
326 fi
327 if test "x$ac_mute_solo" = "xyes"; then
328 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
329 fi
330
331 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
332 if test "x$ac_midi_instrument" = "xyes"; then
333 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
334 fi
335
336 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
337 if test "x$ac_fxsend" = "xyes"; then
338 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
339 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
340 ac_cv_fxsend_level, [
341 AC_TRY_COMPILE([#include "lscp/client.h"], [
342 lscp_fxsend_info_t info;
343 info.level = 0.0f;
344 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
345 ])
346 ac_fxsend_level=$ac_cv_fxsend_level
347 if test "x$ac_fxsend_level" = "xyes"; then
348 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
349 fi
350 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
351 if test "x$ac_fxsend_rename" = "xyes"; then
352 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
353 fi
354 fi
355
356 AC_CACHE_CHECK([for audio_routing array type],
357 ac_cv_audio_routing, [
358 AC_TRY_COMPILE([#include "lscp/client.h"], [
359 lscp_channel_info_t info;
360 char ch = info.audio_routing[0][0];
361 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
362 ])
363 ac_audio_routing=$ac_cv_audio_routing
364 if test "x$ac_audio_routing" = "xyes"; then
365 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
366 fi
367
368 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
369 if test "x$ac_volume" = "xyes"; then
370 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
371 fi
372
373 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
374 if test "x$ac_edit_instrument" = "xyes"; then
375 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
376 fi
377
378 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
379 ac_cv_channel_midi_event, [
380 AC_TRY_COMPILE([
381 #include "lscp/client.h"
382 #include "lscp/event.h"
383 ], [
384 lscp_event_t ev;
385 ev = LSCP_EVENT_CHANNEL_MIDI;
386 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
387 ])
388 ac_channel_midi_event=$ac_cv_channel_midi_event
389 if test "x$ac_channel_midi_event" = "xyes"; then
390 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
391 fi
392
393 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
394 ac_cv_device_midi_event, [
395 AC_TRY_COMPILE([
396 #include "lscp/client.h"
397 #include "lscp/event.h"
398 ], [
399 lscp_event_t ev;
400 ev = LSCP_EVENT_DEVICE_MIDI;
401 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
402 ])
403 ac_device_midi_event=$ac_cv_device_midi_event
404 if test "x$ac_device_midi_event" = "xyes"; then
405 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
406 fi
407
408 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
409 if test "x$ac_max_voices" = "xyes"; then
410 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
411 fi
412
413 # Check for optional libraries.
414 if test "x$ac_libgig" = "xyes"; then
415 PKG_CHECK_MODULES(LIBGIG, gig >= 3.3.0, [ac_libgig="yes"], [ac_libgig="no"])
416 if test "x$ac_libgig" = "xyes"; then
417 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
418 AC_SUBST(LIBGIG_CFLAGS)
419 AC_SUBST(LIBGIG_LIBS)
420 ac_cflags="$ac_cflags $LIBGIG_CFLAGS"
421 ac_libs="$ac_libs $LIBGIG_LIBS"
422 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
423 ac_libgig_setautoload="yes"
424 fi
425 fi
426
427 # Check for round math function.
428 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
429 if test "x$ac_round" = "xyes"; then
430 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
431 fi
432
433 # Check for X11 unique/single instance.
434 if test "x$ac_xunique" = "xyes"; then
435 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if X11 unique/single instance is enabled.])
436 fi
437
438 # Check for debugging stack-trace.
439 if test "x$ac_stacktrace" = "xyes"; then
440 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
441 fi
442
443 # Some recent distros (eg. fedora, debian) require this.
444 if test "x$ac_cv_lib_X11_main" = "xyes"; then
445 ac_libs="$ac_libs -lX11"
446 fi
447
448 AC_SUBST(ac_libs)
449 AC_SUBST(ac_incpath)
450 AC_SUBST(ac_cflags)
451 AC_SUBST(ac_ldflags)
452
453 # Checks for header files.
454 AC_HEADER_STDC
455 AC_HEADER_SYS_WAIT
456 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
457
458 AC_CHECK_HEADER(lscp/client.h, [ac_lscp_h="yes"], [ac_lscp_h="no"])
459 if test "x$ac_lscp_h" = "xno"; then
460 AC_MSG_ERROR([LSCP headers not found.])
461 fi
462
463 if test "x$ac_libgig" = "xyes"; then
464 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
465 if test "x$ac_libgig_sf2" = "xyes"; then
466 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
467 fi
468 fi
469
470 # Checks for typedefs, structures, and compiler characteristics.
471 # AC_C_CONST
472
473 # Checks for library functions.
474 AC_CHECK_FUNCS(system)
475
476 # Finally produce a configure header file and the makefiles.
477 AC_OUTPUT
478
479 # make clean > /dev/null 2>&1
480
481 # Output summary message
482
483 echo
484 echo " $PACKAGE_NAME $PACKAGE_VERSION"
485 echo
486 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
487 echo
488 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
489 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
490 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
491 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
492 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
493 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
494 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
495 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
496 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
497 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
498 if test "x$ac_libgig" = "xyes"; then
499 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
500 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
501 fi
502 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
503 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
504 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
505 echo
506 echo " X11 Unique/Single instance . . . . . . . . . . . .: $ac_xunique"
507 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
508 echo
509 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
510 echo
511 echo "Now type 'make', followed by 'make install' as root."
512 echo

  ViewVC Help
Powered by ViewVC