/[svn]/qsampler/trunk/configure.ac
ViewVC logotype

Contents of /qsampler/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3997 - (show annotations) (download)
Mon Sep 27 09:45:24 2021 UTC (2 months, 1 week ago) by capela
File size: 20232 byte(s)
- Bumped dot version into the next develop cycle.
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(Qsampler, 0.9.5, rncbc@rncbc.org, qsampler)
3
4 AC_CONFIG_SRCDIR(src/qsampler.cpp)
5 AC_CONFIG_HEADERS(src/config.h)
6 AC_CONFIG_FILES(Makefile qsampler.spec src/src.pri)
7
8 # Build version string.
9 AC_CACHE_VAL([ac_cv_build_version], [
10 ac_cv_build_version=$(git describe --tags --dirty --abbrev=6 2>/dev/null)
11 if test -n "$ac_cv_build_version"; then
12 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[^0-9]]\+//')
13 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^1_//')
14 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/^[[_vV]]\+//')
15 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/-g/git./')
16 ac_cv_build_version=$(echo $ac_cv_build_version | sed 's/[[_|-]]/./g')
17 ac_cv_build_version_extra=$(git rev-parse --abbrev-ref HEAD 2>/dev/null)
18 if test "x$ac_cv_build_version_extra" != "xmaster"; then
19 ac_cv_build_version="$ac_cv_build_version [[$ac_cv_build_version_extra]]"
20 fi
21 else
22 ac_cv_build_version=$PACKAGE_VERSION
23 fi
24 ])
25 ac_build_version="$ac_cv_build_version"
26 AC_DEFINE_UNQUOTED(CONFIG_BUILD_VERSION, ["$ac_build_version"], [Build version string.])
27
28 # Sanitized version string.
29 AC_CACHE_VAL([ac_cv_version], [
30 ac_cv_version=$(echo $PACKAGE_VERSION | sed -r 's/^([[0-9|\.]]+).*$/\1/')
31 ])
32 ac_version="$ac_cv_version"
33 AC_DEFINE_UNQUOTED(CONFIG_VERSION, ["$ac_version"], [Version string.])
34 AC_SUBST(ac_version)
35
36 # Set default installation prefix.
37 AC_PREFIX_DEFAULT(/usr/local)
38 if test "x$prefix" = "xNONE"; then
39 prefix=$ac_default_prefix
40 fi
41 if test "x$exec_prefix" = "xNONE"; then
42 exec_prefix=$prefix
43 fi
44 eval ac_prefix=$prefix
45 AC_SUBST(ac_prefix)
46 AC_DEFINE_UNQUOTED(CONFIG_PREFIX, ["$ac_prefix"], [Default installation prefix.])
47
48 # Set default installation directories.
49 eval ac_bindir=$bindir
50 AC_SUBST(ac_bindir)
51 AC_DEFINE_UNQUOTED(CONFIG_BINDIR, ["$ac_bindir"], [Default executable binary path.])
52
53 eval ac_libdir=$libdir
54 AC_SUBST(ac_libdir)
55 AC_DEFINE_UNQUOTED(CONFIG_LIBDIR, ["$ac_libdir"], [Default object library path.])
56
57 eval datarootdir=$datarootdir
58 eval ac_datadir=$datadir
59 AC_SUBST(ac_datadir)
60 AC_DEFINE_UNQUOTED(CONFIG_DATADIR, ["$ac_datadir"], [Default arch-idependent data path.])
61
62 eval ac_mandir=$mandir
63 AC_SUBST(ac_mandir)
64 AC_DEFINE_UNQUOTED(CONFIG_MANDIR, ["$ac_mandir"], [Default man page path.])
65
66
67 # Enable debugging argument option.
68 AC_ARG_ENABLE(debug,
69 AS_HELP_STRING([--enable-debug], [enable debugging (default=no)]),
70 [ac_debug="$enableval"])
71
72 # Enable Qt6 build preference.
73 AC_ARG_ENABLE(qt6,
74 AS_HELP_STRING([--enable-qt6], [enable Qt6 build (default=yes)]),
75 [ac_qt6="$enableval"],
76 [ac_qt6="yes"])
77
78
79 if test "x$ac_debug" = "xyes"; then
80 AC_DEFINE(CONFIG_DEBUG, 1, [Define if debugging is enabled.])
81 ac_stacktrace="yes"
82 ac_build_type="debug"
83 else
84 ac_stacktrace="no"
85 ac_build_type="release"
86 fi
87 AC_SUBST(ac_build_type)
88
89
90 # Enable libgig availability.
91 AC_ARG_ENABLE(libgig,
92 AS_HELP_STRING([--enable-libgig], [enable libgig interface (default=yes)]),
93 [ac_libgig="$enableval"],
94 [ac_libgig="yes"])
95
96 # Enable unique/single instance.
97 AC_ARG_ENABLE(xunique,
98 AS_HELP_STRING([--enable-xunique], [enable unique/single instance (default=yes)]),
99 [ac_xunique="$enableval"],
100 [ac_xunique="yes"])
101
102 # Enable debugger stack-trace option (assumes --enable-debug).
103 AC_ARG_ENABLE(stacktrace,
104 AS_HELP_STRING([--enable-stacktrace], [enable debugger stack-trace (default=no)]),
105 [ac_stacktrace="$enableval"])
106
107
108 # Standard installation base dirs.
109 ac_path=$PATH
110 ac_pkg_config_path=$PKG_CONFIG_PATH
111 ac_with_paths=""
112
113 # Set for alternate Qt installation dir.
114 AC_ARG_WITH(qt,
115 AS_HELP_STRING([--with-qt=PATH], [use alternate Qt install path]),
116 [ac_qt_path="$withval"], [ac_qt_path="no"])
117
118 if test "x$ac_qt_path" != "xno"; then
119 ac_path="$ac_qt_path/bin:$ac_path"
120 ac_pkg_config_path="$ac_qt_path/lib/pkgconfig:$ac_pkg_config_path"
121 fi
122
123 # Set for alternate liblscp installation dir.
124 AC_ARG_WITH(liblscp,
125 AS_HELP_STRING([--with-liblscp=PATH], [use alternate liblscp install path]),
126 [ac_with_paths="$ac_with_paths $withval"])
127
128 # Set for alternate libgig installation dir.
129 AC_ARG_WITH(libgig,
130 AS_HELP_STRING([--with-libgig=PATH], [use alternate libgig install path]),
131 [ac_with_paths="$ac_with_paths $withval"])
132
133
134 # Honor user specified flags.
135 ac_cflags=$CFLAGS
136 ac_ldflags=$LDFLAGS
137
138
139 # Checks for programs.
140 AC_PROG_CPP
141 AC_PROG_CXX
142 AC_PROG_CXXCPP
143
144 # Checks for languages.
145 AC_LANG_CPLUSPLUS
146
147 # Check for pkg-config.
148 PKG_PROG_PKG_CONFIG
149
150 # Check whether -std=c++11 support is necessary (4 < g++ version < 6).
151 AC_CACHE_CHECK([for g++ major version], [ac_cv_gxx_version_major], [
152 ac_cv_gxx_version_major=$($CC -dumpversion)
153 if test -n "$ac_cv_gxx_version_major"; then
154 ac_cv_gxx_version_major=$(echo $ac_cv_gxx_version_major | cut -d'.' -f1);
155 fi
156 ac_gxx_version_major=$(($ac_cv_gxx_version_major + 0))
157 ])
158 ac_gxx_version_major=$ac_cv_gxx_version_major
159 if test $ac_gxx_version_major -ge 4 -a $ac_gxx_version_major -lt 6; then
160 CXXFLAGS="-std=c++11 $CXXFLAGS"
161 ac_cflags="-std=c++11 $ac_cflags"
162 elif test $ac_gxx_version_major -ge 6 -a $ac_gxx_version_major -lt 11; then
163 CXXFLAGS="-std=c++17 $CXXFLAGS"
164 ac_cflags="-std=c++17 $ac_cflags"
165 fi
166
167 # Check for proper flags.
168 ac_arch=$(uname -m)
169
170 # Check for install paths and alternatives...
171 ac_libdirs="lib"
172
173 if test "x$ac_arch" = "xx86_64"; then
174 ac_libdirs="$ac_libdirs lib64"
175 fi
176
177 CFLAGS="-fPIC $CFLAGS"
178 CPPFLAGS="-fPIC $CPPFLAGS"
179
180 # Prepend alternate dependencies paths.
181 for X in $ac_with_paths; do
182 if test -d $X/bin; then
183 ac_path="$X/bin:$ac_path"
184 fi
185 if test -d $X/include; then
186 CFLAGS="-I$X/include $CFLAGS "
187 CPPFLAGS="-I$X/include $CPPFLAGS"
188 ac_incpath="$X/include $ac_incpath"
189 fi
190 for Y in $ac_libdirs; do
191 if test -d $X/$Y; then
192 LIBS="-L$X/$Y $LIBS"
193 ac_libs="-L$X/$Y $ac_libs"
194 if test -d $X/$Y/pkgconfig; then
195 ac_pkg_config_path="$X/$Y/pkgconfig:$ac_pkg_config_path"
196 fi
197 fi
198 done
199 done
200
201 # Set pkg-config path.
202 if test -n "$ac_pkg_config_path"; then
203 export PKG_CONFIG_PATH=$ac_pkg_config_path
204 fi
205
206
207 # A common error message:
208 ac_errmsg="not found in current PATH. Maybe QT development environment isn't available."
209
210 # Check for qtchooser availability.
211 AC_PATH_TOOL(ac_qtchooser, qtchooser, [no], $ac_path)
212 if test -x $ac_qtchooser; then
213 if test "x$ac_qt6" = "xyes"; then
214 export QT_SELECT=6
215 else
216 export QT_SELECT=5
217 fi
218 fi
219
220 # Check for proper qmake path/version alternatives.
221 AC_PATH_TOOL(ac_qmake, qmake, [no], $ac_path)
222 if test "x$ac_qmake" = "xno"; then
223 if test "x$ac_qt6" = "xyes"; then
224 AC_PATH_TOOL(ac_cv_qmake, qmake-qt6, [no], $ac_path)
225 ac_qmake=$ac_cv_qmake
226 else
227 AC_PATH_TOOL(ac_cv_qmake, qmake-qt5, [no], $ac_path)
228 ac_qmake=$ac_cv_qmake
229 fi
230 fi
231
232 # Check for proper Qt major version.
233 AC_CACHE_CHECK([for Qt major version], [ac_cv_qt_version_major], [
234 ac_cv_qt_version=$($ac_qmake -query QT_VERSION)
235 ac_cv_qt_version_major=$(echo $ac_cv_qt_version | cut -d'.' -f1)
236 ac_cv_qt_version_major=$(($ac_cv_qt_version_major + 0))
237 ])
238 ac_qt_version=$ac_cv_qt_version
239 ac_qt_version_major=$ac_cv_qt_version_major
240 if test "x$ac_qmake" = "xno"; then
241 if test $ac_qt_version_major -lt 6; then
242 AC_MSG_ERROR([qmake-qt5 $ac_errmsg (qt5-devel)])
243 else
244 AC_MSG_ERROR([qmake-qt6 $ac_errmsg (qt6-devel)])
245 fi
246 fi
247
248 # Check for proper Qt install path.
249 AC_CACHE_CHECK([for Qt install path (bin)], [ac_cv_qt_install_bins], [
250 ac_cv_qt_install_bins=$($ac_qmake -query QT_INSTALL_BINS)
251 ])
252 ac_qt_install_bins=$ac_cv_qt_install_bins
253 if test -d $ac_qt_install_bins; then
254 ac_path="$ac_qt_install_bins:$ac_path"
255 fi
256
257 AC_CACHE_CHECK([for Qt install path (libexec)], [ac_cv_qt_install_libexecs], [
258 ac_cv_qt_install_libexecs=$($ac_qmake -query QT_INSTALL_LIBEXECS)
259 ])
260 ac_qt_install_libexecs=$ac_cv_qt_install_libexecs
261 if test -d $ac_qt_install_libexecs; then
262 ac_path="$ac_qt_install_libexecs:$ac_path"
263 fi
264
265 # Check it again, now with updated PATH, just in case...
266 AC_PATH_TOOL(ac_cv_qmake, qmake, [no], $ac_path)
267 ac_qmake=$ac_cv_qmake
268 if test "x$ac_qmake" = "xno"; then
269 AC_MSG_ERROR([qmake $ac_errmsg])
270 fi
271
272 AC_SUBST(ac_qmake)
273
274 AC_CACHE_CHECK([for Qt install headers], [ac_cv_qt_install_headers], [
275 ac_cv_qt_install_headers=$($ac_qmake -query QT_INSTALL_HEADERS)
276 ])
277 ac_qt_install_headers=$ac_cv_qt_install_headers
278 if test -d $ac_qt_install_headers; then
279 CFLAGS="-I$ac_qt_install_headers $CFLAGS "
280 CPPFLAGS="-I$ac_qt_install_headers $CPPFLAGS"
281 ac_incpath="$ac_qt_install_headers $ac_incpath"
282 fi
283
284 AC_CACHE_CHECK([for Qt install libraries], [ac_cv_qt_install_libs], [
285 ac_cv_qt_install_libs=$($ac_qmake -query QT_INSTALL_LIBS)
286 ])
287 ac_qt_install_libs=$ac_cv_qt_install_libs
288 if test -d $ac_qt_install_libs; then
289 LIBS="-L$ac_qt_install_libs $LIBS"
290 ac_libs="-L$ac_qt_install_libs $ac_libs"
291 fi
292
293 # Finally, check for proper Qt version.
294 AC_CACHE_CHECK([for Qt library version >= 5.1],
295 ac_cv_qtversion, [
296 AC_TRY_COMPILE([#include "QtCore/qglobal.h"], [
297 #if QT_VERSION < 0x050100
298 #error Qt library 5.1 or greater required.
299 #endif
300 ], ac_cv_qtversion="yes", [
301 echo "no; Qt 5.1 or greater is required"
302 exit 1
303 ])
304 ])
305
306 # Check for Qt moc utility.
307 AC_PATH_TOOL(ac_moc, moc, [no], $ac_path)
308 if test "x$ac_moc" = "xno"; then
309 AC_MSG_ERROR([moc $ac_errmsg])
310 fi
311 AC_SUBST(ac_moc)
312
313 # Check for Qt uic utility.
314 AC_PATH_TOOL(ac_uic, uic, [no], $ac_path)
315 if test "x$ac_uic" = "xno"; then
316 AC_MSG_ERROR([uic $ac_errmsg])
317 fi
318 AC_SUBST(ac_uic)
319
320
321 # Check for Qt lupdate utility.
322 AC_PATH_TOOL(ac_lupdate, lupdate, [no], $ac_path)
323 if test "x$ac_lupdate" = "xno"; then
324 if test $ac_qt_version_major -lt 6; then
325 AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt5, [no], $ac_path)
326 else
327 AC_PATH_TOOL(ac_cv_lupdate, lupdate-qt6, [no], $ac_path)
328 fi
329 if test "x$ac_cv_lupdate" = "xno"; then
330 if test $ac_qt_version_major -lt 6; then
331 AC_MSG_ERROR([lupdate $ac_errmsg (qt5-linguist)])
332 else
333 AC_MSG_ERROR([lupdate $ac_errmsg (qt6-linguist)])
334 fi
335 else
336 ac_lupdate=$ac_cv_lupdate;
337 fi
338 fi
339 AC_SUBST(ac_lupdate)
340
341 # Check for Qt lrelease utility.
342 AC_PATH_TOOL(ac_lrelease, lrelease, [no], $ac_path)
343 if test "x$ac_lrelease" = "xno"; then
344 if test $ac_qt_version_major -lt 6; then
345 AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt5, [no], $ac_path)
346 else
347 AC_PATH_TOOL(ac_cv_lrelease, lrelease-qt6, [no], $ac_path)
348 fi
349 if test "x$ac_cv_lrelease" = "xno"; then
350 if test $ac_qt_version_major -lt 6; then
351 AC_MSG_ERROR([lrelease $ac_errmsg (qt5-linguist)])
352 else
353 AC_MSG_ERROR([lrelease $ac_errmsg (qt6-linguist)])
354 fi
355 else
356 ac_lrelease=$ac_cv_lrelease;
357 fi
358 fi
359 AC_SUBST(ac_lrelease)
360
361
362 # Checks for libraries.
363 AC_CHECK_LIB(m, main)
364 AC_CHECK_LIB(X11, main)
365 AC_CHECK_LIB(Xext, main)
366
367 # Check for round math function.
368 AC_CHECK_LIB(m, round, [ac_round="yes"], [ac_round="no"])
369 if test "x$ac_round" = "xyes"; then
370 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
371 fi
372
373 # Check for mandatory libraries.
374 PKG_CHECK_MODULES([LSCP], [lscp], [ac_liblscp="yes"], [ac_liblscp="no"])
375 if test "x$ac_liblscp" = "xyes"; then
376 AC_DEFINE(CONFIG_LIBLSCP, 1, [Define if liblscp is available.])
377 ac_cflags="$ac_cflags $LSCP_CFLAGS"
378 ac_libs="$ac_libs $LSCP_LIBS"
379 CFLAGS="$CFLAGS $LSCP_CFLAGS"
380 CPPFLAGS="$CPPFLAGS $LSCP_CFLAGS"
381 LIBS="$LIBS $LSCP_LIBS"
382 else
383 AC_MSG_ERROR([*** LSCP library not found (liblscp).])
384 fi
385
386 case "{$host}" in
387 *mingw*)
388 ac_libs="$ac_libs -lws2_32"
389 LIBS="$LIBS -lws2_32"
390 ;;
391 esac
392
393 AC_CACHE_CHECK([for instrument_name in lscp_channel_info_t],
394 ac_cv_instrument_name, [
395 AC_TRY_COMPILE([#include "lscp/client.h"], [
396 lscp_channel_info_t info;
397 info.instrument_name = 0;
398 ], ac_cv_instrument_name="yes", ac_cv_instrument_name="no")
399 ])
400 ac_instrument_name=$ac_cv_instrument_name
401 if test "x$ac_instrument_name" = "xyes"; then
402 AC_DEFINE(CONFIG_INSTRUMENT_NAME, 1, [Define if instrument_name is available.])
403 fi
404
405 AC_CACHE_CHECK([for mute/solo in lscp_channel_info_t],
406 ac_cv_mute_solo, [
407 AC_TRY_COMPILE([#include "lscp/client.h"], [
408 lscp_channel_info_t info;
409 info.mute = 0;
410 info.solo = 0;
411 ], ac_cv_mute_solo="yes", ac_cv_mute_solo="no")
412 ])
413 ac_mute_solo=$ac_cv_mute_solo
414 if test "x$ac_mute_solo" = "xyes"; then
415 AC_CHECK_LIB(lscp, lscp_set_channel_mute, [ac_mute_solo="yes"], [ac_mute_solo="no"])
416 fi
417 if test "x$ac_mute_solo" = "xyes"; then
418 AC_CHECK_LIB(lscp, lscp_set_channel_solo, [ac_mute_solo="yes"], [ac_mute_solo="no"])
419 fi
420 if test "x$ac_mute_solo" = "xyes"; then
421 AC_DEFINE(CONFIG_MUTE_SOLO, 1, [Define if mute/solo is available.])
422 fi
423
424 AC_CHECK_LIB(lscp, lscp_map_midi_instrument, [ac_midi_instrument="yes"], [ac_midi_instrument="no"])
425 if test "x$ac_midi_instrument" = "xyes"; then
426 AC_DEFINE(CONFIG_MIDI_INSTRUMENT, 1, [Define if MIDI instrument mapping is available.])
427 fi
428
429 AC_CHECK_LIB(lscp, lscp_create_fxsend, [ac_fxsend="yes"], [ac_fxsend="no"])
430 if test "x$ac_fxsend" = "xyes"; then
431 AC_DEFINE(CONFIG_FXSEND, 1, [Define if FX sends is available.])
432 AC_CACHE_CHECK([for FX send level in lscp_fxsend_info_t],
433 ac_cv_fxsend_level, [
434 AC_TRY_COMPILE([#include "lscp/client.h"], [
435 lscp_fxsend_info_t info;
436 info.level = 0.0f;
437 ], ac_cv_fxsend_level="yes", ac_cv_fxsend_level="no")
438 ])
439 ac_fxsend_level=$ac_cv_fxsend_level
440 if test "x$ac_fxsend_level" = "xyes"; then
441 AC_DEFINE(CONFIG_FXSEND_LEVEL, 1, [Define if FX send level is available.])
442 fi
443 AC_CHECK_LIB(lscp, lscp_set_fxsend_name, [ac_fxsend_rename="yes"], [ac_fxsend_rename="no"])
444 if test "x$ac_fxsend_rename" = "xyes"; then
445 AC_DEFINE(CONFIG_FXSEND_RENAME, 1, [Define if FX send rename is available.])
446 fi
447 fi
448
449 AC_CACHE_CHECK([for audio_routing array type],
450 ac_cv_audio_routing, [
451 AC_TRY_COMPILE([#include "lscp/client.h"], [
452 lscp_channel_info_t info;
453 char ch = info.audio_routing[0][0];
454 ], ac_cv_audio_routing="no", ac_cv_audio_routing="yes")
455 ])
456 ac_audio_routing=$ac_cv_audio_routing
457 if test "x$ac_audio_routing" = "xyes"; then
458 AC_DEFINE(CONFIG_AUDIO_ROUTING, 1, [Define if audio_routing is an integer array.])
459 fi
460
461 AC_CHECK_LIB(lscp, lscp_set_volume, [ac_volume="yes"], [ac_volume="no"])
462 if test "x$ac_volume" = "xyes"; then
463 AC_DEFINE(CONFIG_VOLUME, 1, [Define if global volume is available.])
464 fi
465
466 AC_CHECK_LIB(lscp, lscp_edit_channel_instrument, [ac_edit_instrument="yes"], [ac_edit_instrument="no"])
467 if test "x$ac_edit_instrument" = "xyes"; then
468 AC_DEFINE(CONFIG_EDIT_INSTRUMENT, 1, [Define if instrument editing is available.])
469 fi
470
471 AC_CACHE_CHECK([for CHANNEL_MIDI LSCP event support in liblscp],
472 ac_cv_channel_midi_event, [
473 AC_TRY_COMPILE([
474 #include "lscp/client.h"
475 #include "lscp/event.h"
476 ], [
477 lscp_event_t ev;
478 ev = LSCP_EVENT_CHANNEL_MIDI;
479 ], ac_cv_channel_midi_event="yes", ac_cv_channel_midi_event="no")
480 ])
481 ac_channel_midi_event=$ac_cv_channel_midi_event
482 if test "x$ac_channel_midi_event" = "xyes"; then
483 AC_DEFINE(CONFIG_EVENT_CHANNEL_MIDI, 1, [Define if LSCP CHANNEL_MIDI event support is available.])
484 fi
485
486 AC_CACHE_CHECK([for DEVICE_MIDI LSCP event support in liblscp],
487 ac_cv_device_midi_event, [
488 AC_TRY_COMPILE([
489 #include "lscp/client.h"
490 #include "lscp/event.h"
491 ], [
492 lscp_event_t ev;
493 ev = LSCP_EVENT_DEVICE_MIDI;
494 ], ac_cv_device_midi_event="yes", ac_cv_device_midi_event="no")
495 ])
496 ac_device_midi_event=$ac_cv_device_midi_event
497 if test "x$ac_device_midi_event" = "xyes"; then
498 AC_DEFINE(CONFIG_EVENT_DEVICE_MIDI, 1, [Define if LSCP DEVICE_MIDI event support is available.])
499 fi
500
501 AC_CHECK_LIB(lscp, lscp_get_voices, [ac_max_voices="yes"], [ac_max_voices="no"])
502 if test "x$ac_max_voices" = "xyes"; then
503 AC_DEFINE(CONFIG_MAX_VOICES, 1, [Define if max. voices / streams is available.])
504 fi
505
506 AC_CHECK_LIB(lscp, lscp_client_connection_lost, [ac_lscp_conn_lost="yes"], [ac_lscp_conn_lost="no"])
507 if test "x$ac_lscp_conn_lost" = "xyes"; then
508 AC_DEFINE(CONFIG_LSCP_CLIENT_CONNECTION_LOST, 1, [Define if liblscp function lscp_client_connection_lost() is available.])
509 fi
510
511 # Check for optional libraries.
512 if test "x$ac_libgig" = "xyes"; then
513 PKG_CHECK_MODULES([GIG], [gig >= 3.3.0], [ac_libgig="yes"], [ac_libgig="no"])
514 fi
515 if test "x$ac_libgig" = "xyes"; then
516 AC_DEFINE(CONFIG_LIBGIG, 1, [Define if libgig is available.])
517 ac_cflags="$ac_cflags $GIG_CFLAGS"
518 ac_libs="$ac_libs $GIG_LIBS"
519 CFLAGS="$CFLAGS $GIG_CFLAGS"
520 CPPFLAGS="$CPPFLAGS $GIG_CFLAGS"
521 LIBS="$LIBS $GIG_LIBS"
522 AC_DEFINE(CONFIG_LIBGIG_SETAUTOLOAD, 1, [Define if libgig provides gig::File::SetAutoLoad() method.])
523 ac_libgig_setautoload="yes"
524 else
525 AC_MSG_WARN([*** GIG library not found (libgig).])
526 fi
527
528 # Check for round math function.
529 AC_CHECK_LIB(m, lroundf, [ac_round="yes"], [ac_round="no"])
530 if test "x$ac_round" = "xyes"; then
531 AC_DEFINE(CONFIG_ROUND, 1, [Define if round is available.])
532 fi
533
534
535 # Checks for header files.
536 AC_HEADER_STDC
537 AC_HEADER_SYS_WAIT
538 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h signal.h sys/socket.h)
539
540 if test "x$ac_libgig" = "xyes"; then
541 AC_CHECK_HEADER(libgig/SF.h, [ac_libgig_sf2="yes"], [ac_libgig_sf2="no"])
542 if test "x$ac_libgig_sf2" = "xyes"; then
543 AC_DEFINE(CONFIG_LIBGIG_SF2, 1, [Define if libgig/SF.h is available.])
544 fi
545 fi
546
547 # Check for unique/single instance support.
548 if test "x$ac_xunique" = "xyes"; then
549 if test $ac_qt_version_major -lt 6; then
550 PKG_CHECK_MODULES([QT5NETWORK], [Qt5Network], [ac_xunique="yes"], [ac_xunique="no"])
551 else
552 #PKG_CHECK_MODULES([QT6NETWORK], [Qt6Network], [ac_xunique="yes"], [ac_xunique="no"])
553 AC_CHECK_LIB(Qt6Network, main, [ac_xunique="yes"], [ac_xunique="no"])
554 fi
555 fi
556 if test "x$ac_xunique" = "xyes"; then
557 AC_DEFINE(CONFIG_XUNIQUE, 1, [Define if unique/single instance is enabled.])
558 ac_qnetwork="network"
559 fi
560 AC_SUBST(ac_qnetwork)
561
562 # Check for debugging stack-trace.
563 if test "x$ac_stacktrace" = "xyes"; then
564 AC_DEFINE(CONFIG_STACKTRACE, 1, [Define if debugger stack-trace is enabled.])
565 fi
566
567 AC_SUBST(ac_cflags)
568 AC_SUBST(ac_ldflags)
569 AC_SUBST(ac_incpath)
570 AC_SUBST(ac_libs)
571
572
573 # Checks for typedefs, structures, and compiler characteristics.
574 # AC_C_CONST
575
576 # Checks for library functions.
577 AC_CHECK_FUNCS(system)
578
579 # Finally produce a configure header file and the makefiles.
580 AC_OUTPUT
581
582 # make clean > /dev/null 2>&1
583
584 # Output summary message
585
586 echo
587 echo " $PACKAGE_NAME $ac_build_version (Qt $ac_qt_version)"
588 echo
589 echo " Build target . . . . . . . . . . . . . . . . . . .: $ac_build_type"
590 echo
591 echo " LSCP instrument name support . . . . . . . . . . .: $ac_instrument_name"
592 echo " LSCP mute/solo support . . . . . . . . . . . . . .: $ac_mute_solo"
593 echo " LSCP MIDI instrument support . . . . . . . . . . .: $ac_midi_instrument"
594 echo " LSCP FX send support . . . . . . . . . . . . . . .: $ac_fxsend"
595 echo " LSCP FX send level support . . . . . . . . . . . .: $ac_fxsend_level"
596 echo " LSCP FX send rename support . . . . . . . . . . .: $ac_fxsend_rename"
597 echo " LSCP audio routing support . . . . . . . . . . . .: $ac_audio_routing"
598 echo " LSCP volume support . . . . . . . . . . . . . . .: $ac_volume"
599 echo " LSCP edit instrument support . . . . . . . . . . .: $ac_edit_instrument"
600 echo " GigaSampler instrument file support (libgig) . . .: $ac_libgig"
601 if test "x$ac_libgig" = "xyes"; then
602 echo " libgig supports fast information retrieval . . . .: $ac_libgig_setautoload"
603 echo " libgig supports SoundFont2 instruments files . . .: $ac_libgig_sf2"
604 fi
605 echo " LSCP channel MIDI event support . . . . . . . . .: $ac_channel_midi_event"
606 echo " LSCP device MIDI event support . . . . . . . . . .: $ac_device_midi_event"
607 echo " LSCP runtime max. voices / disk streams support .: $ac_max_voices"
608 echo " LSCP connection loss support . . . . . . . . . . .: $ac_lscp_conn_lost"
609 echo
610 echo " Unique/Single instance support . . . . . . . . . .: $ac_xunique"
611 echo " Debugger stack-trace (gdb) . . . . . . . . . . . .: $ac_stacktrace"
612 echo
613 echo " Install prefix . . . . . . . . . . . . . . . . . .: $ac_prefix"
614 echo
615 echo "Now type 'make', followed by 'make install' as root."
616 echo

  ViewVC Help
Powered by ViewVC