| 1 |
# Process this file with autoconf to produce a configure script. |
| 2 |
AC_INIT(Qsampler, 0.9.3, rncbc@rncbc.org, qsampler) |
| 3 |
|
| 4 |
AC_CONFIG_SRCDIR(src/qsampler.cpp) |
| 5 |
AC_CONFIG_HEADERS(src/config.h) |
| 6 |
AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri) |
| 7 |
|
| 8 |
# Build version string. |
| 9 |
AC_CACHE_VAL([ac_cv_build_version], [ |
| 10 |
ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null) |
| 11 |
if test -n "$ac_cv_build_version"; then |
| 12 |
ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^0-9]]\+//') |
| 13 |
ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./') |
| 14 |
ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]\+/./g') |
| 15 |
ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null) |
| 16 |
if test "x$ac_cv_build_version_extra" != "xmaster"; then |
| 17 |
ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]" |
| 18 |
fi |
| 19 |
else |
| 20 |
ac_cv_build_version=$PACKAGE_VERSION |
| 21 |
fi |
| 22 |
]) |
| 23 |
ac_build_version="$ac_cv_build_version" |
| 24 |
AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.]) |
| 25 |
|
| 26 |
# Sanitized version string. |
| 27 |
AC_CACHE_VAL([ac_cv_version], [ |
| 28 |
ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/') |
| 29 |
]) |
| 30 |
ac_version="$ac_cv_version" |
| 31 |
AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.]) |
| 32 |
AC_SUBST(ac_version) |
| 33 |
|
| 34 |
# Set default installation prefix. |
| 35 |
AC_PREFIX_DEFAULT(/usr/local) |
| 36 |
if test "x$prefix" = "xNONE"; then |
| 37 |
prefix=$ac_default_prefix |
| 38 |
fi |
| 39 |
if test "x$exec_prefix" = "xNONE"; then |
| 40 |
exec_prefix=$prefix |
| 41 |
fi |
| 42 |
eval ac_prefix=$prefix |
| 43 |
AC_SUBST(ac_prefix) |
| 44 |
AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.]) |
| 45 |
|
| 46 |
# Set default installation directories. |
| 47 |
eval ac_bindir=$bindir |
| 48 |
AC_SUBST(ac_bindir) |
| 49 |
AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.]) |
| 50 |
|
| 51 |
eval ac_libdir=$libdir |
| 52 |
AC_SUBST(ac_libdir) |
| 53 |
AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.]) |
| 54 |
|
| 55 |
eval datarootdir=$datarootdir |
| 56 |
eval ac_datadir=$datadir |
| 57 |
AC_SUBST(ac_datadir) |
| 58 |
AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.]) |
| 59 |
|
| 60 |
eval ac_mandir=$mandir |
| 61 |
AC_SUBST(ac_mandir) |
| 62 |
AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.]) |
| 63 |
|
| 64 |
|
| 65 |
# Enable debugging argument option. |
| 66 |
AC_ARG_ENABLE(debug, |
| 67 |
AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]), |
| 68 |
[ac_debug="$enableval"]) |
| 69 |
|
| 70 |
if test "x$ac_debug" = "xyes"; then |
| 71 |
AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.]) |
| 72 |
ac_stacktrace="yes" |
| 73 |
ac_debug="debug" |
| 74 |
else |
| 75 |
ac_stacktrace="no" |
| 76 |
ac_debug="release" |
| 77 |
fi |
| 78 |
AC_SUBST(ac_debug) |
| 79 |
|
| 80 |
|
| 81 |
# Enable libgig availability. |
| 82 |
AC_ARG_ENABLE(libgig, |
| 83 |
AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]), |
| 84 |
[ac_libgig="$enableval"], |
| 85 |
[ac_libgig="yes"]) |
| 86 |
|
| 87 |
# Enable unique/single instance. |
| 88 |
AC_ARG_ENABLE(xunique, |
| 89 |
AS_HELP_STRING([--enable-xunique], [enable unique/single instance (default=yes)]), |
| 90 |
[ac_xunique="$enableval"], |
| 91 |
[ac_xunique="yes"]) |
| 92 |
|
| 93 |
# Enable debugger stack-trace option (assumes --enable-debug). |
| 94 |
AC_ARG_ENABLE(stacktrace, |
| 95 |
AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]), |
| 96 |
[ac_stacktrace="$enableval"]) |
| 97 |
|
| 98 |
|
| 99 |
# Standard installation base dirs. |
| 100 |
ac_path=$PATH |
| 101 |
ac_pkg_config_path=$PKG_CONFIG_PATH |
| 102 |
ac_with_paths="" |
| 103 |
|
| 104 |
# Set for alternate Qt installation dir. |
| 105 |
AC_ARG_WITH(qt, |
| 106 |
AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]), |
| 107 |
[ac_qt_path="$withval"], [ac_qt_path="no"]) |
| 108 |
|
| 109 |
if test "x$ac_qt_path" != "xno"; then |
| 110 |
ac_path="$ac_qt_path/bin:$ac_path" |
| 111 |
ac_pkg_config_path="$ac_qt_path/lib/pkgconfig:$ac_pkg_config_path" |
| 112 |
fi |
| 113 |
|
| 114 |
# Set for alternate liblscp installation dir. |
| 115 |
AC_ARG_WITH(liblscp, |
| 116 |
AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]), |
| 117 |
[ac_with_paths="$ac_with_paths $withval"]) |
| 118 |
|
| 119 |
# Set for alternate libgig installation dir. |
| 120 |
AC_ARG_WITH(libgig, |
| 121 |
AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]), |
| 122 |
[ac_with_paths="$ac_with_paths $withval"]) |
| 123 |
|
| 124 |
|
| 125 |
# Honor user specified flags. |
| 126 |
ac_cflags=$CFLAGS |
| 127 |
ac_ldflags=$LDFLAGS |
| 128 |
|
| 129 |
|
| 130 |
# Checks for programs. |
| 131 |
AC_PROG_CPP |
| 132 |
AC_PROG_CXX |
| 133 |
AC_PROG_CXXCPP |
| 134 |
|
| 135 |
# Checks for languages. |
| 136 |
AC_LANG_CPLUSPLUS |
| 137 |
|
| 138 |
# Check for pkg-config. |
| 139 |
PKG_PROG_PKG_CONFIG |
| 140 |
|
| 141 |
# Check whether -std=c++11 support is necessary (4 < g++ version < 6). |
| 142 |
AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [ |
| 143 |
ac_cv_gxx_version_major=$($CC -dumpversion) |
| 144 |
if test -n "$ac_cv_gxx_version_major"; then |
| 145 |
ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1); |
| 146 |
fi |
| 147 |
ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0)) |
| 148 |
]) |
| 149 |
ac_gxx_version_major=$ac_cv_gxx_version_major |
| 150 |
if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then |
| 151 |
CXXFLAGS="-std=c++11 $CXXFLAGS" |
| 152 |
ac_cflags="-std=c++11 $ac_cflags" |
| 153 |
elif test $ac_gxx_version_major -ge 6 -a $ac_gxx_version_major -lt 11; then |
| 154 |
CXXFLAGS="-std=c++17 $CXXFLAGS" |
| 155 |
ac_cflags="-std=c++17 $ac_cflags" |
| 156 |
fi |
| 157 |
|
| 158 |
# Check for proper flags. |
| 159 |
ac_arch=$(uname -m) |
| 160 |
|
| 161 |
# Check for install paths and alternatives... |
| 162 |
ac_libdirs="lib" |
| 163 |
|
| 164 |
if test "x$ac_arch" = "xx86_64"; then |
| 165 |
ac_libdirs="$ac_libdirs lib64" |
| 166 |
fi |
| 167 |
|
| 168 |
CFLAGS="-fPIC $CFLAGS" |
| 169 |
CPPFLAGS="-fPIC $CPPFLAGS" |
| 170 |
|
| 171 |
# Prepend alternate dependencies paths. |
| 172 |
for X in $ac_with_paths; do |
| 173 |
if test -d $X/bin; then |
| 174 |
ac_path="$X/bin:$ac_path" |
| 175 |
fi |
| 176 |
if test -d $X/include; then |
| 177 |
CFLAGS="-I$X/include $CFLAGS " |
| 178 |
CPPFLAGS="-I$X/include $CPPFLAGS" |
| 179 |
ac_incpath="$X/include $ac_incpath" |
| 180 |
fi |
| 181 |
for Y in $ac_libdirs; do |
| 182 |
if test -d $X/$Y; then |
| 183 |
LIBS="-L$X/$Y $LIBS" |
| 184 |
ac_libs="-L$X/$Y $ac_libs" |
| 185 |
if test -d $X/$Y/pkgconfig; then |
| 186 |
ac_pkg_config_path="$X/$Y/pkgconfig:$ac_pkg_config_path" |
| 187 |
fi |
| 188 |
fi |
| 189 |
done |
| 190 |
done |
| 191 |
|
| 192 |
# Set pkg-config path. |
| 193 |
if test -n "$ac_pkg_config_path"; then |
| 194 |
export PKG_CONFIG_PATH=$ac_pkg_config_path |
| 195 |
fi |
| 196 |
|
| 197 |
|
| 198 |
# A common error message: |
| 199 |
ac_errmsg="not found in current PATH. Maybe QT development environment isn't available." |
| 200 |
|
| 201 |
# Check for qtchooser availability. |
| 202 |
AC_PATH_TOOL(ac_qtchooser, qtchooser, [no], $ac_path) |
| 203 |
if test -x $ac_qtchooser; then |
| 204 |
export QT_SELECT=5 |
| 205 |
fi |
| 206 |
|
| 207 |
# Check for proper qmake path/version alternatives. |
| 208 |
AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path) |
| 209 |
if test "x$ac_qmake" = "xno"; then |
| 210 |
AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path) |
| 211 |
ac_qmake=$ac_cv_qmake |
| 212 |
fi |
| 213 |
if test "x$ac_qmake" = "xno"; then |
| 214 |
AC_PATH_TOOL(ac_cv_qmake, qmake-qt6, [no], $ac_path) |
| 215 |
ac_qmake=$ac_cv_qmake |
| 216 |
fi |
| 217 |
|
| 218 |
# Check for proper Qt major version. |
| 219 |
AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [ |
| 220 |
ac_cv_qt_version=$($ac_qmake -query QT_VERSION) |
| 221 |
ac_cv_qt_version_major=$(echo $ac_cv_qt_version | cut -d'.' -f1) |
| 222 |
ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0)) |
| 223 |
]) |
| 224 |
ac_qt_version=$ac_cv_qt_version |
| 225 |
ac_qt_version_major=$ac_cv_qt_version_major |
| 226 |
if test "x$ac_qmake" = "xno"; then |
| 227 |
if test $ac_qt_version_major -lt 6; then |
| 228 |
AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)]) |
| 229 |
else |
| 230 |
AC_MSG_ERROR([qmake-qt6 $ac_errmsg (qt6-devel)]) |
| 231 |
fi |
| 232 |
fi |
| 233 |
|
| 234 |
# Check for proper Qt install path. |
| 235 |
AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [ |
| 236 |
ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS) |
| 237 |
]) |
| 238 |
ac_qt_install_path=$ac_cv_qt_install_path |
| 239 |
if test -d $ac_qt_install_path; then |
| 240 |
ac_path="$ac_qt_install_path:$ac_path" |
| 241 |
fi |
| 242 |
|
| 243 |
# Check it again, now with updated PATH, just in case... |
| 244 |
AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path) |
| 245 |
ac_qmake=$ac_cv_qmake |
| 246 |
if test "x$ac_qmake" = "xno"; then |
| 247 |
AC_MSG_ERROR([qmake $ac_errmsg]) |
| 248 |
fi |
| 249 |
|
| 250 |
AC_SUBST(ac_qmake) |
| 251 |
|
| 252 |
AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [ |
| 253 |
ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS) |
| 254 |
]) |
| 255 |
ac_qt_install_headers=$ac_cv_qt_install_headers |
| 256 |
if test -d $ac_qt_install_headers; then |
| 257 |
CFLAGS="-I$ac_qt_install_headers $CFLAGS " |
| 258 |
CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS" |
| 259 |
ac_incpath="$ac_qt_install_headers $ac_incpath" |
| 260 |
fi |
| 261 |
|
| 262 |
AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [ |
| 263 |
ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS) |
| 264 |
]) |
| 265 |
ac_qt_install_libs=$ac_cv_qt_install_libs |
| 266 |
if test -d $ac_qt_install_libs; then |
| 267 |
LIBS="-L$ac_qt_install_libs $LIBS" |
| 268 |
ac_libs="-L$ac_qt_install_libs $ac_libs" |
| 269 |
fi |
| 270 |
|
| 271 |
# Finally, check for proper Qt version. |
| 272 |
AC_CACHE_CHECK([for Qt library version >= 5.1], |
| 273 |
ac_cv_qtversion, [ |
| 274 |
AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [ |
| 275 |
#if QT_VERSION < 0x050100 |
| 276 |
#error Qt library 5.1 or greater required. |
| 277 |
#endif |
| 278 |
], ac_cv_qtversion="yes", [ |
| 279 |
echo "no; Qt 5.1 or greater is required" |
| 280 |
exit 1 |
| 281 |
]) |
| 282 |
]) |
| 283 |
|
| 284 |
# Check for Qt moc utility. |
| 285 |
AC_PATH_TOOL(ac_moc, moc, [no], $ac_path) |
| 286 |
if test "x$ac_moc" = "xno"; then |
| 287 |
AC_MSG_ERROR([moc $ac_errmsg]) |
| 288 |
fi |
| 289 |
AC_SUBST(ac_moc) |
| 290 |
|
| 291 |
# Check for Qt uic utility. |
| 292 |
AC_PATH_TOOL(ac_uic, uic, [no], $ac_path) |
| 293 |
if test "x$ac_uic" = "xno"; then |
| 294 |
AC_MSG_ERROR([uic $ac_errmsg]) |
| 295 |
fi |
| 296 |
AC_SUBST(ac_uic) |
| 297 |
|
| 298 |
|
| 299 |
# Check for Qt lupdate utility. |
| 300 |
AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path) |
| 301 |
if test "x$ac_lupdate" = "xno"; then |
| 302 |
if test $ac_qt_version_major -lt 6; then |
| 303 |
AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt5, [no], $ac_path) |
| 304 |
else |
| 305 |
AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt6, [no], $ac_path) |
| 306 |
fi |
| 307 |
if test "x$ac_cv_lupdate" = "xno"; then |
| 308 |
if test $ac_qt_version_major -lt 6; then |
| 309 |
AC_MSG_ERROR([lupdate $ac_errmsg (qt5-linguist)]) |
| 310 |
else |
| 311 |
AC_MSG_ERROR([lupdate $ac_errmsg (qt6-linguist)]) |
| 312 |
fi |
| 313 |
else |
| 314 |
ac_lupdate=$ac_cv_lupdate; |
| 315 |
fi |
| 316 |
fi |
| 317 |
AC_SUBST(ac_lupdate) |
| 318 |
|
| 319 |
# Check for Qt lrelease utility. |
| 320 |
AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path) |
| 321 |
if test "x$ac_lrelease" = "xno"; then |
| 322 |
if test $ac_qt_version_major -lt 6; then |
| 323 |
AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt5, [no], $ac_path) |
| 324 |
else |
| 325 |
AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt6, [no], $ac_path) |
| 326 |
fi |
| 327 |
if test "x$ac_cv_lrelease" = "xno"; then |
| 328 |
if test $ac_qt_version_major -lt 6; then |
| 329 |
AC_MSG_ERROR([lrelease $ac_errmsg (qt5-linguist)]) |
| 330 |
else |
| 331 |
AC_MSG_ERROR([lrelease $ac_errmsg (qt6-linguist)]) |
| 332 |
fi |
| 333 |
else |
| 334 |
ac_lrelease=$ac_cv_lrelease; |
| 335 |
fi |
| 336 |
fi |
| 337 |
AC_SUBST(ac_lrelease) |
| 338 |
|
| 339 |
|
| 340 |
# Checks for libraries. |
| 341 |
AC_CHECK_LIB(m, main) |
| 342 |
AC_CHECK_LIB(X11, main) |
| 343 |
AC_CHECK_LIB(Xext, main) |
| 344 |
|
| 345 |
# Check for round math function. |
| 346 |
AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"]) |
| 347 |
if test "x$ac_round" = "xyes"; then |
| 348 |
AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.]) |
| 349 |
fi |
| 350 |
|
| 351 |
# Check for mandatory libraries. |
| 352 |
PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"]) |
| 353 |
if test "x$ac_liblscp" = "xyes"; then |
| 354 |
AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.]) |
| 355 |
ac_cflags="$ac_cflags $LSCP_CFLAGS" |
| 356 |
ac_libs="$ac_libs $LSCP_LIBS" |
| 357 |
CFLAGS="$CFLAGS $LSCP_CFLAGS" |
| 358 |
CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS" |
| 359 |
LIBS="$LIBS $LSCP_LIBS" |
| 360 |
else |
| 361 |
AC_MSG_ERROR([*** LSCP library not found (liblscp).]) |
| 362 |
fi |
| 363 |
|
| 364 |
case "{$host}" in |
| 365 |
*mingw*) |
| 366 |
ac_libs="$ac_libs -lws2_32" |
| 367 |
LIBS="$LIBS -lws2_32" |
| 368 |
;; |
| 369 |
esac |
| 370 |
|
| 371 |
AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t], |
| 372 |
ac_cv_instrument_name, [ |
| 373 |
AC_TRY_COMPILE([#include "lscp/client.h"], [ |
| 374 |
lscp_channel_info_t info; |
| 375 |
info.instrument_name = 0; |
| 376 |
], ac_cv_instrument_name="yes", ac_cv_instrument_name="no") |
| 377 |
]) |
| 378 |
ac_instrument_name=$ac_cv_instrument_name |
| 379 |
if test "x$ac_instrument_name" = "xyes"; then |
| 380 |
AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.]) |
| 381 |
fi |
| 382 |
|
| 383 |
AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t], |
| 384 |
ac_cv_mute_solo, [ |
| 385 |
AC_TRY_COMPILE([#include "lscp/client.h"], [ |
| 386 |
lscp_channel_info_t info; |
| 387 |
info.mute = 0; |
| 388 |
info.solo = 0; |
| 389 |
], ac_cv_mute_solo="yes", ac_cv_mute_solo="no") |
| 390 |
]) |
| 391 |
ac_mute_solo=$ac_cv_mute_solo |
| 392 |
if test "x$ac_mute_solo" = "xyes"; then |
| 393 |
AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"]) |
| 394 |
fi |
| 395 |
if test "x$ac_mute_solo" = "xyes"; then |
| 396 |
AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"]) |
| 397 |
fi |
| 398 |
if test "x$ac_mute_solo" = "xyes"; then |
| 399 |
AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.]) |
| 400 |
fi |
| 401 |
|
| 402 |
AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"]) |
| 403 |
if test "x$ac_midi_instrument" = "xyes"; then |
| 404 |
AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.]) |
| 405 |
fi |
| 406 |
|
| 407 |
AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"]) |
| 408 |
if test "x$ac_fxsend" = "xyes"; then |
| 409 |
AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.]) |
| 410 |
AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t], |
| 411 |
ac_cv_fxsend_level, [ |
| 412 |
AC_TRY_COMPILE([#include "lscp/client.h"], [ |
| 413 |
lscp_fxsend_info_t info; |
| 414 |
info.level = 0.0f; |
| 415 |
], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no") |
| 416 |
]) |
| 417 |
ac_fxsend_level=$ac_cv_fxsend_level |
| 418 |
if test "x$ac_fxsend_level" = "xyes"; then |
| 419 |
AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.]) |
| 420 |
fi |
| 421 |
AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"]) |
| 422 |
if test "x$ac_fxsend_rename" = "xyes"; then |
| 423 |
AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.]) |
| 424 |
fi |
| 425 |
fi |
| 426 |
|
| 427 |
AC_CACHE_CHECK([for audio_routing array type], |
| 428 |
ac_cv_audio_routing, [ |
| 429 |
AC_TRY_COMPILE([#include "lscp/client.h"], [ |
| 430 |
lscp_channel_info_t info; |
| 431 |
char ch = info.audio_routing[0][0]; |
| 432 |
], ac_cv_audio_routing="no", ac_cv_audio_routing="yes") |
| 433 |
]) |
| 434 |
ac_audio_routing=$ac_cv_audio_routing |
| 435 |
if test "x$ac_audio_routing" = "xyes"; then |
| 436 |
AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.]) |
| 437 |
fi |
| 438 |
|
| 439 |
AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"]) |
| 440 |
if test "x$ac_volume" = "xyes"; then |
| 441 |
AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.]) |
| 442 |
fi |
| 443 |
|
| 444 |
AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"]) |
| 445 |
if test "x$ac_edit_instrument" = "xyes"; then |
| 446 |
AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.]) |
| 447 |
fi |
| 448 |
|
| 449 |
AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp], |
| 450 |
ac_cv_channel_midi_event, [ |
| 451 |
AC_TRY_COMPILE([ |
| 452 |
#include "lscp/client.h" |
| 453 |
#include "lscp/event.h" |
| 454 |
], [ |
| 455 |
lscp_event_t ev; |
| 456 |
ev = LSCP_EVENT_CHANNEL_MIDI; |
| 457 |
], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no") |
| 458 |
]) |
| 459 |
ac_channel_midi_event=$ac_cv_channel_midi_event |
| 460 |
if test "x$ac_channel_midi_event" = "xyes"; then |
| 461 |
AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.]) |
| 462 |
fi |
| 463 |
|
| 464 |
AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp], |
| 465 |
ac_cv_device_midi_event, [ |
| 466 |
AC_TRY_COMPILE([ |
| 467 |
#include "lscp/client.h" |
| 468 |
#include "lscp/event.h" |
| 469 |
], [ |
| 470 |
lscp_event_t ev; |
| 471 |
ev = LSCP_EVENT_DEVICE_MIDI; |
| 472 |
], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no") |
| 473 |
]) |
| 474 |
ac_device_midi_event=$ac_cv_device_midi_event |
| 475 |
if test "x$ac_device_midi_event" = "xyes"; then |
| 476 |
AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.]) |
| 477 |
fi |
| 478 |
|
| 479 |
AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"]) |
| 480 |
if test "x$ac_max_voices" = "xyes"; then |
| 481 |
AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.]) |
| 482 |
fi |
| 483 |
|
| 484 |
AC_CHECK_LIB(lscp, lscp_client_connection_lost, [ac_lscp_conn_lost="yes"], [ac_lscp_conn_lost="no"]) |
| 485 |
if test "x$ac_lscp_conn_lost" = "xyes"; then |
| 486 |
AC_DEFINE(CONFIG_LSCP_CLIENT_CONNECTION_LOST, 1, [Define if liblscp function lscp_client_connection_lost() is available.]) |
| 487 |
fi |
| 488 |
|
| 489 |
# Check for optional libraries. |
| 490 |
if test "x$ac_libgig" = "xyes"; then |
| 491 |
PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"]) |
| 492 |
fi |
| 493 |
if test "x$ac_libgig" = "xyes"; then |
| 494 |
AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.]) |
| 495 |
ac_cflags="$ac_cflags $GIG_CFLAGS" |
| 496 |
ac_libs="$ac_libs $GIG_LIBS" |
| 497 |
CFLAGS="$CFLAGS $GIG_CFLAGS" |
| 498 |
CPPFLAGS="$CPPFLAGS $GIG_CFLAGS" |
| 499 |
LIBS="$LIBS $GIG_LIBS" |
| 500 |
AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.]) |
| 501 |
ac_libgig_setautoload="yes" |
| 502 |
else |
| 503 |
AC_MSG_WARN([*** GIG library not found (libgig).]) |
| 504 |
fi |
| 505 |
|
| 506 |
# Check for round math function. |
| 507 |
AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"]) |
| 508 |
if test "x$ac_round" = "xyes"; then |
| 509 |
AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.]) |
| 510 |
fi |
| 511 |
|
| 512 |
|
| 513 |
# Checks for header files. |
| 514 |
AC_HEADER_STDC |
| 515 |
AC_HEADER_SYS_WAIT |
| 516 |
AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h) |
| 517 |
|
| 518 |
if test "x$ac_libgig" = "xyes"; then |
| 519 |
AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"]) |
| 520 |
if test "x$ac_libgig_sf2" = "xyes"; then |
| 521 |
AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.]) |
| 522 |
fi |
| 523 |
fi |
| 524 |
|
| 525 |
# Check for unique/single instance support. |
| 526 |
if test "x$ac_xunique" = "xyes"; then |
| 527 |
if test $ac_qt_version_major -lt 6; then |
| 528 |
PKG_CHECK_MODULES([QT5NETWORK], [Qt5Network], [ac_xunique="yes"], [ac_xunique="no"]) |
| 529 |
else |
| 530 |
PKG_CHECK_MODULES([QT6NETWORK], [Qt6Network], [ac_xunique="yes"], [ac_xunique="no"]) |
| 531 |
fi |
| 532 |
fi |
| 533 |
if test "x$ac_xunique" = "xyes"; then |
| 534 |
AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if unique/single instance is enabled.]) |
| 535 |
ac_qnetwork="network" |
| 536 |
fi |
| 537 |
AC_SUBST(ac_qnetwork) |
| 538 |
|
| 539 |
# Check for debugging stack-trace. |
| 540 |
if test "x$ac_stacktrace" = "xyes"; then |
| 541 |
AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.]) |
| 542 |
fi |
| 543 |
|
| 544 |
AC_SUBST(ac_cflags) |
| 545 |
AC_SUBST(ac_ldflags) |
| 546 |
AC_SUBST(ac_incpath) |
| 547 |
AC_SUBST(ac_libs) |
| 548 |
|
| 549 |
|
| 550 |
# Checks for typedefs, structures, and compiler characteristics. |
| 551 |
# AC_C_CONST |
| 552 |
|
| 553 |
# Checks for library functions. |
| 554 |
AC_CHECK_FUNCS(system) |
| 555 |
|
| 556 |
# Finally produce a configure header file and the makefiles. |
| 557 |
AC_OUTPUT |
| 558 |
|
| 559 |
# make clean > /dev/null 2>&1 |
| 560 |
|
| 561 |
# Output summary message |
| 562 |
|
| 563 |
echo |
| 564 |
echo " $PACKAGE_NAME $ac_build_version (Qt $ac_qt_version)" |
| 565 |
echo |
| 566 |
echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug" |
| 567 |
echo |
| 568 |
echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name" |
| 569 |
echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo" |
| 570 |
echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument" |
| 571 |
echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend" |
| 572 |
echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level" |
| 573 |
echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename" |
| 574 |
echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing" |
| 575 |
echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume" |
| 576 |
echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument" |
| 577 |
echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig" |
| 578 |
if test "x$ac_libgig" = "xyes"; then |
| 579 |
echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload" |
| 580 |
echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2" |
| 581 |
fi |
| 582 |
echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event" |
| 583 |
echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event" |
| 584 |
echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices" |
| 585 |
echo " LSCP connection loss support . . . . . . . . . . .: $ac_lscp_conn_lost" |
| 586 |
echo |
| 587 |
echo " Unique/Single instance support . . . . . . . . . .: $ac_xunique" |
| 588 |
echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace" |
| 589 |
echo |
| 590 |
echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix" |
| 591 |
echo |
| 592 |
echo "Now type 'make', followed by 'make install' as root." |
| 593 |
echo |
Parent Directory
| 
Revision Log