/[svn]/libgig/trunk/configure.ac
ViewVC logotype

Contents of /libgig/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3980 - (show annotations) (download)
Tue Aug 3 14:37:25 2021 UTC (2 years, 7 months ago) by schoenebeck
File size: 4953 byte(s)
* Add new command line tool "wav2gig".

* Bumped version (4.3.0.svn30).

1 #------------------------------------------------------------------------------------
2 # Library's "official" release version:
3
4 m4_define(libgig_release_major, 4)
5 m4_define(libgig_release_minor, 3)
6 m4_define(libgig_release_build, 0.svn30)
7
8
9 AC_INIT([libgig],[libgig_release_major.libgig_release_minor.libgig_release_build])
10 AC_CONFIG_SRCDIR([configure.ac])
11
12 #------------------------------------------------------------------------------------
13 # The following is the libtool / shared library version. This doesn't have to
14 # do anything with the release version. It MUST conform to the following rules:
15 #
16 # 1. Start with version information of `0:0:0' for each libtool library.
17 # 2. Update the version information only immediately before a public release of
18 # your software. More frequent updates are unnecessary, and only guarantee
19 # that the current interface number gets larger faster.
20 # 3. If the library source code has changed at all since the last update, then
21 # increment revision (`c:r:a' becomes `c:r+1:a').
22 # 4. If any interfaces have been added, removed, or changed since the last update,
23 # increment current, and set revision to 0.
24 # 5. If any interfaces have been added since the last public release, then increment
25 # age.
26 # 6. If any interfaces have been removed since the last public release, then set age
27 # to 0.
28
29 LIBGIG_LT_CURRENT=10
30 LIBGIG_LT_REVISION=0
31 LIBGIG_LT_AGE=0
32 LIBGIG_SHARED_VERSION_INFO="$LIBGIG_LT_CURRENT:$LIBGIG_LT_REVISION:$LIBGIG_LT_AGE"
33
34 LIBAKAI_LT_CURRENT=0
35 LIBAKAI_LT_REVISION=0
36 LIBAKAI_LT_AGE=0
37 LIBAKAI_SHARED_VERSION_INFO="$LIBAKAI_LT_CURRENT:$LIBAKAI_LT_REVISION:$LIBAKAI_LT_AGE"
38
39
40 AC_LANG([C++])
41 AC_PROG_CXX
42 AC_LIBTOOL_WIN32_DLL
43 AC_PROG_LIBTOOL
44
45 AC_C_BIGENDIAN
46
47 AC_SUBST(LIBGIG_SHLIB_VERSION_ARG)
48 AC_SUBST(LIBGIG_SHARED_VERSION_INFO)
49 AC_SUBST(LIBGIG_RELEASE_MAJOR, libgig_release_major)
50 AC_SUBST(LIBGIG_RELEASE_MINOR, libgig_release_minor)
51 AC_SUBST(LIBGIG_RELEASE_BUILD, libgig_release_build)
52
53 AC_SUBST(LIBAKAI_SHLIB_VERSION_ARG)
54 AC_SUBST(LIBAKAI_SHARED_VERSION_INFO)
55 AC_SUBST(LIBAKAI_RELEASE_MAJOR, libakai_release_major)
56 AC_SUBST(LIBAKAI_RELEASE_MINOR, libakai_release_minor)
57 AC_SUBST(LIBAKAI_RELEASE_BUILD, libakai_release_build)
58
59 # make sure C++11 is supported by compiler
60 # (add CXXFLAGS if required [e.g. -std=c++11])
61 m4_ifdef([m4_include(m4/ax_cxx_compile_stdcxx.m4)],,
62 [sinclude([m4/ax_cxx_compile_stdcxx.m4])])
63 AX_CXX_COMPILE_STDCXX(11, [], mandatory)
64
65 have_audio_file_lib="false"
66
67 # check for presence of libsndfile
68 PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.2, ac_cv_sndfile=1, ac_cv_sndfile=0)
69 AM_CONDITIONAL(HAVE_SNDFILE, test $ac_cv_sndfile = "1")
70 AC_DEFINE_UNQUOTED([HAVE_SNDFILE],${ac_cv_sndfile}, [Set to 1 if you have libsndfile.])
71 AC_SUBST(SNDFILE_CFLAGS)
72 AC_SUBST(SNDFILE_LIBS)
73 if test "$ac_cv_sndfile" = "1"; then
74 have_audio_file_lib="true";
75 else
76 # no libsndfile? then check for presence of libaudiofile
77 PKG_CHECK_MODULES(AUDIOFILE, audiofile >= 0.2.3, ac_cv_audiofile=1, ac_cv_audiofile=0)
78 AC_DEFINE_UNQUOTED([HAVE_AUDIOFILE],${ac_cv_audiofile}, [Set to 1 if you have libaudiofile.])
79 AC_SUBST(AUDIOFILE_CFLAGS)
80 AC_SUBST(AUDIOFILE_LIBS)
81 if test "$ac_cv_audiofile" = "1"; then
82 have_audio_file_lib="true";
83 fi
84 fi
85 if test "$have_audio_file_lib" = "false"; then
86 echo "No audio file library found!"
87 echo "Sorry, you need either libsndfile or libaudiofile to compile libgig."
88 echo "This is needed for the gigextract utility to write audio files."
89 exit -1;
90 fi
91
92 AC_CHECK_HEADERS(uuid/uuid.h)
93 AC_SEARCH_LIBS(uuid_generate, uuid)
94 AC_CHECK_FUNCS(uuid_generate)
95 AC_CHECK_FUNCS(vasprintf)
96
97 case "$host" in
98 *mingw*|*cygwin*)
99 win32=yes
100 ;;
101 *)
102 win32=no
103 ;;
104 esac
105 AM_CONDITIONAL(WIN32, test "$win32" = "yes")
106
107 case "$host" in
108 *-*-darwin*)
109 mac=yes
110 ;;
111 *)
112 mac=no
113 ;;
114 esac
115 AM_CONDITIONAL(MAC, test "$mac" = "yes")
116
117 if test "$ac_cv_func_uuid_generate" = no -a "$mac" = no -a "$win32" = no; then
118 AC_MSG_WARN([No UUID generate function found.
119 *** libgig will not be able to create DLSIDs in DLS and gig files.
120 *** Install libuuid from e2fsprogs to solve this. Package might be called
121 *** uuid-dev, libext2fs2-devel or e2fsprogs-devel.])
122 exit -1;
123 fi
124
125 AC_CONFIG_HEADERS([config.h])
126 AM_INIT_AUTOMAKE
127
128 AC_CONFIG_FILES([\
129 Doxyfile \
130 gig.pc \
131 akai.pc \
132 libgig.spec \
133 Makefile \
134 src/Makefile \
135 src/testcases/Makefile \
136 src/tools/Makefile \
137 doc/Makefile \
138 man/Makefile \
139 man/dlsdump.1 \
140 man/gigdump.1 \
141 man/gigextract.1 \
142 man/gigmerge.1 \
143 man/gig2mono.1 \
144 man/gig2stereo.1 \
145 man/rifftree.1 \
146 man/sf2dump.1 \
147 man/sf2extract.1 \
148 man/korgdump.1 \
149 man/korg2gig.1 \
150 man/akaidump.1 \
151 man/akaiextract.1 \
152 man/wav2gig.1 \
153 debian/Makefile \
154 osx/Makefile \
155 osx/libgig.xcodeproj/Makefile \
156 win32/Makefile \
157 win32/libgig.dev \
158 ])
159 AC_OUTPUT

  ViewVC Help
Powered by ViewVC