/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3758 - (show annotations) (download)
Fri Mar 27 17:57:40 2020 UTC (4 years ago) by capela
File size: 18318 byte(s)
- Early fixing to build for Qt >= 5.15.0.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.6.3, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^_]]*[[_v]]//i')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]\+/./g')
15 ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null)
16 if test "x$ac_cv_build_version_extra" != "xmaster"; then
17 ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]"
18 fi
19 else
20 ac_cv_build_version=$PACKAGE_VERSION
21 fi
22 ])
23 ac_build_version="$ac_cv_build_version"
24 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
25
26 # Sanitized version string.
27 AC_CACHE_VAL([ac_cv_version], [
28 ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/')
29 ])
30 ac_version="$ac_cv_version"
31 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
32 AC_SUBST(ac_version)
33
34 # Set default installation prefix.
35 AC_PREFIX_DEFAULT(/usr/local)
36 if test "x$prefix" = "xNONE"; then
37 prefix=$ac_default_prefix
38 fi
39 if test "x$exec_prefix" = "xNONE"; then
40 exec_prefix=$prefix
41 fi
42 eval ac_prefix=$prefix
43 AC_SUBST(ac_prefix)
44 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
45
46 # Set default installation directories.
47 eval ac_bindir=$bindir
48 AC_SUBST(ac_bindir)
49 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
50
51 eval ac_libdir=$libdir
52 AC_SUBST(ac_libdir)
53 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
54
55 eval datarootdir=$datarootdir
56 eval ac_datadir=$datadir
57 AC_SUBST(ac_datadir)
58 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
59
60 eval ac_mandir=$mandir
61 AC_SUBST(ac_mandir)
62 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
63
64
65 # Enable debugging argument option.
66 AC_ARG_ENABLE(debug,
67 AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
68 [ac_debug="$enableval"])
69
70 if test "x$ac_debug" = "xyes"; then
71 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
72 ac_stacktrace="yes"
73 ac_debug="debug"
74 else
75 ac_stacktrace="no"
76 ac_debug="release"
77 fi
78 AC_SUBST(ac_debug)
79
80
81 # Enable libgig availability.
82 AC_ARG_ENABLE(libgig,
83 AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
84 [ac_libgig="$enableval"],
85 [ac_libgig="yes"])
86
87 # Enable unique/single instance.
88 AC_ARG_ENABLE(xunique,
89 AS_HELP_STRING([--enable-xunique], [enable unique/single instance (default=yes)]),
90 [ac_xunique="$enableval"],
91 [ac_xunique="yes"])
92
93 # Enable debugger stack-trace option (assumes --enable-debug).
94 AC_ARG_ENABLE(stacktrace,
95 AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
96 [ac_stacktrace="$enableval"])
97
98
99 # Standard installation base dirs.
100 ac_path=$PATH
101 ac_pkg_config_path=$PKG_CONFIG_PATH
102 ac_with_paths=""
103
104 # Set for alternate Qt installation dir.
105 AC_ARG_WITH(qt,
106 AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]),
107 [ac_qt_path="$withval"], [ac_qt_path="no"])
108
109 if test "x$ac_qt_path" != "xno"; then
110 ac_path="$ac_qt_path/bin:$ac_path"
111 ac_pkg_config_path="$ac_qt_path/lib/pkgconfig:$ac_pkg_config_path"
112 fi
113
114 # Set for alternate liblscp installation dir.
115 AC_ARG_WITH(liblscp,
116 AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
117 [ac_with_paths="$ac_with_paths $withval"])
118
119 # Set for alternate libgig installation dir.
120 AC_ARG_WITH(libgig,
121 AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
122 [ac_with_paths="$ac_with_paths $withval"])
123
124
125 # Honor user specified flags.
126 ac_cflags=$CFLAGS
127 ac_ldflags=$LDFLAGS
128
129
130 # Checks for programs.
131 AC_PROG_CPP
132 AC_PROG_CXX
133 AC_PROG_CXXCPP
134
135 # Checks for languages.
136 AC_LANG_CPLUSPLUS
137
138 # Check for pkg-config.
139 PKG_PROG_PKG_CONFIG
140
141 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
142 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
143 ac_cv_gxx_version_major=$($CC -dumpversion)
144 if test -n "$ac_cv_gxx_version_major"; then
145 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
146 fi
147 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
148 ])
149 ac_gxx_version_major=$ac_cv_gxx_version_major
150 if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then
151 CPPFLAGS="-std=c++11 $CPPFLAGS"
152 ac_cflags="-std=c++11 $ac_cflags"
153 fi
154
155 # Check for proper flags.
156 ac_arch=$(uname -m)
157
158 # Check for install paths and alternatives...
159 ac_libdirs="lib"
160
161 if test "x$ac_arch" = "xx86_64"; then
162 ac_libdirs="$ac_libdirs lib64"
163 fi
164
165 CFLAGS="-fPIC $CFLAGS"
166 CPPFLAGS="-fPIC $CPPFLAGS"
167
168 # Prepend alternate dependencies paths.
169 for X in $ac_with_paths; do
170 if test -d $X/bin; then
171 ac_path="$X/bin:$ac_path"
172 fi
173 if test -d $X/include; then
174 CFLAGS="-I$X/include $CFLAGS "
175 CPPFLAGS="-I$X/include $CPPFLAGS"
176 ac_incpath="$X/include $ac_incpath"
177 fi
178 for Y in $ac_libdirs; do
179 if test -d $X/$Y; then
180 LIBS="-L$X/$Y $LIBS"
181 ac_libs="-L$X/$Y $ac_libs"
182 if test -d $X/$Y/pkgconfig; then
183 ac_pkg_config_path="$X/$Y/pkgconfig:$ac_pkg_config_path"
184 fi
185 fi
186 done
187 done
188
189 # Set pkg-config path.
190 if test -n "$ac_pkg_config_path"; then
191 export PKG_CONFIG_PATH=$ac_pkg_config_path
192 fi
193
194
195 # A common error message:
196 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
197
198 # Check for qtchooser availability.
199 AC_PATH_TOOL(ac_qtchooser, qtchooser, [no], $ac_path)
200 if test -x $ac_qtchooser; then
201 export QT_SELECT=5
202 fi
203
204 # Check for proper qmake path/version alternatives.
205 AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path)
206 if test "x$ac_qmake" = "xno"; then
207 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
208 ac_qmake=$ac_cv_qmake
209 fi
210
211 # Check for proper Qt major version.
212 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
213 ac_cv_qt_version_major=$($ac_qmake -query QT_VERSION | cut -d'.' -f1)
214 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
215 ])
216 ac_qt_version_major=$ac_cv_qt_version_major
217 if test $ac_qt_version_major -ne 5; then
218 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
219 ac_qmake=$ac_cv_qmake
220 fi
221
222 if test "x$ac_qmake" = "xno"; then
223 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
224 fi
225
226 # Check for proper Qt install path.
227 AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [
228 ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS)
229 ])
230 ac_qt_install_path=$ac_cv_qt_install_path
231 if test -d $ac_qt_install_path; then
232 ac_path="$ac_qt_install_path:$ac_path"
233 fi
234
235 # Check it again, now with updated PATH, just in case...
236 AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path)
237 ac_qmake=$ac_cv_qmake
238 if test "x$ac_qmake" = "xno"; then
239 AC_MSG_ERROR([qmake $ac_errmsg])
240 fi
241
242 AC_SUBST(ac_qmake)
243
244 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
245 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
246 ])
247 ac_qt_install_headers=$ac_cv_qt_install_headers
248 if test -d $ac_qt_install_headers; then
249 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
250 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
251 ac_incpath="$ac_qt_install_headers $ac_incpath"
252 fi
253
254 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
255 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
256 ])
257 ac_qt_install_libs=$ac_cv_qt_install_libs
258 if test -d $ac_qt_install_libs; then
259 LIBS="-L$ac_qt_install_libs $LIBS"
260 ac_libs="-L$ac_qt_install_libs $ac_libs"
261 fi
262
263 # Finally, check for proper Qt version.
264 AC_CACHE_CHECK([for Qt library version >= 5.1],
265 ac_cv_qtversion, [
266 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
267 #if QT_VERSION < 0x050100
268 #error Qt library 5.1 or greater required.
269 #endif
270 ], ac_cv_qtversion="yes", [
271 echo "no; Qt 5.1 or greater is required"
272 exit 1
273 ])
274 ])
275
276 # Check for Qt moc utility.
277 AC_PATH_TOOL(ac_moc, moc, [no], $ac_path)
278 if test "x$ac_moc" = "xno"; then
279 AC_MSG_ERROR([moc $ac_errmsg])
280 fi
281 AC_SUBST(ac_moc)
282
283 # Check for Qt uic utility.
284 AC_PATH_TOOL(ac_uic, uic, [no], $ac_path)
285 if test "x$ac_uic" = "xno"; then
286 AC_MSG_ERROR([uic $ac_errmsg])
287 fi
288 AC_SUBST(ac_uic)
289
290
291 # Check for Qt lupdate utility.
292 AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path)
293 if test "x$ac_lupdate" = "xno"; then
294 AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt5, [no], $ac_path)
295 if test "x$ac_cv_lupdate" = "xno"; then
296 AC_MSG_ERROR([lupdate $ac_errmsg (qt5-linguist)])
297 else
298 ac_lupdate=$ac_cv_lupdate;
299 fi
300 fi
301 AC_SUBST(ac_lupdate)
302
303 # Check for Qt lrelease utility.
304 AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path)
305 if test "x$ac_lrelease" = "xno"; then
306 AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt5, [no], $ac_path)
307 if test "x$ac_cv_lrelease" = "xno"; then
308 AC_MSG_ERROR([lrelease $ac_errmsg (qt5-linguist)])
309 else
310 ac_lrelease=$ac_cv_lrelease;
311 fi
312 fi
313 AC_SUBST(ac_lrelease)
314
315
316 # Checks for libraries.
317 AC_CHECK_LIB(m, main)
318 AC_CHECK_LIB(X11, main)
319 AC_CHECK_LIB(Xext, main)
320
321 # Check for round math function.
322 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
323 if test "x$ac_round" = "xyes"; then
324 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
325 fi
326
327 # Check for mandatory libraries.
328 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
329 if test "x$ac_liblscp" = "xyes"; then
330 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
331 ac_cflags="$ac_cflags $LSCP_CFLAGS"
332 ac_libs="$ac_libs $LSCP_LIBS"
333 CFLAGS="$CFLAGS $LSCP_CFLAGS"
334 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
335 LIBS="$LIBS $LSCP_LIBS"
336 else
337 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
338 fi
339
340 case "{$host}" in
341 *mingw*)
342 ac_libs="$ac_libs -lws2_32"
343 LIBS="$LIBS -lws2_32"
344 ;;
345 esac
346
347 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
348 ac_cv_instrument_name, [
349 AC_TRY_COMPILE([#include "lscp/client.h"], [
350 lscp_channel_info_t info;
351 info.instrument_name = 0;
352 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
353 ])
354 ac_instrument_name=$ac_cv_instrument_name
355 if test "x$ac_instrument_name" = "xyes"; then
356 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
357 fi
358
359 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
360 ac_cv_mute_solo, [
361 AC_TRY_COMPILE([#include "lscp/client.h"], [
362 lscp_channel_info_t info;
363 info.mute = 0;
364 info.solo = 0;
365 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
366 ])
367 ac_mute_solo=$ac_cv_mute_solo
368 if test "x$ac_mute_solo" = "xyes"; then
369 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
370 fi
371 if test "x$ac_mute_solo" = "xyes"; then
372 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
373 fi
374 if test "x$ac_mute_solo" = "xyes"; then
375 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
376 fi
377
378 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
379 if test "x$ac_midi_instrument" = "xyes"; then
380 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
381 fi
382
383 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
384 if test "x$ac_fxsend" = "xyes"; then
385 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
386 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
387 ac_cv_fxsend_level, [
388 AC_TRY_COMPILE([#include "lscp/client.h"], [
389 lscp_fxsend_info_t info;
390 info.level = 0.0f;
391 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
392 ])
393 ac_fxsend_level=$ac_cv_fxsend_level
394 if test "x$ac_fxsend_level" = "xyes"; then
395 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
396 fi
397 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
398 if test "x$ac_fxsend_rename" = "xyes"; then
399 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
400 fi
401 fi
402
403 AC_CACHE_CHECK([for audio_routing array type],
404 ac_cv_audio_routing, [
405 AC_TRY_COMPILE([#include "lscp/client.h"], [
406 lscp_channel_info_t info;
407 char ch = info.audio_routing[0][0];
408 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
409 ])
410 ac_audio_routing=$ac_cv_audio_routing
411 if test "x$ac_audio_routing" = "xyes"; then
412 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
413 fi
414
415 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
416 if test "x$ac_volume" = "xyes"; then
417 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
418 fi
419
420 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
421 if test "x$ac_edit_instrument" = "xyes"; then
422 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
423 fi
424
425 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
426 ac_cv_channel_midi_event, [
427 AC_TRY_COMPILE([
428 #include "lscp/client.h"
429 #include "lscp/event.h"
430 ], [
431 lscp_event_t ev;
432 ev = LSCP_EVENT_CHANNEL_MIDI;
433 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
434 ])
435 ac_channel_midi_event=$ac_cv_channel_midi_event
436 if test "x$ac_channel_midi_event" = "xyes"; then
437 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
438 fi
439
440 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
441 ac_cv_device_midi_event, [
442 AC_TRY_COMPILE([
443 #include "lscp/client.h"
444 #include "lscp/event.h"
445 ], [
446 lscp_event_t ev;
447 ev = LSCP_EVENT_DEVICE_MIDI;
448 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
449 ])
450 ac_device_midi_event=$ac_cv_device_midi_event
451 if test "x$ac_device_midi_event" = "xyes"; then
452 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
453 fi
454
455 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
456 if test "x$ac_max_voices" = "xyes"; then
457 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
458 fi
459
460 AC_CHECK_LIB(lscp, lscp_client_connection_lost, [ac_lscp_conn_lost="yes"], [ac_lscp_conn_lost="no"])
461 if test "x$ac_lscp_conn_lost" = "xyes"; then
462 AC_DEFINE(CONFIG_LSCP_CLIENT_CONNECTION_LOST, 1, [Define if liblscp function lscp_client_connection_lost() is available.])
463 fi
464
465 # Check for optional libraries.
466 if test "x$ac_libgig" = "xyes"; then
467 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
468 fi
469 if test "x$ac_libgig" = "xyes"; then
470 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
471 ac_cflags="$ac_cflags $GIG_CFLAGS"
472 ac_libs="$ac_libs $GIG_LIBS"
473 CFLAGS="$CFLAGS $GIG_CFLAGS"
474 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
475 LIBS="$LIBS $GIG_LIBS"
476 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
477 ac_libgig_setautoload="yes"
478 else
479 AC_MSG_WARN([*** GIG library not found (libgig).])
480 fi
481
482 # Check for round math function.
483 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
484 if test "x$ac_round" = "xyes"; then
485 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
486 fi
487
488
489 # Checks for header files.
490 AC_HEADER_STDC
491 AC_HEADER_SYS_WAIT
492 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
493
494 if test "x$ac_libgig" = "xyes"; then
495 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
496 if test "x$ac_libgig_sf2" = "xyes"; then
497 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
498 fi
499 fi
500
501 # Check for unique/single instance support.
502 if test "x$ac_xunique" = "xyes"; then
503 PKG_CHECK_MODULES([QT5NETWORK], [Qt5Network], [ac_qt5network="yes"], [ac_qt5network="no"])
504 if test "x$ac_qt5network" = "xyes"; then
505 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if unique/single instance is enabled.])
506 ac_qnetwork="network"
507 fi
508 fi
509 AC_SUBST(ac_qnetwork)
510
511 # Check for debugging stack-trace.
512 if test "x$ac_stacktrace" = "xyes"; then
513 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
514 fi
515
516 AC_SUBST(ac_cflags)
517 AC_SUBST(ac_ldflags)
518 AC_SUBST(ac_incpath)
519 AC_SUBST(ac_libs)
520
521
522 # Checks for typedefs, structures, and compiler characteristics.
523 # AC_C_CONST
524
525 # Checks for library functions.
526 AC_CHECK_FUNCS(system)
527
528 # Finally produce a configure header file and the makefiles.
529 AC_OUTPUT
530
531 # make clean > /dev/null 2>&1
532
533 # Output summary message
534
535 echo
536 echo " $PACKAGE_NAME $ac_build_version"
537 echo
538 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
539 echo
540 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
541 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
542 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
543 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
544 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
545 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
546 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
547 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
548 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
549 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
550 if test "x$ac_libgig" = "xyes"; then
551 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
552 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
553 fi
554 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
555 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
556 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
557 echo " LSCP connection loss support . . . . . . . . . . .: $ac_lscp_conn_lost"
558 echo
559 echo " Unique/Single instance support . . . . . . . . . .: $ac_xunique"
560 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
561 echo
562 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
563 echo
564 echo "Now type 'make', followed by 'make install' as root."
565 echo

  ViewVC Help
Powered by ViewVC