/[svn]/gigedit/trunk/configure.ac
ViewVC logotype

Contents of /gigedit/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3831 - (show annotations) (download)
Thu Oct 15 18:08:49 2020 UTC (3 years, 5 months ago) by schoenebeck
File size: 8935 byte(s)
* Main Window: auto save & restore the vertical splitter position.

* Bumped version (1.1.1.svn33).

1 dnl Process this file with autoconf to produce a configure script.
2
3 #------------------------------------------------------------------------------------
4 # The following is the current, official release version of gigedit:
5
6 m4_define(gigedit_ver_major, 1)
7 m4_define(gigedit_ver_minor, 1)
8 m4_define(gigedit_ver_release, 1.svn33)
9
10 AC_INIT([gigedit], [gigedit_ver_major.gigedit_ver_minor.gigedit_ver_release])
11 AC_CONFIG_SRCDIR([configure.ac])
12 AC_CONFIG_AUX_DIR([.])
13
14 #------------------------------------------------------------------------------------
15 # The following is the libtool / shared library version. This doesn't have to
16 # do anything with the release version. It MUST conform to the following rules:
17 #
18 # 1. Start with version information of `0:0:0' for each libtool library.
19 # 2. Update the version information only immediately before a public release of
20 # your software. More frequent updates are unnecessary, and only guarantee
21 # that the current interface number gets larger faster.
22 # 3. If the library source code has changed at all since the last update, then
23 # increment revision (`c:r:a' becomes `c:r+1:a').
24 # 4. If any interfaces have been added, removed, or changed since the last update,
25 # increment current, and set revision to 0.
26 # 5. If any interfaces have been added since the last public release, then increment
27 # age.
28 # 6. If any interfaces have been removed since the last public release, then set age
29 # to 0.
30
31 LIBGIGEDIT_LT_CURRENT=4
32 LIBGIGEDIT_LT_REVISION=0
33 LIBGIGEDIT_LT_AGE=0
34
35 SHARED_VERSION_INFO="$LIBGIGEDIT_LT_CURRENT:$LIBGIGEDIT_LT_REVISION:$LIBGIGEDIT_LT_AGE"
36 AC_LANG([C++])
37 AC_PROG_CXX
38 AC_LIBTOOL_WIN32_DLL
39 AC_PROG_LIBTOOL
40 AC_SUBST(SHLIB_VERSION_ARG)
41 AC_SUBST(SHARED_VERSION_INFO)
42 AC_SUBST(GIGEDIT_VER_MAJOR, gigedit_ver_major)
43 AC_SUBST(GIGEDIT_VER_MINOR, gigedit_ver_minor)
44 AC_SUBST(GIGEDIT_VER_RELEASE, gigedit_ver_release)
45
46 # configure checks for the following file's existence to make sure that
47 # the directory that it is told contains the source code in fact does.
48 # Occasionally people accidentally specify the wrong directory with
49 # `--srcdir'; this is a safety check.
50 AC_CONFIG_SRCDIR(src/gigedit/main.cpp)
51
52 GETTEXT_PACKAGE=gigedit
53 AC_SUBST([GETTEXT_PACKAGE])
54 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
55
56 # the libgig header files need this
57 AC_C_BIGENDIAN
58
59 AC_PROG_CXX
60
61 IT_PROG_INTLTOOL(0.35.0)
62 AM_GLIB_GNU_GETTEXT
63
64 windows=no
65 mac=no
66 case $host in
67 *mingw*|*cygwin*) windows=yes ;;
68 *-*-darwin*) mac=yes ;;
69 esac
70 AM_CONDITIONAL(WINDOWS, test "$windows" = "yes")
71 AM_CONDITIONAL(MAC, test "$mac" = "yes")
72
73 # make sure C++11 is supported by compiler
74 # (add CXXFLAGS if required [e.g. -std=c++11])
75 m4_ifdef([m4_include(m4/ax_cxx_compile_stdcxx.m4)],,
76 [sinclude([m4/ax_cxx_compile_stdcxx.m4])])
77 AX_CXX_COMPILE_STDCXX(11, [], mandatory)
78
79 # Note: even though Objective-C sources are just compiled for Mac, the
80 # following AC macros though must not be embedded into a shell check
81 # (if test "$mac" = "yes" ...), because those AC macros themselves are
82 # expanded before any shell code is executed, the generated configure
83 # code though would then not be executed and would lead to interesting
84 # libtool errors on non-Mac systems due to this.
85 AC_PROG_OBJC
86 # The OBJCXX macro didn't exist before autoconf 2.65, so ifdef it to
87 # avoid warnings on old systems.
88 m4_ifdef([AC_PROG_OBJCXX], [AC_PROG_OBJCXX])
89
90 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
91
92 PKG_CHECK_EXISTS(gtk+-3.0 >= 2.99,
93 [PKG_CHECK_MODULES([GTK], [gtk+-3.0])],
94 [PKG_CHECK_MODULES([GTK], [gtk+-2.0])])
95
96 PKG_PROG_PKG_CONFIG
97 have_gtk3=no
98 PKG_CHECK_EXISTS(gtkmm-3.0 >= 2.99,
99 [PKG_CHECK_MODULES(GTKMM, gtkmm-3.0, have_gtk3=yes)],
100 [PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 >= 2.8 gthread-2.0 cairomm-1.0)])
101 AM_CONDITIONAL(HAVE_GTK3, [test "$have_gtk3" = "yes"])
102
103 # Check for cairommconfig.h, as it was moved in cairomm 1.8.4. We only
104 # need it for newer versions.
105 gigedit_save_CPPFLAGS=$CPPFLAGS
106 CPPFLAGS="$GTKMM_CFLAGS $CPPFLAGS"
107 AC_CHECK_HEADERS([cairommconfig.h])
108 CPPFLAGS=$gigedit_save_CPPFLAGS
109
110 PKG_CHECK_MODULES(SIGC, sigc++-2.0)
111 AC_SUBST(SIGC_CFLAGS)
112 AC_SUBST(SIGC_LIBS)
113
114 PKG_CHECK_MODULES(GIG, gig >= 4.2.0)
115 AC_SUBST(GIG_CFLAGS)
116 AC_SUBST(GIG_LIBS)
117
118 # check for presence of libsndfile
119 PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.11)
120 AC_SUBST(SNDFILE_CFLAGS)
121 AC_SUBST(SNDFILE_LIBS)
122
123 # check for (optional) presence of liblinuxsampler
124 liblinuxsampler_version="2.1.1"
125 PKG_CHECK_MODULES(
126 LINUXSAMPLER, linuxsampler >= $liblinuxsampler_version,
127 have_linuxsampler=1, have_linuxsampler=0
128 )
129 LINUXSAMPLER_PLUGIN_DIR=
130 if test "$have_linuxsampler" = "0"; then
131 echo "Required liblinuxsampler version not found!"
132 echo "You need to have liblinuxsampler version ${liblinuxsampler_version}"
133 echo "installed. Support for on-the-fly editing with LinuxSampler will"
134 echo "be disabled."
135 else
136 echo "Found linuxsampler $liblinuxsampler_version"
137 echo -n "Retrieving LinuxSampler's plugin dir... "
138 LINUXSAMPLER_PLUGIN_DIR=`$PKG_CONFIG --variable plugindir linuxsampler`
139 if test "$LINUXSAMPLER_PLUGIN_DIR" = ""; then
140 have_linuxsampler=0
141 echo "Error"
142 echo "Could not retrieve LinuxSampler's plugin directory. Support"
143 echo "for on-the-fly editing with LinuxSampler will be disabled."
144 else
145 echo "${LINUXSAMPLER_PLUGIN_DIR} "
146 # convert absolute LS plugin dir into relative dir
147 # (see ch 27.10 of the automake manual,
148 # "Installing to Hard-Coded Locations")
149 # this one is extended to work with digit postfixed lib directories
150 # (e.g. "/usr/lib64/linuxsampler") as well
151 LINUXSAMPLER_PLUGIN_DIR=`echo "${LINUXSAMPLER_PLUGIN_DIR}" | sed 's/^.*\/lib[[0-9]]*\//\${libdir}\//g'`
152 if echo "${LINUXSAMPLER_PLUGIN_DIR}" | grep "\${libdir}" > /dev/null; then
153 echo "Relative plugin dir: ${LINUXSAMPLER_PLUGIN_DIR}"
154 else
155 echo "*********************************************************"
156 echo "* ! WARNING ! : Could not resolve LinuxSampler's plugin"
157 echo "* directory as relative path. This is probably not an"
158 echo "* issue if you're just going to install gigedit by"
159 echo "* 'make install', but it IS a problem if you're"
160 echo "* installing to a certain destination directory and/or"
161 echo "* compile in sandbox (e.g. Debian package or Gentoo emerge)"
162 echo "*********************************************************"
163 fi
164 fi
165 fi
166 AC_SUBST(LINUXSAMPLER_CFLAGS)
167 AC_SUBST(LINUXSAMPLER_LIBS)
168 AC_SUBST(LINUXSAMPLER_PLUGIN_DIR)
169 AM_CONDITIONAL(HAVE_LINUXSAMPLER, test $have_linuxsampler = "1")
170 AC_DEFINE_UNQUOTED(
171 HAVE_LINUXSAMPLER, $have_linuxsampler,
172 [Define to 1 if you have LinuxSampler installed.]
173 )
174
175 have_ls_vmidi=0
176 if test $have_linuxsampler = "1"; then
177 AC_MSG_CHECKING([whether LinuxSampler supports virtual MIDI devices])
178 AC_LANG_PUSH([C++])
179 LIBS="$LINUXSAMPLER_LIBS $LIBS"
180 CFLAGS="$CFLAGS $LINUXSAMPLER_CFLAGS"
181 CXXFLAGS="$CXXFLAGS $CFLAGS"
182 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
183 #include <linuxsampler/drivers/midi/VirtualMidiDevice.h>
184 using namespace LinuxSampler;
185 ]], [[
186 bool (VirtualMidiDevice::*ptr1)(uint8_t, uint8_t) = 0;
187 bool (VirtualMidiDevice::*ptr2)() = 0;
188 bool (VirtualMidiDevice::*ptr3)(uint8_t) = 0;
189 uint8_t (VirtualMidiDevice::*ptr4)(uint8_t) = 0;
190 ptr1 = &VirtualMidiDevice::SendNoteOnToSampler;
191 ptr2 = &VirtualMidiDevice::NotesChanged;
192 ptr3 = &VirtualMidiDevice::NoteChanged;
193 ptr4 = &VirtualMidiDevice::NoteOffVelocity;
194 ]])],[
195 AC_MSG_RESULT(yes)
196 have_ls_vmidi=1
197 ],[
198 AC_MSG_RESULT(no)
199 echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"
200 echo "! Support for the virtual MIDI keyboard in gigedit will"
201 echo "! be disabled. You'll see the keyboard in gigedit, but"
202 echo "! you won't be able to trigger notes with it nor see"
203 echo "! active notes caused by external MIDI sources of LS."
204 echo "! Update LinuxSampler and recompile gigedit if you want"
205 echo "! this feature."
206 echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"
207 ])
208 AC_LANG_POP([C++])
209 fi
210 AC_DEFINE_UNQUOTED(
211 HAVE_LINUXSAMPLER_VIRTUAL_MIDI_DEVICE, $have_ls_vmidi,
212 [Define to 1 if LinuxSampler supports virtual MIDI devices.]
213 )
214
215 AC_CONFIG_HEADERS(config.h)
216 AM_INIT_AUTOMAKE
217
218 AC_CONFIG_FILES([
219 Makefile
220 src/Makefile
221 src/gigedit/Makefile
222 src/gigedit/gfx/Makefile
223 src/plugin/Makefile
224 gfx/Makefile
225 po/Makefile.in
226 debian/Makefile
227 doc/Makefile
228 doc/quickstart/Makefile
229 win32/libgigedit.dev
230 win32/gigedit.dev
231 win32/gigedit.nsi
232 win32/Makefile
233 gigedit.spec
234 ])
235 AC_OUTPUT

  ViewVC Help
Powered by ViewVC