/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3516 - (show annotations) (download)
Tue Jun 18 07:49:48 2019 UTC (4 years, 9 months ago) by capela
File size: 17244 byte(s)
- Configure updated to check for qtchooser availability.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.5.6, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^_]]*[[_v]]//i')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]\+/./g')
15 ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null)
16 if test "x$ac_cv_build_version_extra" != "xmaster"; then
17 ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]"
18 fi
19 else
20 ac_cv_build_version=$PACKAGE_VERSION
21 fi
22 ])
23 ac_build_version="$ac_cv_build_version"
24 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
25
26 # Sanitized version string.
27 AC_CACHE_VAL([ac_cv_version], [
28 ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/')
29 ])
30 ac_version="$ac_cv_version"
31 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
32 AC_SUBST(ac_version)
33
34 # Set default installation prefix.
35 AC_PREFIX_DEFAULT(/usr/local)
36 if test "x$prefix" = "xNONE"; then
37 prefix=$ac_default_prefix
38 fi
39 if test "x$exec_prefix" = "xNONE"; then
40 exec_prefix=$prefix
41 fi
42 eval ac_prefix=$prefix
43 AC_SUBST(ac_prefix)
44 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
45
46 # Set default installation directories.
47 eval ac_bindir=$bindir
48 AC_SUBST(ac_bindir)
49 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
50
51 eval ac_libdir=$libdir
52 AC_SUBST(ac_libdir)
53 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
54
55 eval datarootdir=$datarootdir
56 eval ac_datadir=$datadir
57 AC_SUBST(ac_datadir)
58 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
59
60 eval ac_mandir=$mandir
61 AC_SUBST(ac_mandir)
62 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
63
64
65 # Enable debugging argument option.
66 AC_ARG_ENABLE(debug,
67 AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
68 [ac_debug="$enableval"])
69
70 if test "x$ac_debug" = "xyes"; then
71 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
72 ac_stacktrace="yes"
73 ac_debug="debug"
74 else
75 ac_stacktrace="no"
76 ac_debug="release"
77 fi
78 AC_SUBST(ac_debug)
79
80
81 # Enable libgig availability.
82 AC_ARG_ENABLE(libgig,
83 AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
84 [ac_libgig="$enableval"],
85 [ac_libgig="yes"])
86
87 # Enable unique/single instance.
88 AC_ARG_ENABLE(xunique,
89 AS_HELP_STRING([--enable-xunique], [enable unique/single instance (default=yes)]),
90 [ac_xunique="$enableval"],
91 [ac_xunique="yes"])
92
93 # Enable debugger stack-trace option (assumes --enable-debug).
94 AC_ARG_ENABLE(stacktrace,
95 AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
96 [ac_stacktrace="$enableval"])
97
98
99 # Standard installation base dirs.
100 ac_path=$PATH
101 ac_with_paths=""
102
103 # Set for alternate Qt installation dir.
104 AC_ARG_WITH(qt,
105 AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]),
106 [ac_qt_path="$withval"], [ac_qt_path="no"])
107
108 if test "x$ac_qt_path" != "xno"; then
109 ac_path="$ac_qt_path/bin:$ac_path"
110 fi
111
112 # Set for alternate liblscp installation dir.
113 AC_ARG_WITH(liblscp,
114 AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
115 [ac_with_paths="$ac_with_paths $withval"])
116
117 # Set for alternate libgig installation dir.
118 AC_ARG_WITH(libgig,
119 AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
120 [ac_with_paths="$ac_with_paths $withval"])
121
122
123 # Honor user specified flags.
124 ac_cflags=$CFLAGS
125 ac_ldflags=$LDFLAGS
126
127
128 # Checks for programs.
129 AC_PROG_CPP
130 AC_PROG_CXX
131 AC_PROG_CXXCPP
132
133 # Checks for languages.
134 AC_LANG_CPLUSPLUS
135
136 # Check for pkg-config.
137 PKG_PROG_PKG_CONFIG
138
139 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
140 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
141 ac_cv_gxx_version_major=$($CC -dumpversion)
142 if test -n "$ac_cv_gxx_version_major"; then
143 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
144 fi
145 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
146 ])
147 ac_gxx_version_major=$ac_cv_gxx_version_major
148 if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then
149 CXXFLAGS="-std=c++11 $CXXFLAGS"
150 fi
151
152 # Check for proper flags.
153 ac_arch=$(uname -m)
154
155 # Check for install paths and alternatives...
156 ac_libdirs="lib"
157
158 if test "x$ac_arch" = "xx86_64"; then
159 ac_libdirs="$ac_libdirs lib64"
160 fi
161
162 CFLAGS="-fPIC $CFLAGS"
163 CPPFLAGS="-fPIC $CPPFLAGS"
164
165 # Prepend alternate dependencies paths.
166 for X in $ac_with_paths; do
167 if test -d $X/bin; then
168 ac_path="$X/bin:$ac_path"
169 fi
170 if test -d $X/include; then
171 CFLAGS="-I$X/include $CFLAGS "
172 CPPFLAGS="-I$X/include $CPPFLAGS"
173 ac_incpath="$X/include $ac_incpath"
174 fi
175 for Y in $ac_libdirs; do
176 if test -d $X/$Y; then
177 LIBS="-L$X/$Y $LIBS"
178 ac_libs="-L$X/$Y $ac_libs"
179 fi
180 done
181 done
182
183 # A common error message:
184 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
185
186 # Check for qtchooser availability.
187 AC_PATH_TOOL(ac_qtchooser, qtchooser, [no], $ac_path)
188 if test -x $ac_qtchooser; then
189 export QT_SELECT=5
190 fi
191
192 # Check for proper qmake path/version alternatives.
193 AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path)
194 if test "x$ac_qmake" = "xno"; then
195 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
196 ac_qmake=$ac_cv_qmake
197 fi
198
199 # Check for proper Qt major version.
200 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
201 ac_cv_qt_version_major=$($ac_qmake -query QT_VERSION | cut -d'.' -f1)
202 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
203 ])
204 ac_qt_version_major=$ac_cv_qt_version_major
205 if test $ac_qt_version_major -ne 5; then
206 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
207 ac_qmake=$ac_cv_qmake
208 fi
209
210 if test "x$ac_qmake" = "xno"; then
211 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
212 fi
213
214 # Check for proper Qt install path.
215 AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [
216 ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS)
217 ])
218 ac_qt_install_path=$ac_cv_qt_install_path
219 if test -d $ac_qt_install_path; then
220 ac_path="$ac_qt_install_path:$ac_path"
221 fi
222
223 # Check it again, now with updated PATH, just in case...
224 AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path)
225 ac_qmake=$ac_cv_qmake
226 if test "x$ac_qmake" = "xno"; then
227 AC_MSG_ERROR([qmake $ac_errmsg])
228 fi
229
230 AC_SUBST(ac_qmake)
231
232 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
233 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
234 ])
235 ac_qt_install_headers=$ac_cv_qt_install_headers
236 if test -d $ac_qt_install_headers; then
237 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
238 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
239 ac_incpath="$ac_qt_install_headers $ac_incpath"
240 fi
241
242 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
243 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
244 ])
245 ac_qt_install_libs=$ac_cv_qt_install_libs
246 if test -d $ac_qt_install_libs; then
247 LIBS="-L$ac_qt_install_libs $LIBS"
248 ac_libs="-L$ac_qt_install_libs $ac_libs"
249 fi
250
251 # Finally, check for proper Qt version.
252 AC_CACHE_CHECK([for Qt library version >= 5.1],
253 ac_cv_qtversion, [
254 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
255 #if QT_VERSION < 0x050100
256 #error Qt library 5.1 or greater required.
257 #endif
258 ], ac_cv_qtversion="yes", [
259 echo "no; Qt 5.1 or greater is required"
260 exit 1
261 ])
262 ])
263
264 # Check for Qt moc utility.
265 AC_PATH_TOOL(ac_moc, moc, [no], $ac_path)
266 if test "x$ac_moc" = "xno"; then
267 AC_MSG_ERROR([moc $ac_errmsg])
268 fi
269 AC_SUBST(ac_moc)
270
271 # Check for Qt uic utility.
272 AC_PATH_TOOL(ac_uic, uic, [no], $ac_path)
273 if test "x$ac_uic" = "xno"; then
274 AC_MSG_ERROR([uic $ac_errmsg])
275 fi
276 AC_SUBST(ac_uic)
277
278 # Check for Qt lupdate utility.
279 AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path)
280 if test "x$ac_lupdate" = "xno"; then
281 AC_MSG_ERROR([lupdate $ac_errmsg])
282 fi
283 AC_SUBST(ac_lupdate)
284
285 # Check for Qt lrelease utility.
286 AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path)
287 if test "x$ac_release" = "xno"; then
288 AC_MSG_ERROR([lrelease $ac_errmsg])
289 fi
290 AC_SUBST(ac_lrelease)
291
292
293 # Checks for libraries.
294 AC_CHECK_LIB(m, main)
295 AC_CHECK_LIB(X11, main)
296 AC_CHECK_LIB(Xext, main)
297
298 # Check for round math function.
299 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
300 if test "x$ac_round" = "xyes"; then
301 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
302 fi
303
304 # Check for mandatory libraries.
305 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
306 if test "x$ac_liblscp" = "xyes"; then
307 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
308 ac_cflags="$ac_cflags $LSCP_CFLAGS"
309 ac_libs="$ac_libs $LSCP_LIBS"
310 CFLAGS="$CFLAGS $LSCP_CFLAGS"
311 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
312 LIBS="$LIBS $LSCP_LIBS"
313 else
314 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
315 fi
316
317 case "{$host}" in
318 *mingw*)
319 ac_libs="$ac_libs -lws2_32"
320 LIBS="$LIBS -lws2_32"
321 ;;
322 esac
323
324 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
325 ac_cv_instrument_name, [
326 AC_TRY_COMPILE([#include "lscp/client.h"], [
327 lscp_channel_info_t info;
328 info.instrument_name = 0;
329 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
330 ])
331 ac_instrument_name=$ac_cv_instrument_name
332 if test "x$ac_instrument_name" = "xyes"; then
333 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
334 fi
335
336 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
337 ac_cv_mute_solo, [
338 AC_TRY_COMPILE([#include "lscp/client.h"], [
339 lscp_channel_info_t info;
340 info.mute = 0;
341 info.solo = 0;
342 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
343 ])
344 ac_mute_solo=$ac_cv_mute_solo
345 if test "x$ac_mute_solo" = "xyes"; then
346 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
347 fi
348 if test "x$ac_mute_solo" = "xyes"; then
349 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
350 fi
351 if test "x$ac_mute_solo" = "xyes"; then
352 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
353 fi
354
355 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
356 if test "x$ac_midi_instrument" = "xyes"; then
357 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
358 fi
359
360 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
361 if test "x$ac_fxsend" = "xyes"; then
362 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
363 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
364 ac_cv_fxsend_level, [
365 AC_TRY_COMPILE([#include "lscp/client.h"], [
366 lscp_fxsend_info_t info;
367 info.level = 0.0f;
368 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
369 ])
370 ac_fxsend_level=$ac_cv_fxsend_level
371 if test "x$ac_fxsend_level" = "xyes"; then
372 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
373 fi
374 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
375 if test "x$ac_fxsend_rename" = "xyes"; then
376 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
377 fi
378 fi
379
380 AC_CACHE_CHECK([for audio_routing array type],
381 ac_cv_audio_routing, [
382 AC_TRY_COMPILE([#include "lscp/client.h"], [
383 lscp_channel_info_t info;
384 char ch = info.audio_routing[0][0];
385 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
386 ])
387 ac_audio_routing=$ac_cv_audio_routing
388 if test "x$ac_audio_routing" = "xyes"; then
389 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
390 fi
391
392 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
393 if test "x$ac_volume" = "xyes"; then
394 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
395 fi
396
397 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
398 if test "x$ac_edit_instrument" = "xyes"; then
399 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
400 fi
401
402 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
403 ac_cv_channel_midi_event, [
404 AC_TRY_COMPILE([
405 #include "lscp/client.h"
406 #include "lscp/event.h"
407 ], [
408 lscp_event_t ev;
409 ev = LSCP_EVENT_CHANNEL_MIDI;
410 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
411 ])
412 ac_channel_midi_event=$ac_cv_channel_midi_event
413 if test "x$ac_channel_midi_event" = "xyes"; then
414 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
415 fi
416
417 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
418 ac_cv_device_midi_event, [
419 AC_TRY_COMPILE([
420 #include "lscp/client.h"
421 #include "lscp/event.h"
422 ], [
423 lscp_event_t ev;
424 ev = LSCP_EVENT_DEVICE_MIDI;
425 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
426 ])
427 ac_device_midi_event=$ac_cv_device_midi_event
428 if test "x$ac_device_midi_event" = "xyes"; then
429 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
430 fi
431
432 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
433 if test "x$ac_max_voices" = "xyes"; then
434 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
435 fi
436
437 # Check for optional libraries.
438 if test "x$ac_libgig" = "xyes"; then
439 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
440 fi
441 if test "x$ac_libgig" = "xyes"; then
442 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
443 ac_cflags="$ac_cflags $GIG_CFLAGS"
444 ac_libs="$ac_libs $GIG_LIBS"
445 CFLAGS="$CFLAGS $GIG_CFLAGS"
446 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
447 LIBS="$LIBS $GIG_LIBS"
448 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
449 ac_libgig_setautoload="yes"
450 else
451 AC_MSG_WARN([*** GIG library not found (libgig).])
452 fi
453
454 # Check for round math function.
455 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
456 if test "x$ac_round" = "xyes"; then
457 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
458 fi
459
460
461 # Checks for header files.
462 AC_HEADER_STDC
463 AC_HEADER_SYS_WAIT
464 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
465
466 if test "x$ac_libgig" = "xyes"; then
467 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
468 if test "x$ac_libgig_sf2" = "xyes"; then
469 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
470 fi
471 fi
472
473 # Check for unique/single instance support.
474 if test "x$ac_xunique" = "xyes"; then
475 PKG_CHECK_MODULES([QT5NETWORK], [Qt5Network], [ac_qt5network="yes"], [ac_qt5network="no"])
476 if test "x$ac_qt5network" = "xyes"; then
477 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if unique/single instance is enabled.])
478 ac_qnetwork="network"
479 fi
480 fi
481 AC_SUBST(ac_qnetwork)
482
483 # Check for debugging stack-trace.
484 if test "x$ac_stacktrace" = "xyes"; then
485 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
486 fi
487
488 AC_SUBST(ac_cflags)
489 AC_SUBST(ac_ldflags)
490 AC_SUBST(ac_incpath)
491 AC_SUBST(ac_libs)
492
493
494 # Checks for typedefs, structures, and compiler characteristics.
495 # AC_C_CONST
496
497 # Checks for library functions.
498 AC_CHECK_FUNCS(system)
499
500 # Finally produce a configure header file and the makefiles.
501 AC_OUTPUT
502
503 # make clean > /dev/null 2>&1
504
505 # Output summary message
506
507 echo
508 echo " $PACKAGE_NAME $ac_build_version"
509 echo
510 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
511 echo
512 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
513 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
514 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
515 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
516 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
517 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
518 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
519 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
520 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
521 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
522 if test "x$ac_libgig" = "xyes"; then
523 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
524 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
525 fi
526 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
527 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
528 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
529 echo
530 echo " Unique/Single instance support . . . . . . . . . .: $ac_xunique"
531 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
532 echo
533 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
534 echo
535 echo "Now type 'make', followed by 'make install' as root."
536 echo

  ViewVC Help
Powered by ViewVC