/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3861 - (show annotations) (download)
Mon Mar 1 15:38:42 2021 UTC (3 years ago) by capela
File size: 19215 byte(s)
- Fixed messages stdout-buffer flush.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.9.2, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^0-9]]\+//')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]\+/./g')
15 ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null)
16 if test "x$ac_cv_build_version_extra" != "xmaster"; then
17 ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]"
18 fi
19 else
20 ac_cv_build_version=$PACKAGE_VERSION
21 fi
22 ])
23 ac_build_version="$ac_cv_build_version"
24 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
25
26 # Sanitized version string.
27 AC_CACHE_VAL([ac_cv_version], [
28 ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/')
29 ])
30 ac_version="$ac_cv_version"
31 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
32 AC_SUBST(ac_version)
33
34 # Set default installation prefix.
35 AC_PREFIX_DEFAULT(/usr/local)
36 if test "x$prefix" = "xNONE"; then
37 prefix=$ac_default_prefix
38 fi
39 if test "x$exec_prefix" = "xNONE"; then
40 exec_prefix=$prefix
41 fi
42 eval ac_prefix=$prefix
43 AC_SUBST(ac_prefix)
44 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
45
46 # Set default installation directories.
47 eval ac_bindir=$bindir
48 AC_SUBST(ac_bindir)
49 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
50
51 eval ac_libdir=$libdir
52 AC_SUBST(ac_libdir)
53 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
54
55 eval datarootdir=$datarootdir
56 eval ac_datadir=$datadir
57 AC_SUBST(ac_datadir)
58 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
59
60 eval ac_mandir=$mandir
61 AC_SUBST(ac_mandir)
62 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
63
64
65 # Enable debugging argument option.
66 AC_ARG_ENABLE(debug,
67 AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
68 [ac_debug="$enableval"])
69
70 if test "x$ac_debug" = "xyes"; then
71 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
72 ac_stacktrace="yes"
73 ac_debug="debug"
74 else
75 ac_stacktrace="no"
76 ac_debug="release"
77 fi
78 AC_SUBST(ac_debug)
79
80
81 # Enable libgig availability.
82 AC_ARG_ENABLE(libgig,
83 AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
84 [ac_libgig="$enableval"],
85 [ac_libgig="yes"])
86
87 # Enable unique/single instance.
88 AC_ARG_ENABLE(xunique,
89 AS_HELP_STRING([--enable-xunique], [enable unique/single instance (default=yes)]),
90 [ac_xunique="$enableval"],
91 [ac_xunique="yes"])
92
93 # Enable debugger stack-trace option (assumes --enable-debug).
94 AC_ARG_ENABLE(stacktrace,
95 AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
96 [ac_stacktrace="$enableval"])
97
98
99 # Standard installation base dirs.
100 ac_path=$PATH
101 ac_pkg_config_path=$PKG_CONFIG_PATH
102 ac_with_paths=""
103
104 # Set for alternate Qt installation dir.
105 AC_ARG_WITH(qt,
106 AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]),
107 [ac_qt_path="$withval"], [ac_qt_path="no"])
108
109 if test "x$ac_qt_path" != "xno"; then
110 ac_path="$ac_qt_path/bin:$ac_path"
111 ac_pkg_config_path="$ac_qt_path/lib/pkgconfig:$ac_pkg_config_path"
112 fi
113
114 # Set for alternate liblscp installation dir.
115 AC_ARG_WITH(liblscp,
116 AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
117 [ac_with_paths="$ac_with_paths $withval"])
118
119 # Set for alternate libgig installation dir.
120 AC_ARG_WITH(libgig,
121 AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
122 [ac_with_paths="$ac_with_paths $withval"])
123
124
125 # Honor user specified flags.
126 ac_cflags=$CFLAGS
127 ac_ldflags=$LDFLAGS
128
129
130 # Checks for programs.
131 AC_PROG_CPP
132 AC_PROG_CXX
133 AC_PROG_CXXCPP
134
135 # Checks for languages.
136 AC_LANG_CPLUSPLUS
137
138 # Check for pkg-config.
139 PKG_PROG_PKG_CONFIG
140
141 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
142 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
143 ac_cv_gxx_version_major=$($CC -dumpversion)
144 if test -n "$ac_cv_gxx_version_major"; then
145 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
146 fi
147 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
148 ])
149 ac_gxx_version_major=$ac_cv_gxx_version_major
150 if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then
151 CXXFLAGS="-std=c++11 $CXXFLAGS"
152 ac_cflags="-std=c++11 $ac_cflags"
153 elif test $ac_gxx_version_major -ge 6 -a $ac_gxx_version_major -lt 11; then
154 CXXFLAGS="-std=c++17 $CXXFLAGS"
155 ac_cflags="-std=c++17 $ac_cflags"
156 fi
157
158 # Check for proper flags.
159 ac_arch=$(uname -m)
160
161 # Check for install paths and alternatives...
162 ac_libdirs="lib"
163
164 if test "x$ac_arch" = "xx86_64"; then
165 ac_libdirs="$ac_libdirs lib64"
166 fi
167
168 CFLAGS="-fPIC $CFLAGS"
169 CPPFLAGS="-fPIC $CPPFLAGS"
170
171 # Prepend alternate dependencies paths.
172 for X in $ac_with_paths; do
173 if test -d $X/bin; then
174 ac_path="$X/bin:$ac_path"
175 fi
176 if test -d $X/include; then
177 CFLAGS="-I$X/include $CFLAGS "
178 CPPFLAGS="-I$X/include $CPPFLAGS"
179 ac_incpath="$X/include $ac_incpath"
180 fi
181 for Y in $ac_libdirs; do
182 if test -d $X/$Y; then
183 LIBS="-L$X/$Y $LIBS"
184 ac_libs="-L$X/$Y $ac_libs"
185 if test -d $X/$Y/pkgconfig; then
186 ac_pkg_config_path="$X/$Y/pkgconfig:$ac_pkg_config_path"
187 fi
188 fi
189 done
190 done
191
192 # Set pkg-config path.
193 if test -n "$ac_pkg_config_path"; then
194 export PKG_CONFIG_PATH=$ac_pkg_config_path
195 fi
196
197
198 # A common error message:
199 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
200
201 # Check for qtchooser availability.
202 AC_PATH_TOOL(ac_qtchooser, qtchooser, [no], $ac_path)
203 if test -x $ac_qtchooser; then
204 export QT_SELECT=5
205 fi
206
207 # Check for proper qmake path/version alternatives.
208 AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path)
209 if test "x$ac_qmake" = "xno"; then
210 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
211 ac_qmake=$ac_cv_qmake
212 fi
213 if test "x$ac_qmake" = "xno"; then
214 AC_PATH_TOOL(ac_cv_qmake, qmake-qt6, [no], $ac_path)
215 ac_qmake=$ac_cv_qmake
216 fi
217
218 # Check for proper Qt major version.
219 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
220 ac_cv_qt_version_major=$($ac_qmake -query QT_VERSION | cut -d'.' -f1)
221 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
222 ])
223 ac_qt_version_major=$ac_cv_qt_version_major
224 if test "x$ac_qmake" = "xno"; then
225 if test $ac_qt_version_major -lt 6; then
226 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
227 else
228 AC_MSG_ERROR([qmake-qt6 $ac_errmsg (qt6-devel)])
229 fi
230 fi
231
232 # Check for proper Qt install path.
233 AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [
234 ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS)
235 ])
236 ac_qt_install_path=$ac_cv_qt_install_path
237 if test -d $ac_qt_install_path; then
238 ac_path="$ac_qt_install_path:$ac_path"
239 fi
240
241 # Check it again, now with updated PATH, just in case...
242 AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path)
243 ac_qmake=$ac_cv_qmake
244 if test "x$ac_qmake" = "xno"; then
245 AC_MSG_ERROR([qmake $ac_errmsg])
246 fi
247
248 AC_SUBST(ac_qmake)
249
250 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
251 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
252 ])
253 ac_qt_install_headers=$ac_cv_qt_install_headers
254 if test -d $ac_qt_install_headers; then
255 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
256 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
257 ac_incpath="$ac_qt_install_headers $ac_incpath"
258 fi
259
260 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
261 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
262 ])
263 ac_qt_install_libs=$ac_cv_qt_install_libs
264 if test -d $ac_qt_install_libs; then
265 LIBS="-L$ac_qt_install_libs $LIBS"
266 ac_libs="-L$ac_qt_install_libs $ac_libs"
267 fi
268
269 # Finally, check for proper Qt version.
270 AC_CACHE_CHECK([for Qt library version >= 5.1],
271 ac_cv_qtversion, [
272 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
273 #if QT_VERSION < 0x050100
274 #error Qt library 5.1 or greater required.
275 #endif
276 ], ac_cv_qtversion="yes", [
277 echo "no; Qt 5.1 or greater is required"
278 exit 1
279 ])
280 ])
281
282 # Check for Qt moc utility.
283 AC_PATH_TOOL(ac_moc, moc, [no], $ac_path)
284 if test "x$ac_moc" = "xno"; then
285 AC_MSG_ERROR([moc $ac_errmsg])
286 fi
287 AC_SUBST(ac_moc)
288
289 # Check for Qt uic utility.
290 AC_PATH_TOOL(ac_uic, uic, [no], $ac_path)
291 if test "x$ac_uic" = "xno"; then
292 AC_MSG_ERROR([uic $ac_errmsg])
293 fi
294 AC_SUBST(ac_uic)
295
296
297 # Check for Qt lupdate utility.
298 AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path)
299 if test "x$ac_lupdate" = "xno"; then
300 if test $ac_qt_version_major -lt 6; then
301 AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt5, [no], $ac_path)
302 else
303 AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt6, [no], $ac_path)
304 fi
305 if test "x$ac_cv_lupdate" = "xno"; then
306 if test $ac_qt_version_major -lt 6; then
307 AC_MSG_ERROR([lupdate $ac_errmsg (qt5-linguist)])
308 else
309 AC_MSG_ERROR([lupdate $ac_errmsg (qt6-linguist)])
310 fi
311 else
312 ac_lupdate=$ac_cv_lupdate;
313 fi
314 fi
315 AC_SUBST(ac_lupdate)
316
317 # Check for Qt lrelease utility.
318 AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path)
319 if test "x$ac_lrelease" = "xno"; then
320 if test $ac_qt_version_major -lt 6; then
321 AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt5, [no], $ac_path)
322 else
323 AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt6, [no], $ac_path)
324 fi
325 if test "x$ac_cv_lrelease" = "xno"; then
326 if test $ac_qt_version_major -lt 6; then
327 AC_MSG_ERROR([lrelease $ac_errmsg (qt5-linguist)])
328 else
329 AC_MSG_ERROR([lrelease $ac_errmsg (qt6-linguist)])
330 fi
331 else
332 ac_lrelease=$ac_cv_lrelease;
333 fi
334 fi
335 AC_SUBST(ac_lrelease)
336
337
338 # Checks for libraries.
339 AC_CHECK_LIB(m, main)
340 AC_CHECK_LIB(X11, main)
341 AC_CHECK_LIB(Xext, main)
342
343 # Check for round math function.
344 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
345 if test "x$ac_round" = "xyes"; then
346 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
347 fi
348
349 # Check for mandatory libraries.
350 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
351 if test "x$ac_liblscp" = "xyes"; then
352 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
353 ac_cflags="$ac_cflags $LSCP_CFLAGS"
354 ac_libs="$ac_libs $LSCP_LIBS"
355 CFLAGS="$CFLAGS $LSCP_CFLAGS"
356 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
357 LIBS="$LIBS $LSCP_LIBS"
358 else
359 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
360 fi
361
362 case "{$host}" in
363 *mingw*)
364 ac_libs="$ac_libs -lws2_32"
365 LIBS="$LIBS -lws2_32"
366 ;;
367 esac
368
369 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
370 ac_cv_instrument_name, [
371 AC_TRY_COMPILE([#include "lscp/client.h"], [
372 lscp_channel_info_t info;
373 info.instrument_name = 0;
374 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
375 ])
376 ac_instrument_name=$ac_cv_instrument_name
377 if test "x$ac_instrument_name" = "xyes"; then
378 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
379 fi
380
381 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
382 ac_cv_mute_solo, [
383 AC_TRY_COMPILE([#include "lscp/client.h"], [
384 lscp_channel_info_t info;
385 info.mute = 0;
386 info.solo = 0;
387 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
388 ])
389 ac_mute_solo=$ac_cv_mute_solo
390 if test "x$ac_mute_solo" = "xyes"; then
391 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
392 fi
393 if test "x$ac_mute_solo" = "xyes"; then
394 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
395 fi
396 if test "x$ac_mute_solo" = "xyes"; then
397 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
398 fi
399
400 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
401 if test "x$ac_midi_instrument" = "xyes"; then
402 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
403 fi
404
405 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
406 if test "x$ac_fxsend" = "xyes"; then
407 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
408 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
409 ac_cv_fxsend_level, [
410 AC_TRY_COMPILE([#include "lscp/client.h"], [
411 lscp_fxsend_info_t info;
412 info.level = 0.0f;
413 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
414 ])
415 ac_fxsend_level=$ac_cv_fxsend_level
416 if test "x$ac_fxsend_level" = "xyes"; then
417 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
418 fi
419 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
420 if test "x$ac_fxsend_rename" = "xyes"; then
421 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
422 fi
423 fi
424
425 AC_CACHE_CHECK([for audio_routing array type],
426 ac_cv_audio_routing, [
427 AC_TRY_COMPILE([#include "lscp/client.h"], [
428 lscp_channel_info_t info;
429 char ch = info.audio_routing[0][0];
430 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
431 ])
432 ac_audio_routing=$ac_cv_audio_routing
433 if test "x$ac_audio_routing" = "xyes"; then
434 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
435 fi
436
437 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
438 if test "x$ac_volume" = "xyes"; then
439 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
440 fi
441
442 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
443 if test "x$ac_edit_instrument" = "xyes"; then
444 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
445 fi
446
447 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
448 ac_cv_channel_midi_event, [
449 AC_TRY_COMPILE([
450 #include "lscp/client.h"
451 #include "lscp/event.h"
452 ], [
453 lscp_event_t ev;
454 ev = LSCP_EVENT_CHANNEL_MIDI;
455 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
456 ])
457 ac_channel_midi_event=$ac_cv_channel_midi_event
458 if test "x$ac_channel_midi_event" = "xyes"; then
459 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
460 fi
461
462 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
463 ac_cv_device_midi_event, [
464 AC_TRY_COMPILE([
465 #include "lscp/client.h"
466 #include "lscp/event.h"
467 ], [
468 lscp_event_t ev;
469 ev = LSCP_EVENT_DEVICE_MIDI;
470 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
471 ])
472 ac_device_midi_event=$ac_cv_device_midi_event
473 if test "x$ac_device_midi_event" = "xyes"; then
474 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
475 fi
476
477 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
478 if test "x$ac_max_voices" = "xyes"; then
479 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
480 fi
481
482 AC_CHECK_LIB(lscp, lscp_client_connection_lost, [ac_lscp_conn_lost="yes"], [ac_lscp_conn_lost="no"])
483 if test "x$ac_lscp_conn_lost" = "xyes"; then
484 AC_DEFINE(CONFIG_LSCP_CLIENT_CONNECTION_LOST, 1, [Define if liblscp function lscp_client_connection_lost() is available.])
485 fi
486
487 # Check for optional libraries.
488 if test "x$ac_libgig" = "xyes"; then
489 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
490 fi
491 if test "x$ac_libgig" = "xyes"; then
492 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
493 ac_cflags="$ac_cflags $GIG_CFLAGS"
494 ac_libs="$ac_libs $GIG_LIBS"
495 CFLAGS="$CFLAGS $GIG_CFLAGS"
496 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
497 LIBS="$LIBS $GIG_LIBS"
498 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
499 ac_libgig_setautoload="yes"
500 else
501 AC_MSG_WARN([*** GIG library not found (libgig).])
502 fi
503
504 # Check for round math function.
505 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
506 if test "x$ac_round" = "xyes"; then
507 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
508 fi
509
510
511 # Checks for header files.
512 AC_HEADER_STDC
513 AC_HEADER_SYS_WAIT
514 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
515
516 if test "x$ac_libgig" = "xyes"; then
517 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
518 if test "x$ac_libgig_sf2" = "xyes"; then
519 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
520 fi
521 fi
522
523 # Check for unique/single instance support.
524 if test "x$ac_xunique" = "xyes"; then
525 if test $ac_qt_version_major -lt 6; then
526 PKG_CHECK_MODULES([QT5NETWORK], [Qt5Network], [ac_xunique="yes"], [ac_xunique="no"])
527 else
528 PKG_CHECK_MODULES([QT6NETWORK], [Qt6Network], [ac_xunique="yes"], [ac_xunique="no"])
529 fi
530 fi
531 if test "x$ac_xunique" = "xyes"; then
532 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if unique/single instance is enabled.])
533 ac_qnetwork="network"
534 fi
535 AC_SUBST(ac_qnetwork)
536
537 # Check for debugging stack-trace.
538 if test "x$ac_stacktrace" = "xyes"; then
539 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
540 fi
541
542 AC_SUBST(ac_cflags)
543 AC_SUBST(ac_ldflags)
544 AC_SUBST(ac_incpath)
545 AC_SUBST(ac_libs)
546
547
548 # Checks for typedefs, structures, and compiler characteristics.
549 # AC_C_CONST
550
551 # Checks for library functions.
552 AC_CHECK_FUNCS(system)
553
554 # Finally produce a configure header file and the makefiles.
555 AC_OUTPUT
556
557 # make clean > /dev/null 2>&1
558
559 # Output summary message
560
561 echo
562 echo " $PACKAGE_NAME $ac_build_version"
563 echo
564 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
565 echo
566 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
567 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
568 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
569 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
570 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
571 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
572 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
573 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
574 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
575 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
576 if test "x$ac_libgig" = "xyes"; then
577 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
578 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
579 fi
580 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
581 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
582 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
583 echo " LSCP connection loss support . . . . . . . . . . .: $ac_lscp_conn_lost"
584 echo
585 echo " Unique/Single instance support . . . . . . . . . .: $ac_xunique"
586 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
587 echo
588 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
589 echo
590 echo "Now type 'make', followed by 'make install' as root."
591 echo

  ViewVC Help
Powered by ViewVC