1 |
# qsampler.pro |
2 |
# |
3 |
NAME = qsampler |
4 |
|
5 |
TARGET = $${NAME} |
6 |
TEMPLATE = app |
7 |
|
8 |
include(src.pri) |
9 |
|
10 |
#DEFINES += DEBUG |
11 |
|
12 |
HEADERS += config.h \ |
13 |
qsamplerAbout.h \ |
14 |
qsamplerOptions.h \ |
15 |
qsamplerChannel.h \ |
16 |
qsamplerMessages.h \ |
17 |
qsamplerInstrument.h \ |
18 |
qsamplerInstrumentList.h \ |
19 |
qsamplerDevice.h \ |
20 |
qsamplerFxSend.h \ |
21 |
qsamplerFxSendsModel.h \ |
22 |
qsamplerUtilities.h \ |
23 |
qsamplerInstrumentForm.h \ |
24 |
qsamplerInstrumentListForm.h \ |
25 |
qsamplerDeviceForm.h \ |
26 |
qsamplerDeviceStatusForm.h \ |
27 |
qsamplerChannelStrip.h \ |
28 |
qsamplerChannelForm.h \ |
29 |
qsamplerChannelFxForm.h \ |
30 |
qsamplerOptionsForm.h \ |
31 |
qsamplerMainForm.h |
32 |
|
33 |
SOURCES += \ |
34 |
qsampler.cpp \ |
35 |
qsamplerOptions.cpp \ |
36 |
qsamplerChannel.cpp \ |
37 |
qsamplerMessages.cpp \ |
38 |
qsamplerInstrument.cpp \ |
39 |
qsamplerInstrumentList.cpp \ |
40 |
qsamplerDevice.cpp \ |
41 |
qsamplerFxSend.cpp \ |
42 |
qsamplerFxSendsModel.cpp \ |
43 |
qsamplerUtilities.cpp \ |
44 |
qsamplerInstrumentForm.cpp \ |
45 |
qsamplerInstrumentListForm.cpp \ |
46 |
qsamplerDeviceForm.cpp \ |
47 |
qsamplerDeviceStatusForm.cpp \ |
48 |
qsamplerChannelStrip.cpp \ |
49 |
qsamplerChannelForm.cpp \ |
50 |
qsamplerChannelFxForm.cpp \ |
51 |
qsamplerOptionsForm.cpp \ |
52 |
qsamplerMainForm.cpp |
53 |
|
54 |
FORMS += \ |
55 |
qsamplerInstrumentForm.ui \ |
56 |
qsamplerInstrumentListForm.ui \ |
57 |
qsamplerDeviceForm.ui \ |
58 |
qsamplerChannelStrip.ui \ |
59 |
qsamplerChannelForm.ui \ |
60 |
qsamplerChannelFxForm.ui \ |
61 |
qsamplerOptionsForm.ui \ |
62 |
qsamplerMainForm.ui |
63 |
|
64 |
RESOURCES += \ |
65 |
qsampler.qrc |
66 |
|
67 |
|
68 |
TRANSLATIONS += \ |
69 |
translations/qsampler_cs.ts \ |
70 |
translations/qsampler_ru.ts |
71 |
|
72 |
|
73 |
unix { |
74 |
|
75 |
# variables |
76 |
OBJECTS_DIR = .obj |
77 |
MOC_DIR = .moc |
78 |
UI_DIR = .ui |
79 |
|
80 |
isEmpty(PREFIX) { |
81 |
PREFIX = /usr/local |
82 |
} |
83 |
|
84 |
BINDIR = $${PREFIX}/bin |
85 |
DATADIR = $$PREFIX/share |
86 |
|
87 |
DEFINES += DATADIR=\"$${DATADIR}\" |
88 |
|
89 |
# make install |
90 |
INSTALLS += target desktop icon appdata \ |
91 |
icon_scalable mimeinfo mimetypes mimetypes_scalable |
92 |
|
93 |
target.path = $${BINDIR} |
94 |
|
95 |
desktop.path = $${DATADIR}/applications |
96 |
desktop.files += $${NAME}.desktop |
97 |
|
98 |
icon.path = $${DATADIR}/icons/hicolor/32x32/apps |
99 |
icon.files += images/$${NAME}.png |
100 |
|
101 |
icon_scalable.path = $${DATADIR}/icons/hicolor/scalable/apps |
102 |
icon_scalable.files += images/$${NAME}.svg |
103 |
|
104 |
appdata.path = $${DATADIR}/appdata |
105 |
appdata.files += appdata/$${NAME}.appdata.xml |
106 |
|
107 |
mimeinfo.path = $${DATADIR}/mime/packages |
108 |
mimeinfo.files += mimetypes/$${NAME}.xml |
109 |
|
110 |
mimetypes.path = $${DATADIR}/icons/hicolor/32x32/mimetypes |
111 |
mimetypes.files += mimetypes/application-x-$${NAME}-session.png |
112 |
|
113 |
mimetypes_scalable.path = $${DATADIR}/icons/hicolor/scalable/mimetypes |
114 |
mimetypes_scalable.files += mimetypes/application-x-$${NAME}-session.svg |
115 |
} |
116 |
|
117 |
win32 { |
118 |
|
119 |
CONFIG(debug, debug|release): CONFIG += console |
120 |
INSTALLS += target |
121 |
target.path = $${PREFIX}/bin |
122 |
} |
123 |
|
124 |
macx { |
125 |
|
126 |
QMAKE_MAC_SDK = $$(SDKROOT) |
127 |
CONFIG += $$(QMAKE_ARCHS) |
128 |
} |
129 |
|
130 |
|
131 |
# QT5 support |
132 |
!lessThan(QT_MAJOR_VERSION, 5) { |
133 |
QT += widgets |
134 |
unix { |
135 |
QT += x11extras |
136 |
} |
137 |
} |