/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3613 - (show annotations) (download)
Tue Oct 1 08:35:49 2019 UTC (4 years, 5 months ago) by capela
File size: 17624 byte(s)
- Modernize channel strip list iterations.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.5.7, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^_]]*[[_v]]//i')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]\+/./g')
15 ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null)
16 if test "x$ac_cv_build_version_extra" != "xmaster"; then
17 ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]"
18 fi
19 else
20 ac_cv_build_version=$PACKAGE_VERSION
21 fi
22 ])
23 ac_build_version="$ac_cv_build_version"
24 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
25
26 # Sanitized version string.
27 AC_CACHE_VAL([ac_cv_version], [
28 ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/')
29 ])
30 ac_version="$ac_cv_version"
31 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
32 AC_SUBST(ac_version)
33
34 # Set default installation prefix.
35 AC_PREFIX_DEFAULT(/usr/local)
36 if test "x$prefix" = "xNONE"; then
37 prefix=$ac_default_prefix
38 fi
39 if test "x$exec_prefix" = "xNONE"; then
40 exec_prefix=$prefix
41 fi
42 eval ac_prefix=$prefix
43 AC_SUBST(ac_prefix)
44 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
45
46 # Set default installation directories.
47 eval ac_bindir=$bindir
48 AC_SUBST(ac_bindir)
49 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
50
51 eval ac_libdir=$libdir
52 AC_SUBST(ac_libdir)
53 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
54
55 eval datarootdir=$datarootdir
56 eval ac_datadir=$datadir
57 AC_SUBST(ac_datadir)
58 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
59
60 eval ac_mandir=$mandir
61 AC_SUBST(ac_mandir)
62 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
63
64
65 # Enable debugging argument option.
66 AC_ARG_ENABLE(debug,
67 AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
68 [ac_debug="$enableval"])
69
70 if test "x$ac_debug" = "xyes"; then
71 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
72 ac_stacktrace="yes"
73 ac_debug="debug"
74 else
75 ac_stacktrace="no"
76 ac_debug="release"
77 fi
78 AC_SUBST(ac_debug)
79
80
81 # Enable libgig availability.
82 AC_ARG_ENABLE(libgig,
83 AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
84 [ac_libgig="$enableval"],
85 [ac_libgig="yes"])
86
87 # Enable unique/single instance.
88 AC_ARG_ENABLE(xunique,
89 AS_HELP_STRING([--enable-xunique], [enable unique/single instance (default=yes)]),
90 [ac_xunique="$enableval"],
91 [ac_xunique="yes"])
92
93 # Enable debugger stack-trace option (assumes --enable-debug).
94 AC_ARG_ENABLE(stacktrace,
95 AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
96 [ac_stacktrace="$enableval"])
97
98
99 # Standard installation base dirs.
100 ac_path=$PATH
101 ac_with_paths=""
102
103 # Set for alternate Qt installation dir.
104 AC_ARG_WITH(qt,
105 AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]),
106 [ac_qt_path="$withval"], [ac_qt_path="no"])
107
108 if test "x$ac_qt_path" != "xno"; then
109 ac_path="$ac_qt_path/bin:$ac_path"
110 fi
111
112 # Set for alternate liblscp installation dir.
113 AC_ARG_WITH(liblscp,
114 AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
115 [ac_with_paths="$ac_with_paths $withval"])
116
117 # Set for alternate libgig installation dir.
118 AC_ARG_WITH(libgig,
119 AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
120 [ac_with_paths="$ac_with_paths $withval"])
121
122
123 # Honor user specified flags.
124 ac_cflags=$CFLAGS
125 ac_ldflags=$LDFLAGS
126
127
128 # Checks for programs.
129 AC_PROG_CPP
130 AC_PROG_CXX
131 AC_PROG_CXXCPP
132
133 # Checks for languages.
134 AC_LANG_CPLUSPLUS
135
136 # Check for pkg-config.
137 PKG_PROG_PKG_CONFIG
138
139 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
140 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
141 ac_cv_gxx_version_major=$($CC -dumpversion)
142 if test -n "$ac_cv_gxx_version_major"; then
143 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
144 fi
145 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
146 ])
147 ac_gxx_version_major=$ac_cv_gxx_version_major
148 if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then
149 CPPFLAGS="-std=c++11 $CPPFLAGS"
150 ac_cflags="-std=c++11 $ac_cflags"
151 fi
152
153 # Check for proper flags.
154 ac_arch=$(uname -m)
155
156 # Check for install paths and alternatives...
157 ac_libdirs="lib"
158
159 if test "x$ac_arch" = "xx86_64"; then
160 ac_libdirs="$ac_libdirs lib64"
161 fi
162
163 CFLAGS="-fPIC $CFLAGS"
164 CPPFLAGS="-fPIC $CPPFLAGS"
165
166 # Prepend alternate dependencies paths.
167 for X in $ac_with_paths; do
168 if test -d $X/bin; then
169 ac_path="$X/bin:$ac_path"
170 fi
171 if test -d $X/include; then
172 CFLAGS="-I$X/include $CFLAGS "
173 CPPFLAGS="-I$X/include $CPPFLAGS"
174 ac_incpath="$X/include $ac_incpath"
175 fi
176 for Y in $ac_libdirs; do
177 if test -d $X/$Y; then
178 LIBS="-L$X/$Y $LIBS"
179 ac_libs="-L$X/$Y $ac_libs"
180 fi
181 done
182 done
183
184 # A common error message:
185 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
186
187 # Check for qtchooser availability.
188 AC_PATH_TOOL(ac_qtchooser, qtchooser, [no], $ac_path)
189 if test -x $ac_qtchooser; then
190 export QT_SELECT=5
191 fi
192
193 # Check for proper qmake path/version alternatives.
194 AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path)
195 if test "x$ac_qmake" = "xno"; then
196 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
197 ac_qmake=$ac_cv_qmake
198 fi
199
200 # Check for proper Qt major version.
201 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
202 ac_cv_qt_version_major=$($ac_qmake -query QT_VERSION | cut -d'.' -f1)
203 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
204 ])
205 ac_qt_version_major=$ac_cv_qt_version_major
206 if test $ac_qt_version_major -ne 5; then
207 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
208 ac_qmake=$ac_cv_qmake
209 fi
210
211 if test "x$ac_qmake" = "xno"; then
212 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
213 fi
214
215 # Check for proper Qt install path.
216 AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [
217 ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS)
218 ])
219 ac_qt_install_path=$ac_cv_qt_install_path
220 if test -d $ac_qt_install_path; then
221 ac_path="$ac_qt_install_path:$ac_path"
222 fi
223
224 # Check it again, now with updated PATH, just in case...
225 AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path)
226 ac_qmake=$ac_cv_qmake
227 if test "x$ac_qmake" = "xno"; then
228 AC_MSG_ERROR([qmake $ac_errmsg])
229 fi
230
231 AC_SUBST(ac_qmake)
232
233 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
234 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
235 ])
236 ac_qt_install_headers=$ac_cv_qt_install_headers
237 if test -d $ac_qt_install_headers; then
238 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
239 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
240 ac_incpath="$ac_qt_install_headers $ac_incpath"
241 fi
242
243 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
244 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
245 ])
246 ac_qt_install_libs=$ac_cv_qt_install_libs
247 if test -d $ac_qt_install_libs; then
248 LIBS="-L$ac_qt_install_libs $LIBS"
249 ac_libs="-L$ac_qt_install_libs $ac_libs"
250 fi
251
252 # Finally, check for proper Qt version.
253 AC_CACHE_CHECK([for Qt library version >= 5.1],
254 ac_cv_qtversion, [
255 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
256 #if QT_VERSION < 0x050100
257 #error Qt library 5.1 or greater required.
258 #endif
259 ], ac_cv_qtversion="yes", [
260 echo "no; Qt 5.1 or greater is required"
261 exit 1
262 ])
263 ])
264
265 # Check for Qt moc utility.
266 AC_PATH_TOOL(ac_moc, moc, [no], $ac_path)
267 if test "x$ac_moc" = "xno"; then
268 AC_MSG_ERROR([moc $ac_errmsg])
269 fi
270 AC_SUBST(ac_moc)
271
272 # Check for Qt uic utility.
273 AC_PATH_TOOL(ac_uic, uic, [no], $ac_path)
274 if test "x$ac_uic" = "xno"; then
275 AC_MSG_ERROR([uic $ac_errmsg])
276 fi
277 AC_SUBST(ac_uic)
278
279
280 # Check for Qt lupdate utility.
281 AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path)
282 if test "x$ac_lupdate" = "xno"; then
283 AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt5, [no], $ac_path)
284 if test "x$ac_cv_lupdate" = "xno"; then
285 AC_MSG_ERROR([lupdate $ac_errmsg (qt5-linguist)])
286 else
287 ac_lupdate=$ac_cv_lupdate;
288 fi
289 fi
290 AC_SUBST(ac_lupdate)
291
292 # Check for Qt lrelease utility.
293 AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path)
294 if test "x$ac_lrelease" = "xno"; then
295 AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt5, [no], $ac_path)
296 if test "x$ac_cv_lrelease" = "xno"; then
297 AC_MSG_ERROR([lrelease $ac_errmsg (qt5-linguist)])
298 else
299 ac_lrelease=$ac_cv_lrelease;
300 fi
301 fi
302 AC_SUBST(ac_lrelease)
303
304
305 # Checks for libraries.
306 AC_CHECK_LIB(m, main)
307 AC_CHECK_LIB(X11, main)
308 AC_CHECK_LIB(Xext, main)
309
310 # Check for round math function.
311 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
312 if test "x$ac_round" = "xyes"; then
313 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
314 fi
315
316 # Check for mandatory libraries.
317 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
318 if test "x$ac_liblscp" = "xyes"; then
319 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
320 ac_cflags="$ac_cflags $LSCP_CFLAGS"
321 ac_libs="$ac_libs $LSCP_LIBS"
322 CFLAGS="$CFLAGS $LSCP_CFLAGS"
323 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
324 LIBS="$LIBS $LSCP_LIBS"
325 else
326 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
327 fi
328
329 case "{$host}" in
330 *mingw*)
331 ac_libs="$ac_libs -lws2_32"
332 LIBS="$LIBS -lws2_32"
333 ;;
334 esac
335
336 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
337 ac_cv_instrument_name, [
338 AC_TRY_COMPILE([#include "lscp/client.h"], [
339 lscp_channel_info_t info;
340 info.instrument_name = 0;
341 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
342 ])
343 ac_instrument_name=$ac_cv_instrument_name
344 if test "x$ac_instrument_name" = "xyes"; then
345 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
346 fi
347
348 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
349 ac_cv_mute_solo, [
350 AC_TRY_COMPILE([#include "lscp/client.h"], [
351 lscp_channel_info_t info;
352 info.mute = 0;
353 info.solo = 0;
354 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
355 ])
356 ac_mute_solo=$ac_cv_mute_solo
357 if test "x$ac_mute_solo" = "xyes"; then
358 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
359 fi
360 if test "x$ac_mute_solo" = "xyes"; then
361 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
362 fi
363 if test "x$ac_mute_solo" = "xyes"; then
364 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
365 fi
366
367 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
368 if test "x$ac_midi_instrument" = "xyes"; then
369 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
370 fi
371
372 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
373 if test "x$ac_fxsend" = "xyes"; then
374 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
375 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
376 ac_cv_fxsend_level, [
377 AC_TRY_COMPILE([#include "lscp/client.h"], [
378 lscp_fxsend_info_t info;
379 info.level = 0.0f;
380 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
381 ])
382 ac_fxsend_level=$ac_cv_fxsend_level
383 if test "x$ac_fxsend_level" = "xyes"; then
384 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
385 fi
386 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
387 if test "x$ac_fxsend_rename" = "xyes"; then
388 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
389 fi
390 fi
391
392 AC_CACHE_CHECK([for audio_routing array type],
393 ac_cv_audio_routing, [
394 AC_TRY_COMPILE([#include "lscp/client.h"], [
395 lscp_channel_info_t info;
396 char ch = info.audio_routing[0][0];
397 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
398 ])
399 ac_audio_routing=$ac_cv_audio_routing
400 if test "x$ac_audio_routing" = "xyes"; then
401 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
402 fi
403
404 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
405 if test "x$ac_volume" = "xyes"; then
406 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
407 fi
408
409 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
410 if test "x$ac_edit_instrument" = "xyes"; then
411 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
412 fi
413
414 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
415 ac_cv_channel_midi_event, [
416 AC_TRY_COMPILE([
417 #include "lscp/client.h"
418 #include "lscp/event.h"
419 ], [
420 lscp_event_t ev;
421 ev = LSCP_EVENT_CHANNEL_MIDI;
422 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
423 ])
424 ac_channel_midi_event=$ac_cv_channel_midi_event
425 if test "x$ac_channel_midi_event" = "xyes"; then
426 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
427 fi
428
429 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
430 ac_cv_device_midi_event, [
431 AC_TRY_COMPILE([
432 #include "lscp/client.h"
433 #include "lscp/event.h"
434 ], [
435 lscp_event_t ev;
436 ev = LSCP_EVENT_DEVICE_MIDI;
437 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
438 ])
439 ac_device_midi_event=$ac_cv_device_midi_event
440 if test "x$ac_device_midi_event" = "xyes"; then
441 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
442 fi
443
444 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
445 if test "x$ac_max_voices" = "xyes"; then
446 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
447 fi
448
449 # Check for optional libraries.
450 if test "x$ac_libgig" = "xyes"; then
451 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
452 fi
453 if test "x$ac_libgig" = "xyes"; then
454 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
455 ac_cflags="$ac_cflags $GIG_CFLAGS"
456 ac_libs="$ac_libs $GIG_LIBS"
457 CFLAGS="$CFLAGS $GIG_CFLAGS"
458 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
459 LIBS="$LIBS $GIG_LIBS"
460 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
461 ac_libgig_setautoload="yes"
462 else
463 AC_MSG_WARN([*** GIG library not found (libgig).])
464 fi
465
466 # Check for round math function.
467 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
468 if test "x$ac_round" = "xyes"; then
469 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
470 fi
471
472
473 # Checks for header files.
474 AC_HEADER_STDC
475 AC_HEADER_SYS_WAIT
476 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
477
478 if test "x$ac_libgig" = "xyes"; then
479 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
480 if test "x$ac_libgig_sf2" = "xyes"; then
481 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
482 fi
483 fi
484
485 # Check for unique/single instance support.
486 if test "x$ac_xunique" = "xyes"; then
487 PKG_CHECK_MODULES([QT5NETWORK], [Qt5Network], [ac_qt5network="yes"], [ac_qt5network="no"])
488 if test "x$ac_qt5network" = "xyes"; then
489 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if unique/single instance is enabled.])
490 ac_qnetwork="network"
491 fi
492 fi
493 AC_SUBST(ac_qnetwork)
494
495 # Check for debugging stack-trace.
496 if test "x$ac_stacktrace" = "xyes"; then
497 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
498 fi
499
500 AC_SUBST(ac_cflags)
501 AC_SUBST(ac_ldflags)
502 AC_SUBST(ac_incpath)
503 AC_SUBST(ac_libs)
504
505
506 # Checks for typedefs, structures, and compiler characteristics.
507 # AC_C_CONST
508
509 # Checks for library functions.
510 AC_CHECK_FUNCS(system)
511
512 # Finally produce a configure header file and the makefiles.
513 AC_OUTPUT
514
515 # make clean > /dev/null 2>&1
516
517 # Output summary message
518
519 echo
520 echo " $PACKAGE_NAME $ac_build_version"
521 echo
522 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
523 echo
524 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
525 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
526 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
527 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
528 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
529 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
530 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
531 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
532 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
533 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
534 if test "x$ac_libgig" = "xyes"; then
535 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
536 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
537 fi
538 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
539 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
540 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
541 echo
542 echo " Unique/Single instance support . . . . . . . . . .: $ac_xunique"
543 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
544 echo
545 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
546 echo
547 echo "Now type 'make', followed by 'make install' as root."
548 echo

  ViewVC Help
Powered by ViewVC