/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3428 - (show annotations) (download)
Sat Jul 21 22:22:35 2018 UTC (5 years, 8 months ago) by capela
File size: 18865 byte(s)
- Preparations for v0.5.2 (summer'18) release.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.5.2, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^_]]*[[_v]]//i')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]\+/./g')
15 ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null)
16 if test "x$ac_cv_build_version_extra" != "xmaster"; then
17 ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]"
18 fi
19 else
20 ac_cv_build_version=$PACKAGE_VERSION
21 fi
22 ])
23 ac_build_version="$ac_cv_build_version"
24 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
25
26 # Sanitized version string.
27 AC_CACHE_VAL([ac_cv_version], [
28 ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/')
29 ])
30 ac_version="$ac_cv_version"
31 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
32 AC_SUBST(ac_version)
33
34 # Set default installation prefix.
35 AC_PREFIX_DEFAULT(/usr/local)
36 if test "x$prefix" = "xNONE"; then
37 prefix=$ac_default_prefix
38 fi
39 if test "x$exec_prefix" = "xNONE"; then
40 exec_prefix=$prefix
41 fi
42 eval ac_prefix=$prefix
43 AC_SUBST(ac_prefix)
44 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
45
46 # Set default installation directories.
47 eval ac_bindir=$bindir
48 AC_SUBST(ac_bindir)
49 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
50
51 eval ac_libdir=$libdir
52 AC_SUBST(ac_libdir)
53 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
54
55 eval datarootdir=$datarootdir
56 eval ac_datadir=$datadir
57 AC_SUBST(ac_datadir)
58 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
59
60 eval ac_mandir=$mandir
61 AC_SUBST(ac_mandir)
62 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
63
64
65 # Enable debugging argument option.
66 AC_ARG_ENABLE(debug,
67 AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
68 [ac_debug="$enableval"])
69
70 if test "x$ac_debug" = "xyes"; then
71 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
72 ac_stacktrace="yes"
73 ac_debug="debug"
74 else
75 ac_stacktrace="no"
76 ac_debug="release"
77 fi
78 AC_SUBST(ac_debug)
79
80
81 # Enable Qt4/5 availability.
82 AC_ARG_ENABLE(qt4,
83 AS_HELP_STRING([--enable-qt4], [enable Qt4 build (default=no)]),
84 [ac_qt4="$enableval"],
85 [ac_qt4="no"])
86
87
88 # Enable libgig availability.
89 AC_ARG_ENABLE(libgig,
90 AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
91 [ac_libgig="$enableval"],
92 [ac_libgig="yes"])
93
94 # Enable X11 unique/single instance.
95 AC_ARG_ENABLE(xunique,
96 AS_HELP_STRING([--enable-xunique], [enable X11 unique/single instance (default=yes)]),
97 [ac_xunique="$enableval"],
98 [ac_xunique="yes"])
99
100 # Enable debugger stack-trace option (assumes --enable-debug).
101 AC_ARG_ENABLE(stacktrace,
102 AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
103 [ac_stacktrace="$enableval"])
104
105
106 # Standard installation base dirs.
107 ac_path=$PATH
108 ac_with_paths=""
109
110 # Set for alternate Qt4/5 installation dir.
111 AC_ARG_WITH(qt,
112 AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]),
113 [ac_qt_path="$withval"], [ac_qt_path="no"])
114
115 AC_ARG_WITH(qt4,
116 AS_HELP_STRING([--with-qt4=PATH], [use alternate Qt4 install path]),
117 [ac_qt4_path="$withval"], [ac_qt4_path="no"])
118
119 AC_ARG_WITH(qt5,
120 AS_HELP_STRING([--with-qt5=PATH], [use alternate Qt5 install path]),
121 [ac_qt5_path="$withval"], [ac_qt5_path="no"])
122
123 if test "x$ac_qt_path" != "xno"; then
124 ac_path="$ac_qt_path/bin:$ac_path"
125 fi
126
127 if test "x$ac_qt4_path" != "xno"; then
128 ac_path="$ac_qt4_path/bin:$ac_path"
129 ac_qt4="yes"
130 fi
131
132 if test "x$ac_qt5_path" != "xno"; then
133 ac_path="$ac_qt5_path/bin:$ac_path"
134 ac_qt4="no"
135 fi
136
137 # Set for alternate liblscp installation dir.
138 AC_ARG_WITH(liblscp,
139 AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
140 [ac_with_paths="$ac_with_paths $withval"])
141
142 # Set for alternate libgig installation dir.
143 AC_ARG_WITH(libgig,
144 AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
145 [ac_with_paths="$ac_with_paths $withval"])
146
147
148 # Honor user specified flags.
149 ac_cflags=$CFLAGS
150 ac_ldflags=$LDFLAGS
151
152
153 # Checks for programs.
154 AC_PROG_CPP
155 AC_PROG_CXX
156 AC_PROG_CXXCPP
157
158 # Checks for languages.
159 AC_LANG_CPLUSPLUS
160
161 # Check for pkg-config.
162 PKG_PROG_PKG_CONFIG
163
164 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
165 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
166 ac_cv_gxx_version_major=$($CC -dumpversion)
167 if test -n "$ac_cv_gxx_version_major"; then
168 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
169 fi
170 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
171 ])
172 ac_gxx_version_major=$ac_cv_gxx_version_major
173 if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then
174 CXXFLAGS="-std=c++11 $CXXFLAGS"
175 fi
176
177 # Check for proper flags.
178 ac_arch=$(uname -m)
179
180 # Check for install paths and alternatives...
181 ac_libdirs="lib"
182
183 if test "x$ac_arch" = "xx86_64"; then
184 ac_libdirs="$ac_libdirs lib64"
185 fi
186
187 CFLAGS="-fPIC $CFLAGS"
188 CPPFLAGS="-fPIC $CPPFLAGS"
189
190 # Prepend alternate dependencies paths.
191 for X in $ac_with_paths; do
192 if test -d $X/bin; then
193 ac_path="$X/bin:$ac_path"
194 fi
195 if test -d $X/include; then
196 CFLAGS="-I$X/include $CFLAGS "
197 CPPFLAGS="-I$X/include $CPPFLAGS"
198 ac_incpath="$X/include $ac_incpath"
199 fi
200 for Y in $ac_libdirs; do
201 if test -d $X/$Y; then
202 LIBS="-L$X/$Y $LIBS"
203 ac_libs="-L$X/$Y $ac_libs"
204 fi
205 done
206 done
207
208 # A common error message:
209 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
210
211 # Check for proper qmake path/version alternatives.
212 AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path)
213
214 if test "x$ac_qmake" = "xno"; then
215 if test "x$ac_qt4" = "xyes"; then
216 AC_PATH_TOOL(ac_cv_qmake, qmake-qt4, [no], $ac_path)
217 ac_qmake=$ac_cv_qmake
218 else
219 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
220 ac_qmake=$ac_cv_qmake
221 fi
222 fi
223
224 # Check for proper Qt major version.
225 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
226 ac_cv_qt_version_major=$($ac_qmake -query QT_VERSION | cut -d'.' -f1)
227 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
228 ])
229 ac_qt_version_major=$ac_cv_qt_version_major
230 if test "x$ac_qt4" = "xyes"; then
231 if test $ac_qt_version_major -ne 4; then
232 AC_PATH_TOOL(ac_cv_qmake, qmake-qt4, [no], $ac_path)
233 ac_qmake=$ac_cv_qmake
234 fi
235 else
236 if test $ac_qt_version_major -ne 5; then
237 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
238 ac_qmake=$ac_cv_qmake
239 fi
240 fi
241
242 if test "x$ac_qmake" = "xno"; then
243 if test "x$ac_qt4" = "xyes"; then
244 AC_MSG_ERROR([qmake-qt4 $ac_errmsg (qt4-devel)])
245 else
246 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
247 fi
248 fi
249
250 # Check for proper Qt install path.
251 AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [
252 ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS)
253 ])
254 ac_qt_install_path=$ac_cv_qt_install_path
255 if test -d $ac_qt_install_path; then
256 ac_path="$ac_qt_install_path:$ac_path"
257 fi
258
259 # Check it again, now with updated PATH, just in case...
260 AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path)
261 ac_qmake=$ac_cv_qmake
262 if test "x$ac_qmake" = "xno"; then
263 AC_MSG_ERROR([qmake $ac_errmsg])
264 fi
265
266 AC_SUBST(ac_qmake)
267
268 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
269 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
270 ])
271 ac_qt_install_headers=$ac_cv_qt_install_headers
272 if test -d $ac_qt_install_headers; then
273 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
274 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
275 ac_incpath="$ac_qt_install_headers $ac_incpath"
276 fi
277
278 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
279 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
280 ])
281 ac_qt_install_libs=$ac_cv_qt_install_libs
282 if test -d $ac_qt_install_libs; then
283 LIBS="-L$ac_qt_install_libs $LIBS"
284 ac_libs="-L$ac_qt_install_libs $ac_libs"
285 fi
286
287 # Finally, check for proper Qt4/5 version.
288 if test "x$ac_qt4" = "xyes"; then
289 AC_CACHE_CHECK([for Qt library version >= 4.4],
290 ac_cv_qtversion, [
291 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
292 #if QT_VERSION < 0x040400 || QT_VERSION >= 0x050000
293 #error Qt library 4.4 or greater required.
294 #endif
295 ], ac_cv_qtversion="yes", [
296 echo "no; Qt 4.4 or greater is required"
297 exit 1
298 ])
299 ])
300 else
301 AC_CACHE_CHECK([for Qt library version >= 5.1],
302 ac_cv_qtversion, [
303 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
304 #if QT_VERSION < 0x050100 || QT_VERSION >= 0x060000
305 #error Qt library 5.1 or greater required.
306 #endif
307 ], ac_cv_qtversion="yes", [
308 echo "no; Qt 5.1 or greater is required"
309 exit 1
310 ])
311 ])
312 fi
313
314 # Check for Qt moc utility.
315 AC_PATH_TOOL(ac_moc, moc, [no], $ac_path)
316 if test "x$ac_moc" = "xno"; then
317 AC_MSG_ERROR([moc $ac_errmsg])
318 fi
319 AC_SUBST(ac_moc)
320
321 # Check for Qt uic utility.
322 AC_PATH_TOOL(ac_uic, uic, [no], $ac_path)
323 if test "x$ac_uic" = "xno"; then
324 AC_MSG_ERROR([uic $ac_errmsg])
325 fi
326 AC_SUBST(ac_uic)
327
328 # Check for Qt lupdate utility.
329 AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path)
330 if test "x$ac_lupdate" = "xno"; then
331 AC_MSG_ERROR([lupdate $ac_errmsg])
332 fi
333 AC_SUBST(ac_lupdate)
334
335 # Check for Qt lrelease utility.
336 AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path)
337 if test "x$ac_release" = "xno"; then
338 AC_MSG_ERROR([lrelease $ac_errmsg])
339 fi
340 AC_SUBST(ac_lrelease)
341
342
343 # Checks for libraries.
344 AC_CHECK_LIB(m, main)
345 AC_CHECK_LIB(X11, main)
346 AC_CHECK_LIB(Xext, main)
347
348 # Check for round math function.
349 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
350 if test "x$ac_round" = "xyes"; then
351 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
352 fi
353
354 # Check for mandatory libraries.
355 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
356 if test "x$ac_liblscp" = "xyes"; then
357 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
358 ac_cflags="$ac_cflags $LSCP_CFLAGS"
359 ac_libs="$ac_libs $LSCP_LIBS"
360 CFLAGS="$CFLAGS $LSCP_CFLAGS"
361 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
362 LIBS="$LIBS $LSCP_LIBS"
363 else
364 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
365 fi
366
367 case "{$host}" in
368 *mingw*)
369 ac_libs="$ac_libs -lws2_32"
370 LIBS="$LIBS -lws2_32"
371 ;;
372 esac
373
374 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
375 ac_cv_instrument_name, [
376 AC_TRY_COMPILE([#include "lscp/client.h"], [
377 lscp_channel_info_t info;
378 info.instrument_name = 0;
379 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
380 ])
381 ac_instrument_name=$ac_cv_instrument_name
382 if test "x$ac_instrument_name" = "xyes"; then
383 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
384 fi
385
386 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
387 ac_cv_mute_solo, [
388 AC_TRY_COMPILE([#include "lscp/client.h"], [
389 lscp_channel_info_t info;
390 info.mute = 0;
391 info.solo = 0;
392 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
393 ])
394 ac_mute_solo=$ac_cv_mute_solo
395 if test "x$ac_mute_solo" = "xyes"; then
396 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
397 fi
398 if test "x$ac_mute_solo" = "xyes"; then
399 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
400 fi
401 if test "x$ac_mute_solo" = "xyes"; then
402 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
403 fi
404
405 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
406 if test "x$ac_midi_instrument" = "xyes"; then
407 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
408 fi
409
410 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
411 if test "x$ac_fxsend" = "xyes"; then
412 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
413 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
414 ac_cv_fxsend_level, [
415 AC_TRY_COMPILE([#include "lscp/client.h"], [
416 lscp_fxsend_info_t info;
417 info.level = 0.0f;
418 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
419 ])
420 ac_fxsend_level=$ac_cv_fxsend_level
421 if test "x$ac_fxsend_level" = "xyes"; then
422 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
423 fi
424 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
425 if test "x$ac_fxsend_rename" = "xyes"; then
426 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
427 fi
428 fi
429
430 AC_CACHE_CHECK([for audio_routing array type],
431 ac_cv_audio_routing, [
432 AC_TRY_COMPILE([#include "lscp/client.h"], [
433 lscp_channel_info_t info;
434 char ch = info.audio_routing[0][0];
435 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
436 ])
437 ac_audio_routing=$ac_cv_audio_routing
438 if test "x$ac_audio_routing" = "xyes"; then
439 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
440 fi
441
442 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
443 if test "x$ac_volume" = "xyes"; then
444 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
445 fi
446
447 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
448 if test "x$ac_edit_instrument" = "xyes"; then
449 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
450 fi
451
452 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
453 ac_cv_channel_midi_event, [
454 AC_TRY_COMPILE([
455 #include "lscp/client.h"
456 #include "lscp/event.h"
457 ], [
458 lscp_event_t ev;
459 ev = LSCP_EVENT_CHANNEL_MIDI;
460 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
461 ])
462 ac_channel_midi_event=$ac_cv_channel_midi_event
463 if test "x$ac_channel_midi_event" = "xyes"; then
464 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
465 fi
466
467 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
468 ac_cv_device_midi_event, [
469 AC_TRY_COMPILE([
470 #include "lscp/client.h"
471 #include "lscp/event.h"
472 ], [
473 lscp_event_t ev;
474 ev = LSCP_EVENT_DEVICE_MIDI;
475 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
476 ])
477 ac_device_midi_event=$ac_cv_device_midi_event
478 if test "x$ac_device_midi_event" = "xyes"; then
479 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
480 fi
481
482 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
483 if test "x$ac_max_voices" = "xyes"; then
484 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
485 fi
486
487 # Check for optional libraries.
488 if test "x$ac_libgig" = "xyes"; then
489 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
490 fi
491 if test "x$ac_libgig" = "xyes"; then
492 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
493 ac_cflags="$ac_cflags $GIG_CFLAGS"
494 ac_libs="$ac_libs $GIG_LIBS"
495 CFLAGS="$CFLAGS $GIG_CFLAGS"
496 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
497 LIBS="$LIBS $GIG_LIBS"
498 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
499 ac_libgig_setautoload="yes"
500 else
501 AC_MSG_WARN([*** GIG library not found (libgig).])
502 fi
503
504 # Check for round math function.
505 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
506 if test "x$ac_round" = "xyes"; then
507 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
508 fi
509
510
511 # Checks for header files.
512 AC_HEADER_STDC
513 AC_HEADER_SYS_WAIT
514 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
515
516 if test "x$ac_libgig" = "xyes"; then
517 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
518 if test "x$ac_libgig_sf2" = "xyes"; then
519 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
520 fi
521 fi
522
523 # Check for X11 unique/single instance.
524 if test "x$ac_xunique" = "xyes" -a "x$ac_qt4" = "xno"; then
525 PKG_CHECK_MODULES([QT5X11EXTRAS], [Qt5X11Extras], [ac_xunique="yes"], [ac_xunique="no"])
526 fi
527 if test "x$ac_xunique" = "xyes"; then
528 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if X11 unique/single instance is enabled.])
529 if test "x$ac_qt4" = "xno"; then
530 ac_qx11extras="x11extras"
531 fi
532 # Some recent distros (eg. fedora, debian) require this.
533 if test "x$ac_cv_lib_X11_main" = "xyes"; then
534 ac_libs="$ac_libs -lX11"
535 fi
536 fi
537 AC_SUBST(ac_qx11extras)
538
539 # Check for debugging stack-trace.
540 if test "x$ac_stacktrace" = "xyes"; then
541 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
542 fi
543
544 AC_SUBST(ac_cflags)
545 AC_SUBST(ac_ldflags)
546 AC_SUBST(ac_incpath)
547 AC_SUBST(ac_libs)
548
549
550 # Checks for typedefs, structures, and compiler characteristics.
551 # AC_C_CONST
552
553 # Checks for library functions.
554 AC_CHECK_FUNCS(system)
555
556 # Finally produce a configure header file and the makefiles.
557 AC_OUTPUT
558
559 # make clean > /dev/null 2>&1
560
561 # Output summary message
562
563 echo
564 echo " $PACKAGE_NAME $ac_build_version"
565 echo
566 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
567 echo
568 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
569 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
570 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
571 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
572 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
573 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
574 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
575 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
576 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
577 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
578 if test "x$ac_libgig" = "xyes"; then
579 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
580 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
581 fi
582 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
583 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
584 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
585 echo
586 echo " X11 Unique/Single instance . . . . . . . . . . . .: $ac_xunique"
587 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
588 echo
589 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
590 echo
591 echo "Now type 'make', followed by 'make install' as root."
592 echo

  ViewVC Help
Powered by ViewVC