1 |
# qsampler.pro |
2 |
# |
3 |
NAME = qsampler |
4 |
|
5 |
TARGET = $${NAME} |
6 |
TEMPLATE = app |
7 |
|
8 |
include(src.pri) |
9 |
|
10 |
#DEFINES += DEBUG |
11 |
|
12 |
HEADERS += config.h \ |
13 |
qsamplerAbout.h \ |
14 |
qsamplerOptions.h \ |
15 |
qsamplerChannel.h \ |
16 |
qsamplerMessages.h \ |
17 |
qsamplerInstrument.h \ |
18 |
qsamplerInstrumentList.h \ |
19 |
qsamplerDevice.h \ |
20 |
qsamplerFxSend.h \ |
21 |
qsamplerFxSendsModel.h \ |
22 |
qsamplerUtilities.h \ |
23 |
qsamplerInstrumentForm.h \ |
24 |
qsamplerInstrumentListForm.h \ |
25 |
qsamplerDeviceForm.h \ |
26 |
qsamplerDeviceStatusForm.h \ |
27 |
qsamplerChannelStrip.h \ |
28 |
qsamplerChannelForm.h \ |
29 |
qsamplerChannelFxForm.h \ |
30 |
qsamplerOptionsForm.h \ |
31 |
qsamplerMainForm.h |
32 |
|
33 |
SOURCES += \ |
34 |
qsampler.cpp \ |
35 |
qsamplerOptions.cpp \ |
36 |
qsamplerChannel.cpp \ |
37 |
qsamplerMessages.cpp \ |
38 |
qsamplerInstrument.cpp \ |
39 |
qsamplerInstrumentList.cpp \ |
40 |
qsamplerDevice.cpp \ |
41 |
qsamplerFxSend.cpp \ |
42 |
qsamplerFxSendsModel.cpp \ |
43 |
qsamplerUtilities.cpp \ |
44 |
qsamplerInstrumentForm.cpp \ |
45 |
qsamplerInstrumentListForm.cpp \ |
46 |
qsamplerDeviceForm.cpp \ |
47 |
qsamplerDeviceStatusForm.cpp \ |
48 |
qsamplerChannelStrip.cpp \ |
49 |
qsamplerChannelForm.cpp \ |
50 |
qsamplerChannelFxForm.cpp \ |
51 |
qsamplerOptionsForm.cpp \ |
52 |
qsamplerMainForm.cpp |
53 |
|
54 |
FORMS += \ |
55 |
qsamplerInstrumentForm.ui \ |
56 |
qsamplerInstrumentListForm.ui \ |
57 |
qsamplerDeviceForm.ui \ |
58 |
qsamplerChannelStrip.ui \ |
59 |
qsamplerChannelForm.ui \ |
60 |
qsamplerChannelFxForm.ui \ |
61 |
qsamplerOptionsForm.ui \ |
62 |
qsamplerMainForm.ui |
63 |
|
64 |
RESOURCES += \ |
65 |
qsampler.qrc |
66 |
|
67 |
|
68 |
TRANSLATIONS += \ |
69 |
translations/qsampler_cs.ts \ |
70 |
translations/qsampler_fr.ts \ |
71 |
translations/qsampler_ru.ts |
72 |
|
73 |
|
74 |
unix { |
75 |
|
76 |
# variables |
77 |
OBJECTS_DIR = .obj |
78 |
MOC_DIR = .moc |
79 |
UI_DIR = .ui |
80 |
|
81 |
isEmpty(PREFIX) { |
82 |
PREFIX = /usr/local |
83 |
} |
84 |
|
85 |
isEmpty(BINDIR) { |
86 |
BINDIR = $${PREFIX}/bin |
87 |
} |
88 |
|
89 |
isEmpty(DATADIR) { |
90 |
DATADIR = $${PREFIX}/share |
91 |
} |
92 |
|
93 |
#DEFINES += DATADIR=\"$${DATADIR}\" |
94 |
|
95 |
# make install |
96 |
INSTALLS += target desktop icon appdata \ |
97 |
icon_scalable mimeinfo mimetypes mimetypes_scalable |
98 |
|
99 |
target.path = $${BINDIR} |
100 |
|
101 |
desktop.path = $${DATADIR}/applications |
102 |
desktop.files += $${NAME}.desktop |
103 |
|
104 |
icon.path = $${DATADIR}/icons/hicolor/32x32/apps |
105 |
icon.files += images/$${NAME}.png |
106 |
|
107 |
icon_scalable.path = $${DATADIR}/icons/hicolor/scalable/apps |
108 |
icon_scalable.files += images/$${NAME}.svg |
109 |
|
110 |
appdata.path = $${DATADIR}/metainfo |
111 |
appdata.files += appdata/$${NAME}.appdata.xml |
112 |
|
113 |
mimeinfo.path = $${DATADIR}/mime/packages |
114 |
mimeinfo.files += mimetypes/$${NAME}.xml |
115 |
|
116 |
mimetypes.path = $${DATADIR}/icons/hicolor/32x32/mimetypes |
117 |
mimetypes.files += mimetypes/application-x-$${NAME}-session.png |
118 |
|
119 |
mimetypes_scalable.path = $${DATADIR}/icons/hicolor/scalable/mimetypes |
120 |
mimetypes_scalable.files += mimetypes/application-x-$${NAME}-session.svg |
121 |
} |
122 |
|
123 |
QT += widgets |
124 |
|
125 |
win32 { |
126 |
|
127 |
CONFIG(debug, debug|release): CONFIG += console |
128 |
INSTALLS += target |
129 |
target.path = $${PREFIX}/bin |
130 |
} |
131 |
|
132 |
macx { |
133 |
|
134 |
QMAKE_MAC_SDK = $$(SDKROOT) |
135 |
CONFIG += $$(QMAKE_ARCHS) |
136 |
} |