/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3824 - (show annotations) (download)
Sat Sep 26 18:49:03 2020 UTC (3 years, 6 months ago) by capela
File size: 18462 byte(s)
- Simplified git version string extraction.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.9.0, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^0-9]]\+//')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]\+/./g')
15 ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null)
16 if test "x$ac_cv_build_version_extra" != "xmaster"; then
17 ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]"
18 fi
19 else
20 ac_cv_build_version=$PACKAGE_VERSION
21 fi
22 ])
23 ac_build_version="$ac_cv_build_version"
24 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
25
26 # Sanitized version string.
27 AC_CACHE_VAL([ac_cv_version], [
28 ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/')
29 ])
30 ac_version="$ac_cv_version"
31 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
32 AC_SUBST(ac_version)
33
34 # Set default installation prefix.
35 AC_PREFIX_DEFAULT(/usr/local)
36 if test "x$prefix" = "xNONE"; then
37 prefix=$ac_default_prefix
38 fi
39 if test "x$exec_prefix" = "xNONE"; then
40 exec_prefix=$prefix
41 fi
42 eval ac_prefix=$prefix
43 AC_SUBST(ac_prefix)
44 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
45
46 # Set default installation directories.
47 eval ac_bindir=$bindir
48 AC_SUBST(ac_bindir)
49 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
50
51 eval ac_libdir=$libdir
52 AC_SUBST(ac_libdir)
53 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
54
55 eval datarootdir=$datarootdir
56 eval ac_datadir=$datadir
57 AC_SUBST(ac_datadir)
58 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
59
60 eval ac_mandir=$mandir
61 AC_SUBST(ac_mandir)
62 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
63
64
65 # Enable debugging argument option.
66 AC_ARG_ENABLE(debug,
67 AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
68 [ac_debug="$enableval"])
69
70 if test "x$ac_debug" = "xyes"; then
71 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
72 ac_stacktrace="yes"
73 ac_debug="debug"
74 else
75 ac_stacktrace="no"
76 ac_debug="release"
77 fi
78 AC_SUBST(ac_debug)
79
80
81 # Enable libgig availability.
82 AC_ARG_ENABLE(libgig,
83 AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
84 [ac_libgig="$enableval"],
85 [ac_libgig="yes"])
86
87 # Enable unique/single instance.
88 AC_ARG_ENABLE(xunique,
89 AS_HELP_STRING([--enable-xunique], [enable unique/single instance (default=yes)]),
90 [ac_xunique="$enableval"],
91 [ac_xunique="yes"])
92
93 # Enable debugger stack-trace option (assumes --enable-debug).
94 AC_ARG_ENABLE(stacktrace,
95 AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
96 [ac_stacktrace="$enableval"])
97
98
99 # Standard installation base dirs.
100 ac_path=$PATH
101 ac_pkg_config_path=$PKG_CONFIG_PATH
102 ac_with_paths=""
103
104 # Set for alternate Qt installation dir.
105 AC_ARG_WITH(qt,
106 AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]),
107 [ac_qt_path="$withval"], [ac_qt_path="no"])
108
109 if test "x$ac_qt_path" != "xno"; then
110 ac_path="$ac_qt_path/bin:$ac_path"
111 ac_pkg_config_path="$ac_qt_path/lib/pkgconfig:$ac_pkg_config_path"
112 fi
113
114 # Set for alternate liblscp installation dir.
115 AC_ARG_WITH(liblscp,
116 AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
117 [ac_with_paths="$ac_with_paths $withval"])
118
119 # Set for alternate libgig installation dir.
120 AC_ARG_WITH(libgig,
121 AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
122 [ac_with_paths="$ac_with_paths $withval"])
123
124
125 # Honor user specified flags.
126 ac_cflags=$CFLAGS
127 ac_ldflags=$LDFLAGS
128
129
130 # Checks for programs.
131 AC_PROG_CPP
132 AC_PROG_CXX
133 AC_PROG_CXXCPP
134
135 # Checks for languages.
136 AC_LANG_CPLUSPLUS
137
138 # Check for pkg-config.
139 PKG_PROG_PKG_CONFIG
140
141 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
142 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
143 ac_cv_gxx_version_major=$($CC -dumpversion)
144 if test -n "$ac_cv_gxx_version_major"; then
145 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
146 fi
147 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
148 ])
149 ac_gxx_version_major=$ac_cv_gxx_version_major
150 if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then
151 CXXFLAGS="-std=c++11 $CXXFLAGS"
152 ac_cflags="-std=c++11 $ac_cflags"
153 elif test $ac_gxx_version_major -ge 6 -a $ac_gxx_version_major -lt 11; then
154 CXXFLAGS="-std=c++17 $CXXFLAGS"
155 ac_cflags="-std=c++17 $ac_cflags"
156 fi
157
158 # Check for proper flags.
159 ac_arch=$(uname -m)
160
161 # Check for install paths and alternatives...
162 ac_libdirs="lib"
163
164 if test "x$ac_arch" = "xx86_64"; then
165 ac_libdirs="$ac_libdirs lib64"
166 fi
167
168 CFLAGS="-fPIC $CFLAGS"
169 CPPFLAGS="-fPIC $CPPFLAGS"
170
171 # Prepend alternate dependencies paths.
172 for X in $ac_with_paths; do
173 if test -d $X/bin; then
174 ac_path="$X/bin:$ac_path"
175 fi
176 if test -d $X/include; then
177 CFLAGS="-I$X/include $CFLAGS "
178 CPPFLAGS="-I$X/include $CPPFLAGS"
179 ac_incpath="$X/include $ac_incpath"
180 fi
181 for Y in $ac_libdirs; do
182 if test -d $X/$Y; then
183 LIBS="-L$X/$Y $LIBS"
184 ac_libs="-L$X/$Y $ac_libs"
185 if test -d $X/$Y/pkgconfig; then
186 ac_pkg_config_path="$X/$Y/pkgconfig:$ac_pkg_config_path"
187 fi
188 fi
189 done
190 done
191
192 # Set pkg-config path.
193 if test -n "$ac_pkg_config_path"; then
194 export PKG_CONFIG_PATH=$ac_pkg_config_path
195 fi
196
197
198 # A common error message:
199 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
200
201 # Check for qtchooser availability.
202 AC_PATH_TOOL(ac_qtchooser, qtchooser, [no], $ac_path)
203 if test -x $ac_qtchooser; then
204 export QT_SELECT=5
205 fi
206
207 # Check for proper qmake path/version alternatives.
208 AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path)
209 if test "x$ac_qmake" = "xno"; then
210 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
211 ac_qmake=$ac_cv_qmake
212 fi
213
214 # Check for proper Qt major version.
215 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
216 ac_cv_qt_version_major=$($ac_qmake -query QT_VERSION | cut -d'.' -f1)
217 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
218 ])
219 ac_qt_version_major=$ac_cv_qt_version_major
220 if test $ac_qt_version_major -lt 5; then
221 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
222 ac_qmake=$ac_cv_qmake
223 fi
224
225 if test "x$ac_qmake" = "xno"; then
226 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
227 fi
228
229 # Check for proper Qt install path.
230 AC_CACHE_CHECK([for Qt install path], [ac_cv_qt_install_path], [
231 ac_cv_qt_install_path=$($ac_qmake -query QT_INSTALL_BINS)
232 ])
233 ac_qt_install_path=$ac_cv_qt_install_path
234 if test -d $ac_qt_install_path; then
235 ac_path="$ac_qt_install_path:$ac_path"
236 fi
237
238 # Check it again, now with updated PATH, just in case...
239 AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path)
240 ac_qmake=$ac_cv_qmake
241 if test "x$ac_qmake" = "xno"; then
242 AC_MSG_ERROR([qmake $ac_errmsg])
243 fi
244
245 AC_SUBST(ac_qmake)
246
247 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
248 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
249 ])
250 ac_qt_install_headers=$ac_cv_qt_install_headers
251 if test -d $ac_qt_install_headers; then
252 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
253 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
254 ac_incpath="$ac_qt_install_headers $ac_incpath"
255 fi
256
257 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
258 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
259 ])
260 ac_qt_install_libs=$ac_cv_qt_install_libs
261 if test -d $ac_qt_install_libs; then
262 LIBS="-L$ac_qt_install_libs $LIBS"
263 ac_libs="-L$ac_qt_install_libs $ac_libs"
264 fi
265
266 # Finally, check for proper Qt version.
267 AC_CACHE_CHECK([for Qt library version >= 5.1],
268 ac_cv_qtversion, [
269 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
270 #if QT_VERSION < 0x050100
271 #error Qt library 5.1 or greater required.
272 #endif
273 ], ac_cv_qtversion="yes", [
274 echo "no; Qt 5.1 or greater is required"
275 exit 1
276 ])
277 ])
278
279 # Check for Qt moc utility.
280 AC_PATH_TOOL(ac_moc, moc, [no], $ac_path)
281 if test "x$ac_moc" = "xno"; then
282 AC_MSG_ERROR([moc $ac_errmsg])
283 fi
284 AC_SUBST(ac_moc)
285
286 # Check for Qt uic utility.
287 AC_PATH_TOOL(ac_uic, uic, [no], $ac_path)
288 if test "x$ac_uic" = "xno"; then
289 AC_MSG_ERROR([uic $ac_errmsg])
290 fi
291 AC_SUBST(ac_uic)
292
293
294 # Check for Qt lupdate utility.
295 AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path)
296 if test "x$ac_lupdate" = "xno"; then
297 AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt5, [no], $ac_path)
298 if test "x$ac_cv_lupdate" = "xno"; then
299 AC_MSG_ERROR([lupdate $ac_errmsg (qt5-linguist)])
300 else
301 ac_lupdate=$ac_cv_lupdate;
302 fi
303 fi
304 AC_SUBST(ac_lupdate)
305
306 # Check for Qt lrelease utility.
307 AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path)
308 if test "x$ac_lrelease" = "xno"; then
309 AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt5, [no], $ac_path)
310 if test "x$ac_cv_lrelease" = "xno"; then
311 AC_MSG_ERROR([lrelease $ac_errmsg (qt5-linguist)])
312 else
313 ac_lrelease=$ac_cv_lrelease;
314 fi
315 fi
316 AC_SUBST(ac_lrelease)
317
318
319 # Checks for libraries.
320 AC_CHECK_LIB(m, main)
321 AC_CHECK_LIB(X11, main)
322 AC_CHECK_LIB(Xext, main)
323
324 # Check for round math function.
325 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
326 if test "x$ac_round" = "xyes"; then
327 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
328 fi
329
330 # Check for mandatory libraries.
331 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
332 if test "x$ac_liblscp" = "xyes"; then
333 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
334 ac_cflags="$ac_cflags $LSCP_CFLAGS"
335 ac_libs="$ac_libs $LSCP_LIBS"
336 CFLAGS="$CFLAGS $LSCP_CFLAGS"
337 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
338 LIBS="$LIBS $LSCP_LIBS"
339 else
340 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
341 fi
342
343 case "{$host}" in
344 *mingw*)
345 ac_libs="$ac_libs -lws2_32"
346 LIBS="$LIBS -lws2_32"
347 ;;
348 esac
349
350 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
351 ac_cv_instrument_name, [
352 AC_TRY_COMPILE([#include "lscp/client.h"], [
353 lscp_channel_info_t info;
354 info.instrument_name = 0;
355 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
356 ])
357 ac_instrument_name=$ac_cv_instrument_name
358 if test "x$ac_instrument_name" = "xyes"; then
359 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
360 fi
361
362 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
363 ac_cv_mute_solo, [
364 AC_TRY_COMPILE([#include "lscp/client.h"], [
365 lscp_channel_info_t info;
366 info.mute = 0;
367 info.solo = 0;
368 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
369 ])
370 ac_mute_solo=$ac_cv_mute_solo
371 if test "x$ac_mute_solo" = "xyes"; then
372 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
373 fi
374 if test "x$ac_mute_solo" = "xyes"; then
375 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
376 fi
377 if test "x$ac_mute_solo" = "xyes"; then
378 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
379 fi
380
381 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
382 if test "x$ac_midi_instrument" = "xyes"; then
383 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
384 fi
385
386 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
387 if test "x$ac_fxsend" = "xyes"; then
388 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
389 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
390 ac_cv_fxsend_level, [
391 AC_TRY_COMPILE([#include "lscp/client.h"], [
392 lscp_fxsend_info_t info;
393 info.level = 0.0f;
394 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
395 ])
396 ac_fxsend_level=$ac_cv_fxsend_level
397 if test "x$ac_fxsend_level" = "xyes"; then
398 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
399 fi
400 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
401 if test "x$ac_fxsend_rename" = "xyes"; then
402 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
403 fi
404 fi
405
406 AC_CACHE_CHECK([for audio_routing array type],
407 ac_cv_audio_routing, [
408 AC_TRY_COMPILE([#include "lscp/client.h"], [
409 lscp_channel_info_t info;
410 char ch = info.audio_routing[0][0];
411 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
412 ])
413 ac_audio_routing=$ac_cv_audio_routing
414 if test "x$ac_audio_routing" = "xyes"; then
415 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
416 fi
417
418 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
419 if test "x$ac_volume" = "xyes"; then
420 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
421 fi
422
423 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
424 if test "x$ac_edit_instrument" = "xyes"; then
425 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
426 fi
427
428 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
429 ac_cv_channel_midi_event, [
430 AC_TRY_COMPILE([
431 #include "lscp/client.h"
432 #include "lscp/event.h"
433 ], [
434 lscp_event_t ev;
435 ev = LSCP_EVENT_CHANNEL_MIDI;
436 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
437 ])
438 ac_channel_midi_event=$ac_cv_channel_midi_event
439 if test "x$ac_channel_midi_event" = "xyes"; then
440 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
441 fi
442
443 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
444 ac_cv_device_midi_event, [
445 AC_TRY_COMPILE([
446 #include "lscp/client.h"
447 #include "lscp/event.h"
448 ], [
449 lscp_event_t ev;
450 ev = LSCP_EVENT_DEVICE_MIDI;
451 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
452 ])
453 ac_device_midi_event=$ac_cv_device_midi_event
454 if test "x$ac_device_midi_event" = "xyes"; then
455 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
456 fi
457
458 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
459 if test "x$ac_max_voices" = "xyes"; then
460 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
461 fi
462
463 AC_CHECK_LIB(lscp, lscp_client_connection_lost, [ac_lscp_conn_lost="yes"], [ac_lscp_conn_lost="no"])
464 if test "x$ac_lscp_conn_lost" = "xyes"; then
465 AC_DEFINE(CONFIG_LSCP_CLIENT_CONNECTION_LOST, 1, [Define if liblscp function lscp_client_connection_lost() is available.])
466 fi
467
468 # Check for optional libraries.
469 if test "x$ac_libgig" = "xyes"; then
470 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
471 fi
472 if test "x$ac_libgig" = "xyes"; then
473 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
474 ac_cflags="$ac_cflags $GIG_CFLAGS"
475 ac_libs="$ac_libs $GIG_LIBS"
476 CFLAGS="$CFLAGS $GIG_CFLAGS"
477 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
478 LIBS="$LIBS $GIG_LIBS"
479 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
480 ac_libgig_setautoload="yes"
481 else
482 AC_MSG_WARN([*** GIG library not found (libgig).])
483 fi
484
485 # Check for round math function.
486 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
487 if test "x$ac_round" = "xyes"; then
488 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
489 fi
490
491
492 # Checks for header files.
493 AC_HEADER_STDC
494 AC_HEADER_SYS_WAIT
495 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
496
497 if test "x$ac_libgig" = "xyes"; then
498 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
499 if test "x$ac_libgig_sf2" = "xyes"; then
500 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
501 fi
502 fi
503
504 # Check for unique/single instance support.
505 if test "x$ac_xunique" = "xyes"; then
506 PKG_CHECK_MODULES([QT5NETWORK], [Qt5Network], [ac_qt5network="yes"], [ac_qt5network="no"])
507 if test "x$ac_qt5network" = "xyes"; then
508 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if unique/single instance is enabled.])
509 ac_qnetwork="network"
510 fi
511 fi
512 AC_SUBST(ac_qnetwork)
513
514 # Check for debugging stack-trace.
515 if test "x$ac_stacktrace" = "xyes"; then
516 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
517 fi
518
519 AC_SUBST(ac_cflags)
520 AC_SUBST(ac_ldflags)
521 AC_SUBST(ac_incpath)
522 AC_SUBST(ac_libs)
523
524
525 # Checks for typedefs, structures, and compiler characteristics.
526 # AC_C_CONST
527
528 # Checks for library functions.
529 AC_CHECK_FUNCS(system)
530
531 # Finally produce a configure header file and the makefiles.
532 AC_OUTPUT
533
534 # make clean > /dev/null 2>&1
535
536 # Output summary message
537
538 echo
539 echo " $PACKAGE_NAME $ac_build_version"
540 echo
541 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_debug"
542 echo
543 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
544 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
545 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
546 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
547 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
548 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
549 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
550 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
551 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
552 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
553 if test "x$ac_libgig" = "xyes"; then
554 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
555 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
556 fi
557 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
558 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
559 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
560 echo " LSCP connection loss support . . . . . . . . . . .: $ac_lscp_conn_lost"
561 echo
562 echo " Unique/Single instance support . . . . . . . . . .: $ac_xunique"
563 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
564 echo
565 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
566 echo
567 echo "Now type 'make', followed by 'make install' as root."
568 echo

  ViewVC Help
Powered by ViewVC