/[svn]/gigedit/trunk/configure.ac
ViewVC logotype

Contents of /gigedit/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 2475 - (show annotations) (download)
Sun Sep 15 18:34:28 2013 UTC (10 years, 6 months ago) by schoenebeck
File size: 7742 byte(s)
- Fixed compilation error introduced with previous commit.

1 dnl Process this file with autoconf to produce a configure script.
2
3 #------------------------------------------------------------------------------------
4 # The following is the current, official release version of gigedit:
5
6 m4_define(gigedit_ver_major, 0)
7 m4_define(gigedit_ver_minor, 2)
8 m4_define(gigedit_ver_release, 0)
9
10 AC_INIT([gigedit], [gigedit_ver_major.gigedit_ver_minor.gigedit_ver_release])
11 AC_CONFIG_SRCDIR([configure.ac])
12 AC_CONFIG_AUX_DIR([.])
13
14 #------------------------------------------------------------------------------------
15 # The following is the libtool / shared library version. This doesn't have to
16 # do anything with the release version. It MUST conform to the following rules:
17 #
18 # 1. Start with version information of `0:0:0' for each libtool library.
19 # 2. Update the version information only immediately before a public release of
20 # your software. More frequent updates are unnecessary, and only guarantee
21 # that the current interface number gets larger faster.
22 # 3. If the library source code has changed at all since the last update, then
23 # increment revision (`c:r:a' becomes `c:r+1:a').
24 # 4. If any interfaces have been added, removed, or changed since the last update,
25 # increment current, and set revision to 0.
26 # 5. If any interfaces have been added since the last public release, then increment
27 # age.
28 # 6. If any interfaces have been removed since the last public release, then set age
29 # to 0.
30
31 LIBGIGEDIT_LT_CURRENT=2
32 LIBGIGEDIT_LT_REVISION=0
33 LIBGIGEDIT_LT_AGE=0
34
35 SHARED_VERSION_INFO="$LIBGIGEDIT_LT_CURRENT:$LIBGIGEDIT_LT_REVISION:$LIBGIGEDIT_LT_AGE"
36 AC_LANG([C++])
37 AC_PROG_CXX
38 AC_LIBTOOL_WIN32_DLL
39 AC_PROG_LIBTOOL
40 AC_SUBST(SHLIB_VERSION_ARG)
41 AC_SUBST(SHARED_VERSION_INFO)
42 AC_SUBST(GIGEDIT_VER_MAJOR, gigedit_ver_major)
43 AC_SUBST(GIGEDIT_VER_MINOR, gigedit_ver_minor)
44 AC_SUBST(GIGEDIT_VER_RELEASE, gigedit_ver_release)
45
46 # configure checks for the following file's existence to make sure that
47 # the directory that it is told contains the source code in fact does.
48 # Occasionally people accidentally specify the wrong directory with
49 # `--srcdir'; this is a safety check.
50 AC_CONFIG_SRCDIR(src/gigedit/main.cpp)
51
52 GETTEXT_PACKAGE=gigedit
53 AC_SUBST([GETTEXT_PACKAGE])
54 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
55
56 # the libgig header files need this
57 AC_C_BIGENDIAN
58
59 AC_PROG_CXX
60
61 IT_PROG_INTLTOOL(0.35.0)
62 AM_GLIB_GNU_GETTEXT
63
64 windows=no
65 mac=no
66 case $host in
67 *mingw*|*cygwin*) windows=yes ;;
68 *-*-darwin*) mac=yes ;;
69 esac
70 AM_CONDITIONAL(WINDOWS, test "$windows" = "yes")
71 AM_CONDITIONAL(MAC, test "$mac" = "yes")
72
73 if test "$mac" = "yes"; then
74 AC_PROG_OBJC
75 AC_PROG_OBJCXX
76 fi
77
78 PKG_PROG_PKG_CONFIG
79 have_gtk3=no
80 PKG_CHECK_EXISTS(gtkmm-3.0 >= 2.99,
81 [PKG_CHECK_MODULES(GTKMM, gtkmm-3.0, have_gtk3=yes)],
82 [PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 >= 2.8 gthread-2.0 cairomm-1.0)])
83 AM_CONDITIONAL(HAVE_GTK3, [test "$have_gtk3" = "yes"])
84
85 PKG_CHECK_MODULES(SIGC, sigc++-2.0)
86 AC_SUBST(SIGC_CFLAGS)
87 AC_SUBST(SIGC_LIBS)
88
89 PKG_CHECK_MODULES(GIG, gig >= 3.3.0)
90 AC_SUBST(GIG_CFLAGS)
91 AC_SUBST(GIG_LIBS)
92
93 # check for presence of libsndfile
94 PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.11)
95 AC_SUBST(SNDFILE_CFLAGS)
96 AC_SUBST(SNDFILE_LIBS)
97
98 # check for (optional) presence of liblinuxsampler
99 liblinuxsampler_version="0.5.0"
100 PKG_CHECK_MODULES(
101 LINUXSAMPLER, linuxsampler >= $liblinuxsampler_version,
102 have_linuxsampler=1, have_linuxsampler=0
103 )
104 LINUXSAMPLER_PLUGIN_DIR=
105 if test "$have_linuxsampler" = "0"; then
106 echo "Required liblinuxsampler version not found!"
107 echo "You need to have liblinuxsampler version ${liblinuxsampler_version}"
108 echo "installed. Support for on-the-fly editing with LinuxSampler will"
109 echo "be disabled."
110 else
111 echo "Found linuxsampler $liblinuxsampler_version"
112 echo -n "Retrieving LinuxSampler's plugin dir... "
113 LINUXSAMPLER_PLUGIN_DIR=`$PKG_CONFIG --variable plugindir linuxsampler`
114 if test "$LINUXSAMPLER_PLUGIN_DIR" = ""; then
115 have_linuxsampler=0
116 echo "Error"
117 echo "Could not retrieve LinuxSampler's plugin directory. Support"
118 echo "for on-the-fly editing with LinuxSampler will be disabled."
119 else
120 echo "${LINUXSAMPLER_PLUGIN_DIR} "
121 # convert absolute LS plugin dir into relative dir
122 # (see ch 27.10 of the automake manual,
123 # "Installing to Hard-Coded Locations")
124 # this one is extended to work with digit postfixed lib directories
125 # (e.g. "/usr/lib64/linuxsampler") as well
126 LINUXSAMPLER_PLUGIN_DIR=`echo "${LINUXSAMPLER_PLUGIN_DIR}" | sed 's/^.*\/lib[[0-9]]*\//\${libdir}\//g'`
127 if echo "${LINUXSAMPLER_PLUGIN_DIR}" | grep "\${libdir}" > /dev/null; then
128 echo "Relative plugin dir: ${LINUXSAMPLER_PLUGIN_DIR}"
129 else
130 echo "*********************************************************"
131 echo "* ! WARNING ! : Could not resolve LinuxSampler's plugin"
132 echo "* directory as relative path. This is probably not an"
133 echo "* issue if you're just going to install gigedit by"
134 echo "* 'make install', but it IS a problem if you're"
135 echo "* installing to a certain destination directory and/or"
136 echo "* compile in sandbox (e.g. Debian package or Gentoo emerge)"
137 echo "*********************************************************"
138 fi
139 fi
140 fi
141 AC_SUBST(LINUXSAMPLER_CFLAGS)
142 AC_SUBST(LINUXSAMPLER_LIBS)
143 AC_SUBST(LINUXSAMPLER_PLUGIN_DIR)
144 AM_CONDITIONAL(HAVE_LINUXSAMPLER, test $have_linuxsampler = "1")
145 AC_DEFINE_UNQUOTED(
146 HAVE_LINUXSAMPLER, $have_linuxsampler,
147 [Define to 1 if you have LinuxSampler installed.]
148 )
149
150 have_ls_vmidi=0
151 if test $have_linuxsampler = "1"; then
152 AC_MSG_CHECKING([whether LinuxSampler supports virtual MIDI devices])
153 AC_LANG_PUSH([C++])
154 LIBS="$LINUXSAMPLER_LIBS $LIBS"
155 CFLAGS="$CFLAGS $LINUXSAMPLER_CFLAGS"
156 CXXFLAGS="$CXXFLAGS $CFLAGS"
157 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
158 #include <linuxsampler/drivers/midi/VirtualMidiDevice.h>
159 using namespace LinuxSampler;
160 ]], [[
161 bool (VirtualMidiDevice::*ptr1)(uint8_t, uint8_t) = 0;
162 bool (VirtualMidiDevice::*ptr2)() = 0;
163 bool (VirtualMidiDevice::*ptr3)(uint8_t) = 0;
164 uint8_t (VirtualMidiDevice::*ptr4)(uint8_t) = 0;
165 ptr1 = &VirtualMidiDevice::SendNoteOnToSampler;
166 ptr2 = &VirtualMidiDevice::NotesChanged;
167 ptr3 = &VirtualMidiDevice::NoteChanged;
168 ptr4 = &VirtualMidiDevice::NoteOffVelocity;
169 ]])],[
170 AC_MSG_RESULT(yes)
171 have_ls_vmidi=1
172 ],[
173 AC_MSG_RESULT(no)
174 echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"
175 echo "! Support for the virtual MIDI keyboard in gigedit will"
176 echo "! be disabled. You'll see the keyboard in gigedit, but"
177 echo "! you won't be able to trigger notes with it nor see"
178 echo "! active notes caused by external MIDI sources of LS."
179 echo "! Update LinuxSampler and recompile gigedit if you want"
180 echo "! this feature."
181 echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"
182 ])
183 AC_LANG_POP([C++])
184 fi
185 AC_DEFINE_UNQUOTED(
186 HAVE_LINUXSAMPLER_VIRTUAL_MIDI_DEVICE, $have_ls_vmidi,
187 [Define to 1 if LinuxSampler supports virtual MIDI devices.]
188 )
189
190 AC_CONFIG_HEADERS(config.h)
191 AM_INIT_AUTOMAKE
192
193 AC_CONFIG_FILES([
194 Makefile
195 src/Makefile
196 src/gigedit/Makefile
197 src/plugin/Makefile
198 gfx/Makefile
199 po/Makefile.in
200 debian/Makefile
201 doc/Makefile
202 doc/quickstart/Makefile
203 win32/libgigedit.dev
204 win32/gigedit.dev
205 win32/gigedit.nsi
206 win32/Makefile
207 gigedit.spec
208 ])
209 AC_OUTPUT

  ViewVC Help
Powered by ViewVC