/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3086 - (show annotations) (download)
Fri Jan 13 16:35:41 2017 UTC (7 years, 2 months ago) by capela
File size: 18166 byte(s)
- Fixed libjack detection on configure.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.4.2, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri src/qsampler.desktop)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed -r 's/^[[^_]]+_//')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed -r 's/-g/git./')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed -r 's/[[_|-]]+/./g')
15 else
16 ac_cv_build_version=$PACKAGE_VERSION
17 fi
18 ])
19 ac_build_version="$ac_cv_build_version"
20 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
21
22 # Sanitized version string.
23 AC_CACHE_VAL([ac_cv_version], [
24 ac_cv_version=$(echo $ac_cv_build_version | sed -r 's/^([[0-9|\.]]+).*$/\1/')
25 ])
26 ac_version="$ac_cv_version"
27 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
28 AC_SUBST(ac_version)
29
30 # Set default installation prefix.
31 AC_PREFIX_DEFAULT(/usr/local)
32 if test "x$prefix" = "xNONE"; then
33 prefix=$ac_default_prefix
34 fi
35 if test "x$exec_prefix" = "xNONE"; then
36 exec_prefix=$prefix
37 fi
38 eval ac_prefix=$prefix
39 AC_SUBST(ac_prefix)
40 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
41
42 # Set default installation directories.
43 eval ac_bindir=$bindir
44 AC_SUBST(ac_bindir)
45 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
46
47 eval ac_libdir=$libdir
48 AC_SUBST(ac_libdir)
49 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
50
51 eval datarootdir=$datarootdir
52 eval ac_datadir=$datadir
53 AC_SUBST(ac_datadir)
54 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
55
56 eval ac_mandir=$mandir
57 AC_SUBST(ac_mandir)
58 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
59
60
61 # Enable debugging argument option.
62 AC_ARG_ENABLE(debug,
63 AC_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
64 [ac_debug="$enableval"])
65
66 if test "x$ac_debug" = "xyes"; then
67 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
68 ac_stacktrace="yes"
69 ac_debug="debug"
70 else
71 ac_stacktrace="no"
72 ac_debug="release"
73 fi
74 AC_SUBST(ac_debug)
75
76
77 # Enable Qt4/5 availability.
78 AC_ARG_ENABLE(qt4,
79 AC_HELP_STRING([--enable-qt4], [enable Qt4 build (default=no)]),
80 [ac_qt4="$enableval"],
81 [ac_qt4="no"])
82
83
84 # Enable libgig availability.
85 AC_ARG_ENABLE(libgig,
86 AC_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
87 [ac_libgig="$enableval"],
88 [ac_libgig="yes"])
89
90 # Enable X11 unique/single instance.
91 AC_ARG_ENABLE(xunique,
92 AC_HELP_STRING([--enable-xunique], [enable X11 unique/single instance (default=yes)]),
93 [ac_xunique="$enableval"],
94 [ac_xunique="yes"])
95
96 # Enable debugger stack-trace option (assumes --enable-debug).
97 AC_ARG_ENABLE(stacktrace,
98 AC_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
99 [ac_stacktrace="$enableval"])
100
101
102 # Standard installation base dirs.
103 ac_with_paths=""
104
105 # Set for alternate Qt4/5 installation dir.
106 AC_ARG_WITH(qt4,
107 AC_HELP_STRING([--with-qt4=PATH], [use alternate Qt4 install path]),
108 [ac_qt4_path="$withval"], [ac_qt4_path="no"])
109
110 AC_ARG_WITH(qt5,
111 AC_HELP_STRING([--with-qt5=PATH], [use alternate Qt5 install path]),
112 [ac_qt5_path="$withval"], [ac_qt5_path="no"])
113
114 if test "x$ac_qt4_path" != "xno"; then
115 ac_with_paths="$ac_with_paths $ac_qt4_path"
116 ac_qt4="yes"
117 fi
118
119 if test "x$ac_qt5_path" != "xno"; then
120 ac_with_paths="$ac_with_paths $ac_qt5_path"
121 ac_qt4="no"
122 fi
123
124 # Set for alternate liblscp installation dir.
125 AC_ARG_WITH(liblscp,
126 AC_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
127 [ac_with_paths="$ac_with_paths $withval"])
128
129 # Set for alternate libgig installation dir.
130 AC_ARG_WITH(libgig,
131 AC_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
132 [ac_with_paths="$ac_with_paths $withval"])
133
134
135 # Honor user specified flags.
136 ac_cflags=$CFLAGS
137 ac_ldflags=$LDFLAGS
138
139
140 # Checks for programs.
141 AC_PROG_CPP
142 AC_PROG_CXX
143 AC_PROG_CXXCPP
144
145 # Checks for languages.
146 AC_LANG_CPLUSPLUS
147
148 # Check for pkg-config.
149 PKG_PROG_PKG_CONFIG
150
151 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
152 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
153 ac_cv_gxx_version_major=$($CC -dumpversion)
154 if test -n "$ac_cv_gxx_version_major"; then
155 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
156 fi
157 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
158 ])
159 ac_gxx_version_major=$ac_cv_gxx_version_major
160 if test $ac_gxx_version_major -gt 4 -a $ac_gxx_version_major -lt 6; then
161 CXXFLAGS="-std=c++11 $CXXFLAGS"
162 fi
163
164 # Check for proper flags.
165 ac_arch=$(uname -m)
166
167 # Check for install paths and alternatives...
168 ac_libdirs="lib"
169
170 if test "x$ac_arch" = "xx86_64"; then
171 ac_libdirs="$ac_libdirs lib64"
172 fi
173
174 CFLAGS="-fPIC $CFLAGS"
175 CPPFLAGS="-fPIC $CPPFLAGS"
176
177 # Prepend alternate dependencies paths.
178 ac_path=$PATH
179
180 for X in $ac_with_paths; do
181 if test -d $X/bin; then
182 ac_path="$X/bin:$ac_path"
183 fi
184 if test -d $X/include; then
185 CFLAGS="-I$X/include $CFLAGS "
186 CPPFLAGS="-I$X/include $CPPFLAGS"
187 ac_incpath="$X/include $ac_incpath"
188 fi
189 for Y in $ac_libdirs; do
190 if test -d $X/$Y; then
191 LIBS="-L$X/$Y $LIBS"
192 ac_libs="-L$X/$Y $ac_libs"
193 fi
194 done
195 done
196
197 # A common error message:
198 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
199
200 if test "x$ac_qt4" = "xyes"; then
201 AC_PATH_PROG(ac_qmake, qmake-qt4, [no], $ac_path)
202 else
203 AC_PATH_PROG(ac_qmake, qmake-qt5, [no], $ac_path)
204 fi
205 if test "x$ac_qmake" = "xno"; then
206 AC_PATH_PROG(ac_cv_qmake, qmake, [no], $ac_path)
207 ac_qmake=$ac_cv_qmake
208 fi
209 if test "x$ac_qmake" = "xno"; then
210 AC_MSG_ERROR([qmake $ac_errmsg])
211 fi
212
213 # Check for proper Qt major version.
214 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
215 ac_cv_qt_version_major=$($ac_qmake -query QT_VERSION | cut -d'.' -f1)
216 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
217 ])
218 ac_qt_version_major=$ac_cv_qt_version_major
219 if test "x$ac_qt4" = "xyes"; then
220 if test $ac_qt_version_major -ne 4; then
221 AC_MSG_ERROR([qmake-qt4 $ac_errmsg (qt4-devel)])
222 fi
223 else
224 if test $ac_qt_version_major -ne 5; then
225 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
226 fi
227 fi
228
229 # Check for proper Qt install path.
230 AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [
231 ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS)
232 ])
233 ac_qt_install_path=$ac_cv_qt_install_path
234 if test -d $ac_qt_install_path; then
235 ac_path="$ac_qt_install_path:$ac_path"
236 fi
237
238 # Check it again, now with updated PATH, just in case...
239 AC_PATH_PROG(ac_cv_qmake, qmake, [no], $ac_path)
240 ac_qmake=$ac_cv_qmake
241 if test "x$ac_qmake" = "xno"; then
242 AC_MSG_ERROR([qmake $ac_errmsg])
243 fi
244
245 AC_SUBST(ac_qmake)
246
247 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
248 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
249 ])
250 ac_qt_install_headers=$ac_cv_qt_install_headers
251 if test -d $ac_qt_install_headers; then
252 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
253 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
254 ac_incpath="$ac_qt_install_headers $ac_incpath"
255 fi
256
257 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
258 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
259 ])
260 ac_qt_install_libs=$ac_cv_qt_install_libs
261 if test -d $ac_qt_install_libs; then
262 LIBS="-L$ac_qt_install_libs $LIBS"
263 ac_libs="-L$ac_qt_install_libs $ac_libs"
264 fi
265
266 # Finally, check for proper Qt4/5 version.
267 if test "x$ac_qt4" = "xyes"; then
268 AC_CACHE_CHECK([for Qt library version >= 4.4],
269 ac_cv_qtversion, [
270 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
271 #if QT_VERSION < 0x040400 || QT_VERSION >= 0x050000
272 #error Qt library 4.4 or greater required.
273 #endif
274 ], ac_cv_qtversion="yes", [
275 echo "no; Qt 4.4 or greater is required"
276 exit 1
277 ])
278 ])
279 else
280 AC_CACHE_CHECK([for Qt library version >= 5.1],
281 ac_cv_qtversion, [
282 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
283 #if QT_VERSION < 0x050100 || QT_VERSION >= 0x060000
284 #error Qt library 5.1 or greater required.
285 #endif
286 ], ac_cv_qtversion="yes", [
287 echo "no; Qt 5.1 or greater is required"
288 exit 1
289 ])
290 ])
291 fi
292
293 # Check for Qt moc utility.
294 AC_PATH_PROG(ac_moc, moc, [no], $ac_path)
295 if test "x$ac_moc" = "xno"; then
296 AC_MSG_ERROR([moc $ac_errmsg])
297 fi
298 AC_SUBST(ac_moc)
299
300 # Check for Qt uic utility.
301 AC_PATH_PROG(ac_uic, uic, [no], $ac_path)
302 if test "x$ac_uic" = "xno"; then
303 AC_MSG_ERROR([uic $ac_errmsg])
304 fi
305 AC_SUBST(ac_uic)
306
307 # Check for Qt lupdate utility.
308 AC_PATH_PROG(ac_lupdate, lupdate, [no], $ac_path)
309 if test "x$ac_lupdate" = "xno"; then
310 AC_MSG_ERROR([lupdate $ac_errmsg])
311 fi
312 AC_SUBST(ac_lupdate)
313
314 # Check for Qt lrelease utility.
315 AC_PATH_PROG(ac_lrelease, lrelease, [no], $ac_path)
316 if test "x$ac_release" = "xno"; then
317 AC_MSG_ERROR([lrelease $ac_errmsg])
318 fi
319 AC_SUBST(ac_lrelease)
320
321
322 # Checks for libraries.
323 AC_CHECK_LIB(m, main)
324 AC_CHECK_LIB(X11, main)
325 AC_CHECK_LIB(Xext, main)
326
327 # Check for round math function.
328 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
329 if test "x$ac_round" = "xyes"; then
330 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
331 fi
332
333 # Check for mandatory libraries.
334 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
335 if test "x$ac_liblscp" = "xyes"; then
336 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
337 ac_cflags="$ac_cflags $LSCP_CFLAGS"
338 ac_libs="$ac_libs $LSCP_LIBS"
339 CFLAGS="$CFLAGS $LSCP_CFLAGS"
340 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
341 LIBS="$LIBS $LSCP_LIBS"
342 else
343 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
344 fi
345
346 case "{$host}" in
347 *mingw*)
348 ac_libs="$ac_libs -lws2_32"
349 LIBS="$LIBS -lws2_32"
350 ;;
351 esac
352
353 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
354 ac_cv_instrument_name, [
355 AC_TRY_COMPILE([#include "lscp/client.h"], [
356 lscp_channel_info_t info;
357 info.instrument_name = 0;
358 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
359 ])
360 ac_instrument_name=$ac_cv_instrument_name
361 if test "x$ac_instrument_name" = "xyes"; then
362 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
363 fi
364
365 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
366 ac_cv_mute_solo, [
367 AC_TRY_COMPILE([#include "lscp/client.h"], [
368 lscp_channel_info_t info;
369 info.mute = 0;
370 info.solo = 0;
371 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
372 ])
373 ac_mute_solo=$ac_cv_mute_solo
374 if test "x$ac_mute_solo" = "xyes"; then
375 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
376 fi
377 if test "x$ac_mute_solo" = "xyes"; then
378 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
379 fi
380 if test "x$ac_mute_solo" = "xyes"; then
381 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
382 fi
383
384 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
385 if test "x$ac_midi_instrument" = "xyes"; then
386 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
387 fi
388
389 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
390 if test "x$ac_fxsend" = "xyes"; then
391 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
392 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
393 ac_cv_fxsend_level, [
394 AC_TRY_COMPILE([#include "lscp/client.h"], [
395 lscp_fxsend_info_t info;
396 info.level = 0.0f;
397 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
398 ])
399 ac_fxsend_level=$ac_cv_fxsend_level
400 if test "x$ac_fxsend_level" = "xyes"; then
401 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
402 fi
403 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
404 if test "x$ac_fxsend_rename" = "xyes"; then
405 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
406 fi
407 fi
408
409 AC_CACHE_CHECK([for audio_routing array type],
410 ac_cv_audio_routing, [
411 AC_TRY_COMPILE([#include "lscp/client.h"], [
412 lscp_channel_info_t info;
413 char ch = info.audio_routing[0][0];
414 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
415 ])
416 ac_audio_routing=$ac_cv_audio_routing
417 if test "x$ac_audio_routing" = "xyes"; then
418 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
419 fi
420
421 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
422 if test "x$ac_volume" = "xyes"; then
423 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
424 fi
425
426 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
427 if test "x$ac_edit_instrument" = "xyes"; then
428 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
429 fi
430
431 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
432 ac_cv_channel_midi_event, [
433 AC_TRY_COMPILE([
434 #include "lscp/client.h"
435 #include "lscp/event.h"
436 ], [
437 lscp_event_t ev;
438 ev = LSCP_EVENT_CHANNEL_MIDI;
439 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
440 ])
441 ac_channel_midi_event=$ac_cv_channel_midi_event
442 if test "x$ac_channel_midi_event" = "xyes"; then
443 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
444 fi
445
446 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
447 ac_cv_device_midi_event, [
448 AC_TRY_COMPILE([
449 #include "lscp/client.h"
450 #include "lscp/event.h"
451 ], [
452 lscp_event_t ev;
453 ev = LSCP_EVENT_DEVICE_MIDI;
454 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
455 ])
456 ac_device_midi_event=$ac_cv_device_midi_event
457 if test "x$ac_device_midi_event" = "xyes"; then
458 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
459 fi
460
461 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
462 if test "x$ac_max_voices" = "xyes"; then
463 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
464 fi
465
466 # Check for optional libraries.
467 if test "x$ac_libgig" = "xyes"; then
468 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
469 fi
470 if test "x$ac_libgig" = "xyes"; then
471 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
472 ac_cflags="$ac_cflags $GIG_CFLAGS"
473 ac_libs="$ac_libs $GIG_LIBS"
474 CFLAGS="$CFLAGS $GIG_CFLAGS"
475 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
476 LIBS="$LIBS $GIG_LIBS"
477 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
478 ac_libgig_setautoload="yes"
479 else
480 AC_MSG_WARN([*** GIG library not found (libgig).])
481 fi
482
483 # Check for round math function.
484 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
485 if test "x$ac_round" = "xyes"; then
486 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
487 fi
488
489
490 # Checks for header files.
491 AC_HEADER_STDC
492 AC_HEADER_SYS_WAIT
493 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
494
495 if test "x$ac_libgig" = "xyes"; then
496 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
497 if test "x$ac_libgig_sf2" = "xyes"; then
498 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
499 fi
500 fi
501
502 # Check for X11 unique/single instance.
503 if test "x$ac_xunique" = "xyes" -a "x$ac_qt4" = "xno"; then
504 PKG_CHECK_MODULES([QT5X11EXTRAS], [Qt5X11Extras], [ac_xunique="yes"], [ac_xunique="no"])
505 fi
506 if test "x$ac_xunique" = "xyes"; then
507 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if X11 unique/single instance is enabled.])
508 if test "x$ac_qt4" = "xno"; then
509 ac_qx11extras="x11extras"
510 fi
511 # Some recent distros (eg. fedora, debian) require this.
512 if test "x$ac_cv_lib_X11_main" = "xyes"; then
513 ac_libs="$ac_libs -lX11"
514 fi
515 fi
516 AC_SUBST(ac_qx11extras)
517
518 # Check for debugging stack-trace.
519 if test "x$ac_stacktrace" = "xyes"; then
520 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
521 fi
522
523 AC_SUBST(ac_cflags)
524 AC_SUBST(ac_ldflags)
525 AC_SUBST(ac_incpath)
526 AC_SUBST(ac_libs)
527
528
529 # Checks for typedefs, structures, and compiler characteristics.
530 # AC_C_CONST
531
532 # Checks for library functions.
533 AC_CHECK_FUNCS(system)
534
535 # Finally produce a configure header file and the makefiles.
536 AC_OUTPUT
537
538 # make clean > /dev/null 2>&1
539
540 # Output summary message
541
542 echo
543 echo " $PACKAGE_NAME $ac_build_version"
544 echo
545 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
546 echo
547 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
548 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
549 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
550 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
551 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
552 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
553 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
554 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
555 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
556 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
557 if test "x$ac_libgig" = "xyes"; then
558 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
559 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
560 fi
561 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
562 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
563 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
564 echo
565 echo " X11 Unique/Single instance . . . . . . . . . . . .: $ac_xunique"
566 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
567 echo
568 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
569 echo
570 echo "Now type 'make', followed by 'make install' as root."
571 echo

  ViewVC Help
Powered by ViewVC