/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 2848 - (show annotations) (download)
Sat Oct 3 15:48:18 2015 UTC (4 years, 2 months ago) by capela
File size: 15495 byte(s)
* Messages standard output capture has been improved again, now
  in both ways a non-blocking pipe may get. (EXPERIMENTAL)
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.3.1.8, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri src/qsampler.desktop)
7
8 # Set default installation prefix.
9 AC_PREFIX_DEFAULT(/usr/local)
10 ac_prefix=$prefix
11 if test "x$ac_prefix" = "xNONE"; then
12 ac_prefix=$ac_default_prefix
13 fi
14 AC_SUBST(ac_prefix)
15 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
16
17 # Enable debugging argument option.
18 AC_ARG_ENABLE(debug,
19 AC_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
20 [ac_debug="$enableval"])
21
22 if test "x$ac_debug" = "xyes"; then
23 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
24 ac_stacktrace="yes"
25 ac_debug="debug"
26 else
27 ac_stacktrace="no"
28 ac_debug="release"
29 fi
30 AC_SUBST(ac_debug)
31
32
33 # Enable Qt4/5 availability.
34 AC_ARG_ENABLE(qt4,
35 AC_HELP_STRING([--enable-qt4], [enable Qt4 build (default=no)]),
36 [ac_qt4="$enableval"],
37 [ac_qt4="no"])
38
39 AC_ARG_ENABLE(qt5,
40 AC_HELP_STRING([--enable-qt5], [enable Qt5 build (default=yes)]),
41 [ac_qt5="$enableval"],
42 [ac_qt5="yes"])
43
44
45
46 # Enable libgig availability.
47 AC_ARG_ENABLE(libgig,
48 AC_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
49 [ac_libgig="$enableval"],
50 [ac_libgig="yes"])
51
52 # Enable X11 unique/single instance.
53 AC_ARG_ENABLE(xunique,
54 AC_HELP_STRING([--enable-xunique], [enable X11 unique/single instance (default=yes)]),
55 [ac_xunique="$enableval"],
56 [ac_xunique="yes"])
57
58 # Enable debugger stack-trace option (assumes --enable-debug).
59 AC_ARG_ENABLE(stacktrace,
60 AC_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
61 [ac_stacktrace="$enableval"])
62
63
64 # Standard installation base dirs.
65 if test "$cross_compiling" = yes; then
66 ac_with_paths=""
67 else
68 ac_with_paths="/usr /usr/local"
69 fi
70
71 # Set for alternate Qt4/5 installation dir.
72 AC_ARG_WITH(qt4,
73 AC_HELP_STRING([--with-qt4=PATH], [use alternate Qt4 install path]),
74 [ac_qt4_path="$withval"], [ac_qt4_path="no"])
75
76 AC_ARG_WITH(qt5,
77 AC_HELP_STRING([--with-qt5=PATH], [use alternate Qt5 install path]),
78 [ac_qt5_path="$withval"], [ac_qt5_path="no"])
79
80 if test "x$ac_qt4_path" != "xno"; then
81 ac_with_paths="$ac_with_paths $ac_qt4_path"
82 ac_qt4="yes"
83 fi
84
85 if test "x$ac_qt5_path" != "xno"; then
86 ac_with_paths="$ac_with_paths $ac_qt5_path"
87 ac_qt5="yes"
88 fi
89
90 if test "x$ac_qt5" = "xno"; then
91 ac_qt4="yes"
92 fi
93 if test "x$ac_qt4" = "xyes"; then
94 ac_qt5="no"
95 fi
96
97 # Set for alternate liblscp installation dir.
98 AC_ARG_WITH(liblscp,
99 AC_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
100 [ac_with_paths="$ac_with_paths $withval"])
101
102 # Set for alternate libgig installation dir.
103 AC_ARG_WITH(libgig,
104 AC_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
105 [ac_with_paths="$ac_with_paths $withval"])
106
107
108 # Honor user specified flags.
109 ac_cflags=$CFLAGS
110 ac_ldflags=$LDFLAGS
111
112
113 # Checks for programs.
114 AC_PROG_CC
115 AC_PROG_CPP
116 AC_PROG_CXX
117 AC_PROG_CXXCPP
118 AC_PROG_GCC_TRADITIONAL
119
120 # Checks for languages.
121 AC_LANG_C
122 AC_LANG_CPLUSPLUS
123
124 PKG_PROG_PKG_CONFIG
125
126 # Check for proper flags.
127 ac_arch=`uname -m`
128
129 # Check for install paths and alternatives...
130 ac_libdirs="lib"
131
132 if test "x$ac_arch" = "xx86_64"; then
133 ac_libdirs="$ac_libdirs lib64"
134 fi
135
136 CFLAGS="-fPIC $CFLAGS"
137 CPPFLAGS="-fPIC $CPPFLAGS"
138
139 # Prepend alternate dependencies paths.
140 ac_path=$PATH
141
142 for X in $ac_with_paths; do
143 if test -d $X/bin; then
144 ac_path="$X/bin:$ac_path"
145 fi
146 if test -d $X/include; then
147 CFLAGS="-I$X/include $CFLAGS "
148 CPPFLAGS="-I$X/include $CPPFLAGS"
149 ac_incpath="$X/include $ac_incpath"
150 fi
151 for Y in $ac_libdirs; do
152 if test -d $X/$Y; then
153 LIBS="-L$X/$Y $LIBS"
154 ac_libs="-L$X/$Y $ac_libs"
155 fi
156 done
157 done
158
159 # A common error message:
160 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
161
162 if test "x$ac_qt4" = "xyes"; then
163 AC_PATH_PROG(ac_qmake, qmake-qt4, [no], $ac_path)
164 fi
165 if test "x$ac_qt5" = "xyes"; then
166 AC_PATH_PROG(ac_qmake, qmake-qt5, [no], $ac_path)
167 fi
168 if test "x$ac_qmake" = "xno"; then
169 AC_PATH_PROG(ac_cv_qmake, qmake, [no], $ac_path)
170 ac_qmake=$ac_cv_qmake
171 fi
172 if test "x$ac_qmake" = "xno"; then
173 AC_MSG_ERROR([qmake $ac_errmsg])
174 fi
175
176 # Check for proper Qt4/5 major version.
177 ac_qt_version_major=`$ac_qmake -query QT_VERSION | cut -d. -f1`
178 if test "x$ac_qt4" = "xyes" -a "x$ac_qt_version_major" != "x4"; then
179 AC_MSG_ERROR([qmake-qt4 $ac_errmsg (qt4-devel)])
180 fi
181 if test "x$ac_qt5" = "xyes" -a "x$ac_qt_version_major" != "x5"; then
182 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
183 fi
184
185 ac_qt_install_bins=`$ac_qmake -query QT_INSTALL_BINS`
186 if test -d $ac_qt_install_bins; then
187 ac_path="$ac_qt_install_bins:$ac_path"
188 fi
189
190 # Check it again, now with updated PATH, just in case...
191 AC_PATH_PROG(ac_cv_qmake, qmake, [no], $ac_path)
192 ac_qmake=$ac_cv_qmake
193 if test "x$ac_qmake" = "xno"; then
194 AC_MSG_ERROR([qmake $ac_errmsg])
195 fi
196
197 AC_SUBST(ac_qmake)
198
199 ac_qt_install_headers=`$ac_qmake -query QT_INSTALL_HEADERS`
200 if test -d $ac_qt_install_headers; then
201 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
202 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
203 ac_incpath="$ac_qt_install_headers $ac_incpath"
204 fi
205
206 ac_qt_install_libs=`$ac_qmake -query QT_INSTALL_LIBS`
207 if test -d $ac_qt_install_libs; then
208 LIBS="-L$ac_qt_install_libs $LIBS"
209 ac_libs="-L$ac_qt_install_libs $ac_libs"
210 fi
211
212 # Check for proper Qt4/5 version.
213 if test "x$ac_qt4" = "xyes"; then
214 AC_CACHE_CHECK([for Qt library version >= 4.4],
215 ac_cv_qtversion, [
216 AC_TRY_LINK([#include "QtCore/qglobal.h"], [
217 #if QT_VERSION < 0x040400 || QT_VERSION >= 0x050000
218 #error Qt library 4.4 or greater required.
219 #endif
220 ], ac_cv_qtversion="yes", [
221 echo "no; Qt 4.4 or greater is required"
222 exit 1
223 ])
224 ])
225 fi
226
227 if test "x$ac_qt5" = "xyes"; then
228 AC_CACHE_CHECK([for Qt library version >= 5.1],
229 ac_cv_qtversion, [
230 AC_TRY_LINK([#include "QtCore/qglobal.h"], [
231 #if QT_VERSION < 0x050100 || QT_VERSION >= 0x060000
232 #error Qt library 5.1 or greater required.
233 #endif
234 ], ac_cv_qtversion="yes", [
235 echo "no; Qt 5.1 or greater is required"
236 exit 1
237 ])
238 ])
239 fi
240
241 # Check for Qt moc utility.
242 AC_PATH_PROG(ac_moc, moc, [no], $ac_path)
243 if test "x$ac_moc" = "xno"; then
244 AC_MSG_ERROR([moc $ac_errmsg])
245 fi
246 AC_SUBST(ac_moc)
247
248 # Check for Qt uic utility.
249 AC_PATH_PROG(ac_uic, uic, [no], $ac_path)
250 if test "x$ac_uic" = "xno"; then
251 AC_MSG_ERROR([uic $ac_errmsg])
252 fi
253 AC_SUBST(ac_uic)
254
255 # Check for Qt lupdate utility.
256 AC_PATH_PROG(ac_lupdate, lupdate, [no], $ac_path)
257 if test "x$ac_lupdate" = "xno"; then
258 AC_MSG_ERROR([lupdate $ac_errmsg])
259 fi
260 AC_SUBST(ac_lupdate)
261
262 # Check for Qt lrelease utility.
263 AC_PATH_PROG(ac_lrelease, lrelease, [no], $ac_path)
264 if test "x$ac_release" = "xno"; then
265 AC_MSG_ERROR([lrelease $ac_errmsg])
266 fi
267 AC_SUBST(ac_lrelease)
268
269
270 # Checks for libraries.
271 AC_CHECK_LIB(m, main)
272 AC_CHECK_LIB(X11, main)
273 AC_CHECK_LIB(Xext, main)
274
275 # Check for round math function.
276 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
277 if test "x$ac_round" = "xyes"; then
278 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
279 fi
280
281 # Check for mandatory libraries.
282 AC_CHECK_LIB(lscp, main, [ac_liblscp="yes"], [ac_liblscp="no"])
283 if test "x$ac_liblscp" = "xno"; then
284 AC_MSG_ERROR([LSCP library not found.])
285 fi
286 ac_libs="$ac_libs -llscp"
287 case "{$host}" in
288 *mingw*)
289 ac_libs="$ac_libs -lws2_32"
290 LIBS="$LIBS -lws2_32"
291 ;;
292 esac
293
294 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
295 ac_cv_instrument_name, [
296 AC_TRY_COMPILE([#include "lscp/client.h"], [
297 lscp_channel_info_t info;
298 info.instrument_name = 0;
299 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
300 ])
301 ac_instrument_name=$ac_cv_instrument_name
302 if test "x$ac_instrument_name" = "xyes"; then
303 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
304 fi
305
306 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
307 ac_cv_mute_solo, [
308 AC_TRY_COMPILE([#include "lscp/client.h"], [
309 lscp_channel_info_t info;
310 info.mute = 0;
311 info.solo = 0;
312 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
313 ])
314 ac_mute_solo=$ac_cv_mute_solo
315 if test "x$ac_mute_solo" = "xyes"; then
316 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
317 fi
318 if test "x$ac_mute_solo" = "xyes"; then
319 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
320 fi
321 if test "x$ac_mute_solo" = "xyes"; then
322 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
323 fi
324
325 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
326 if test "x$ac_midi_instrument" = "xyes"; then
327 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
328 fi
329
330 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
331 if test "x$ac_fxsend" = "xyes"; then
332 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
333 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
334 ac_cv_fxsend_level, [
335 AC_TRY_COMPILE([#include "lscp/client.h"], [
336 lscp_fxsend_info_t info;
337 info.level = 0.0f;
338 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
339 ])
340 ac_fxsend_level=$ac_cv_fxsend_level
341 if test "x$ac_fxsend_level" = "xyes"; then
342 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
343 fi
344 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
345 if test "x$ac_fxsend_rename" = "xyes"; then
346 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
347 fi
348 fi
349
350 AC_CACHE_CHECK([for audio_routing array type],
351 ac_cv_audio_routing, [
352 AC_TRY_COMPILE([#include "lscp/client.h"], [
353 lscp_channel_info_t info;
354 char ch = info.audio_routing[0][0];
355 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
356 ])
357 ac_audio_routing=$ac_cv_audio_routing
358 if test "x$ac_audio_routing" = "xyes"; then
359 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
360 fi
361
362 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
363 if test "x$ac_volume" = "xyes"; then
364 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
365 fi
366
367 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
368 if test "x$ac_edit_instrument" = "xyes"; then
369 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
370 fi
371
372 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
373 ac_cv_channel_midi_event, [
374 AC_TRY_COMPILE([
375 #include "lscp/client.h"
376 #include "lscp/event.h"
377 ], [
378 lscp_event_t ev;
379 ev = LSCP_EVENT_CHANNEL_MIDI;
380 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
381 ])
382 ac_channel_midi_event=$ac_cv_channel_midi_event
383 if test "x$ac_channel_midi_event" = "xyes"; then
384 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
385 fi
386
387 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
388 ac_cv_device_midi_event, [
389 AC_TRY_COMPILE([
390 #include "lscp/client.h"
391 #include "lscp/event.h"
392 ], [
393 lscp_event_t ev;
394 ev = LSCP_EVENT_DEVICE_MIDI;
395 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
396 ])
397 ac_device_midi_event=$ac_cv_device_midi_event
398 if test "x$ac_device_midi_event" = "xyes"; then
399 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
400 fi
401
402 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
403 if test "x$ac_max_voices" = "xyes"; then
404 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
405 fi
406
407 # Check for optional libraries.
408 if test "x$ac_libgig" = "xyes"; then
409 PKG_CHECK_MODULES(LIBGIG, gig >= 3.3.0, [ac_libgig="yes"], [ac_libgig="no"])
410 if test "x$ac_libgig" = "xyes"; then
411 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
412 AC_SUBST(LIBGIG_CFLAGS)
413 AC_SUBST(LIBGIG_LIBS)
414 ac_cflags="$ac_cflags $LIBGIG_CFLAGS"
415 ac_libs="$ac_libs $LIBGIG_LIBS"
416 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
417 ac_libgig_setautoload="yes"
418 fi
419 fi
420
421 # Check for round math function.
422 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
423 if test "x$ac_round" = "xyes"; then
424 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
425 fi
426
427 # Check for X11 unique/single instance.
428 if test "x$ac_xunique" = "xyes"; then
429 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if X11 unique/single instance is enabled.])
430 fi
431
432 # Check for debugging stack-trace.
433 if test "x$ac_stacktrace" = "xyes"; then
434 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
435 fi
436
437 # Some recent distros (eg. fedora, debian) require this.
438 if test "x$ac_cv_lib_X11_main" = "xyes"; then
439 ac_libs="$ac_libs -lX11"
440 fi
441
442 AC_SUBST(ac_libs)
443 AC_SUBST(ac_incpath)
444 AC_SUBST(ac_cflags)
445 AC_SUBST(ac_ldflags)
446
447 # Checks for header files.
448 AC_HEADER_STDC
449 AC_HEADER_SYS_WAIT
450 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
451
452 AC_CHECK_HEADER(lscp/client.h, [ac_lscp_h="yes"], [ac_lscp_h="no"])
453 if test "x$ac_lscp_h" = "xno"; then
454 AC_MSG_ERROR([LSCP headers not found.])
455 fi
456
457 if test "x$ac_libgig" = "xyes"; then
458 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
459 if test "x$ac_libgig_sf2" = "xyes"; then
460 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
461 fi
462 fi
463
464 # Checks for typedefs, structures, and compiler characteristics.
465 # AC_C_CONST
466
467 # Checks for library functions.
468 AC_CHECK_FUNCS(system)
469
470 # Finally produce a configure header file and the makefiles.
471 AC_OUTPUT
472
473 # make clean > /dev/null 2>&1
474
475 # Output summary message
476
477 echo
478 echo " $PACKAGE_NAME $PACKAGE_VERSION"
479 echo
480 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
481 echo
482 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
483 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
484 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
485 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
486 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
487 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
488 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
489 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
490 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
491 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
492 if test "x$ac_libgig" = "xyes"; then
493 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
494 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
495 fi
496 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
497 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
498 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
499 echo
500 echo " X11 Unique/Single instance . . . . . . . . . . . .: $ac_xunique"
501 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
502 echo
503 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
504 echo
505 echo "Now type 'make', followed by 'make install' as root."
506 echo

  ViewVC Help
Powered by ViewVC